Technik Wiki
Registrieren
Advertisement
Gruppe: Grid Klebriger Kolben
Anlagen

Grid Roter Sand blass mit Mechaniken

Grid Redstone blass mit Redstone
                Hier:
Grid Befehlsblock mit Befehlen
Verfügbar in:
Wiki Redstone-Welt Redstone-Welt

Ein Wetterwandler und -sensor kann das Wetter aktiv beeinflussen und indirekt feststellen welche Wettererscheinung gerade stattfindet. Jedoch ist das Prüfen der Wetterstufe nur mühsam festzustellen, da es keinen direkten Befehl dafür gibt. Falls Regen oder Schneefall nicht auftreten soll, kann man auch den Befehl /gamerule doWeatherCycle verwenden.

Variante 1[]

Wetterwandler und -sensor (Befehle) Bild 1.1 Wetterwandler und -sensor (Befehle) Bild 1.2

Dieser Wettersensor ließt mit Hilfe eines Tageslichtsensor mit Komparator aus, welche Helligkeitsstufe aktuell vorhanden ist und schließt daraus welche Wetter-Erscheinung vermutlich ansteht. Wichtig: Der Wettersensor berechnet das Wetter nach dem vorherrschenden Lichtlevel, deshalb funktioniert er nur am Tag wenn es hell ist.

Einschalten
  • Befehl 1.1 Ein Rüstungsständer wird erstellt, der den Wettersensor darstellt. an ihm wird ein Tageslichtsensor[B1.2] und ein Komparator[B1.3] platziert
  • Befehl 1.4 Ein Punktestand-Ziel für das Speichern der Wetterstufe wird erstellt.
Wiederholen
  • Befehl 1.5 An der Position des Rüstungsständers wird das Ausgangssignal des Komparators abgefragt und in den Punktestand des Rüstungsständers geschrieben.
  • Befehl 1.6 Wenn der ausgelesene Wert bei genau zehn liegt, erhält der Spieler, sofern er dabei steht in der Schnellzugriffsleiste die Nachricht dass es Gewitter gibt.
  • Befehl 1.7 Bei Stufe elf bis zwölf erhält man die Nachricht, dass es regnerisch ist.
  • Befehl 1.8 Schlussendlich erhält man bei Stufe 13 bis 15 die Nachricht, dass es klares Wetter gibt.
Ausschalten
  • Befehl 1.9 Der Tageslichtsensor und der Komparator die sich an der Position des Rüstungsständers befinden werden entfernt.
  • Befehl 1.10 Der Rüstungsständer wird gelöscht.
  • Befehl 1.11 Das Punktestand-Ziel wird wieder entfernt.

Befehlsblöcke mit Befehlen:
summon minecraft:armor_stand ~-5 ~ ~ {Small:true,NoGravity:true,Invisible:true,Marker:true,CustomNameVisible:true,CustomName:'{"text":"Wettersensor","color":"gold","bold":true}',Tags:["EtiWetWS.1Alle"]}
execute at @e[type=minecraft:armor_stand,tag=EtiWetWS.1Alle] run setblock ~ ~ ~1 minecraft:daylight_detector replace
execute at @e[type=minecraft:armor_stand,tag=EtiWetWS.1Alle] run setblock ~ ~ ~ minecraft:comparator[facing=south] replace
scoreboard objectives add PZWetWS.1Wetter dummy ["Wetterwandler und -sensor.1: ",{"text":"Wetterstufe","bold":true}]


execute as @e[type=minecraft:armor_stand,tag=EtiWetWS.1Alle] at @s store result score @s PZWetWS.1Wetter run data get block ~ ~ ~ OutputSignal
execute as @e[type=minecraft:armor_stand,tag=EtiWetWS.1Alle,scores={PZWetWS.1Wetter=10}] at @s run title @a[distance=..5] actionbar ["",{"text":"[ ","color":"gold","bold":true},{"text":"Gewitter","color":"dark_blue","bold":true},{"text":" ]","color":"gold","bold":true} ]
execute as @e[type=minecraft:armor_stand,tag=EtiWetWS.1Alle,scores={PZWetWS.1Wetter=11..12}] at @s run title @a[distance=..5] actionbar ["",{"text":"[ ","color":"gold","bold":true},{"text":"Regnerisch","color":"blue","bold":true},{"text":" ]","color":"gold","bold":true} ]
execute as @e[type=minecraft:armor_stand,tag=EtiWetWS.1Alle,scores={PZWetWS.1Wetter=13..15}] at @s run title @a[distance=..5] actionbar ["",{"text":"[ ","color":"gold","bold":true},{"text":"Klares Wetter","color":"green","bold":true},{"text":" ]","color":"gold","bold":true} ]


execute at @e[type=minecraft:armor_stand,tag=EtiWetWS.1Alle] run fill ~ ~ ~ ~ ~ ~1 minecraft:air replace
kill @e[type=minecraft:armor_stand,tag=EtiWetWS.1Alle]
scoreboard objectives remove PZWetWS.1Wetter

Variante 2[]

Wetterwandler und -sensor (Befehle) Bild 2.1 Wetterwandler und -sensor (Befehle) Bild 2.2

Mit diesem Wetterwandler lässt sich das Wetter mittels eines Kessels auf klar, regnerisch und Gewitter einstellen. Mit Glasflaschen kann man den Wasserstand des Kessels wie gewünscht senken.

Einschalten
  • Befehl 2.1 Ein Rüstungsständer wird erstellt an dessen Stelle ein Kessel[B2.2] platziert wird.
  • Befehl 2.3 Der Spieler erhält einen Wassereimer und 64 Glasflaschen[B2.4].
  • Befehl 2.5 Jede Füllstufe des Kessels entscheidet welche Wetterlage aktiv ist, dies wird als Nachricht mitgeteilt.
Wiederholen
  • Befehl 2.6 Wenn der Kessel an der Position des Rüstungsständers komplett voll ist, wird Gewitter erzeugt.
  • Befehl 2.7 Wenn der Kessel weder komplett voll noch leer ist, wird Regen aktiviert.
  • Befehl 2.8 Wenn der Kessel leer ist, wird klares Wetter erzeugt.
Ausschalten
  • Befehl 2.9 Der Kessel an der Position des Rüstungsständers wird entfernt
  • Befehl 2.10 Die eventuell auf den Boden geworfenen Glasflaschen oder der Wassereimer erhalten ein Etikett
  • Befehl 2.11 Alle Rüstungsständer sowie die eventuell herumliegenden Gegenstände werden gelöscht.
  • Befehl 2.12 Der Wassereimer sowie die Glasflaschen[B2.13] werden aus dem Inventar entfernt.
  • Befehl 2.14 Das Wetter wird wieder auf klar gesetzt.

Befehlsblöcke mit Befehlen:
summon minecraft:armor_stand ~-5 ~0.3 ~ {Small:true,Marker:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"Wetterwandler","color":"blue","bold":true}',Tags:["EtiWetWS.2Alle"]}
execute at @e[type=minecraft:armor_stand,tag=EtiWetWS.2Alle] run setblock ~ ~ ~ minecraft:cauldron[level=0] replace
give @a[distance=..25] minecraft:water_bucket{wetterwandler_und_-sensor:"v2gegenstand",display:{Lore:['"Fülle damit den Kessel"']} }
give @a[distance=..25] minecraft:glass_bottle{wetterwandler_und_-sensor:"v2gegenstand",display:{Lore:['"Entleere damit den Kessel"']} } 64
tellraw @a[distance=..25] ["Wetterwandler und -sensor.2:\n",{"text":"Klares Wetter: leerer Kessel\nRegen: halbvoller Kessel\nGewitter: Voller Kessel","bold":true}]


execute at @e[sort=nearest,limit=1,type=minecraft:armor_stand,tag=EtiWetWS.2Alle] if block ~ ~ ~ minecraft:cauldron[level=3] run weather thunder 1
execute at @e[sort=nearest,limit=1,type=minecraft:armor_stand,tag=EtiWetWS.2Alle] unless block ~ ~ ~ minecraft:cauldron[level=0] unless block ~ ~ ~ minecraft:cauldron[level=3] run weather rain 1
execute at @e[sort=nearest,limit=1,type=minecraft:armor_stand,tag=EtiWetWS.2Alle] if block ~ ~ ~ minecraft:cauldron[level=0] run weather clear 1


execute at @e[type=minecraft:armor_stand,tag=EtiWetWS.2Alle] run setblock ~ ~ ~ minecraft:air replace
tag @e[type=minecraft:item,nbt={Item:{tag:{wetterwandler_und_-sensor:"v2gegenstand"} } }] add EtiWetWS.2Alle
kill @e[tag=EtiWetWS.2Alle]
clear @a[distance=..25] minecraft:water_bucket{wetterwandler_und_-sensor:"v2gegenstand"}
clear @a[distance=..25] minecraft:glass_bottle{wetterwandler_und_-sensor:"v2gegenstand"}

Variante 3[]

Wetterwandler und -sensor (Befehle) Bild 3.1 Wetterwandler und -sensor (Befehle) Bild 3.2

Mit dieser Variante erhält man die Möglichkeit den Wetterwandler an einer bestimmten Stelle zu platzieren. Wirft man eine Wasserflasche in den Kessel von dieser Wetteranlage, so wird ihr Mechanismus in Gang gesetzt und man erhält eine Chat-Nachricht, in der man alle Wetterstufen anklicken kann sowie die Dauer, wie lange das entsprechende Wetter anhalten soll. Stellt man die Dauer auf -1 so wird das Wetter ewig auf der entsprechenden Wetterstufe verweilen.

Einschalten
  • Befehl 3.1 Wenn der Hebel umgelegt wird, wird die Start-Funktion gestartet.
Wiederholen
  • Befehl 3.2 Beim Einschalten wird auch der Wiederhol-Befehlsblock gestartet, der jeden Tick die Zyklus-Funktion lädt.
Ausschalten
  • Befehl 3.3 Wenn der Hebel wieder in Ausgangsstellung zurück gelegt wird, wird die Stopp-Funktion ausgelöst und schaltet alles wieder ab.

Befehlsblöcke mit Befehlen:


Variante 3: Start-Funktion
Die Start-Funktion gibt den Spielern Rüstungsständer für das Platzieren von Wetteranlagen und Wasserflaschen die man in diese rein werfen kann. Ein Punktestand-Ziel für den Auslöser, sowie eine Konstante und ein Rüstungsständer fürs Wetter werden erstellt.

Editor Icon wetterwandler_und_-sensor:v3start.mcfunction
# Das Punktestand-Ziel wird erstellt
scoreboard objectives add PZWetWS.3Wert trigger ["Wetterwandler und -sensor.3: ",{"text":"Wert der Variablen","bold":true}]

# Die Konstante Hundert wird erstellt
scoreboard players set KonstWetWS.3HUNDERT PZWetWS.3Wert 100

# Die Variable für Dauer des Wetters sowie der Rüstungsständer der die Wetterart speichert werden erstellt
scoreboard players set VarWetWS.3Dauer PZWetWS.3Wert 1
summon minecraft:armor_stand ~ ~1 ~ {Small:true,NoGravity:true,CustomNameVisible:true,CustomName:'{"text":"klares Wetter","color":"yellow","bold":true}',Tags:["EtiWetWS.3Alle","EtiWetWS.3Wetter"]}

# Spielern im Umkreis von 15 Metern wird ein Rüstungsständer und mehrere Wasserflaschen ins Inventar gegeben
give @a[distance=..15] minecraft:armor_stand{wetterwandler_und_-sensor:"v3gegenstand",display:{Name:'{"text":"Wetteranlage","color":"aqua","bold":true}',Lore:['"Platziere den"','"Rüstungsständer um"','"die Wetteranlage"','"zu erstellen"']},EntityTag:{DisabledSlots:2039583,Small:true,Invisible:true,NoGravity:true,CustomNameVisible:true,CustomName:'{"text":"Wetteranlage","color":"aqua","bold":true}',Tags:["EtiWetWS.3Alle","EtiWetWS.3Wetteranlage"],ArmorItems:[{},{},{},{id:"minecraft:beacon",Count:1b} ] } }
give @a[distance=..15] minecraft:potion{wetterwandler_und_-sensor:"v3gegenstand",Potion:"minecraft:water",display:{Lore:['"Wirf mit Q die"','"Wasserflasche auf"','"die Wetteranlage"'] } } 4

Variante 3: Zyklus-Funktion
Die Zyklus-Funktion sorgt dafür, dass die Wetteranlage beim Platzieren des Rüstungsständers entsteht und lässt die Chat-Nachricht erscheinen, wenn man eine Wasserflasche auf den Kessel wirft. In dieser Nachricht erhält man alle Optionen um über das Wetter zu herrschen. Man kann klares, regnerisches oder gewitterisches Wetter einstellen, sowie die Dauer wie lange das Wetter so bleiben soll.

Editor Icon wetterwandler_und_-sensor:v3zyklus.mcfunction
# Jeden Tick wird die Dauer des Wetters um eins reduziert und bei null wird das Wetter wieder klar
data merge entity @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetter,name=!"klares Wetter",scores={PZWetWS.3Wert=0},sort=nearest,limit=1] {CustomName:'{"text":"klares Wetter","color":"yellow","bold":true}'}
scoreboard players remove @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetter,scores={PZWetWS.3Wert=1..}] PZWetWS.3Wert 1

# Je nach Einstellung wird das Wetter auf die Wetterart eingestellt, so wie der Rüstungsständer seinen Namen dafür besitzt
execute if entity @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetter,name="klares Wetter"] run weather clear 1
execute as @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetter,name="Regen"] unless entity @s[scores={PZWetWS.3Wert=0}] run weather rain 1
execute as @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetter,name="Gewitter"] unless entity @s[scores={PZWetWS.3Wert=0}] run weather thunder 1

# Falls an der Position des Rüstungsständers (Wetteranlage) kein Kessel vorhanden ist, wird einer platziert
execute at @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetteranlage] unless block ~ ~ ~ minecraft:cauldron run setblock ~ ~ ~ minecraft:cauldron replace

# Wenn man eine Wasserflasche in die Nähe der Wetteranlage wirft, erhält der Drop ein Etikett, damit es einfacher erkannt werden kann
execute as @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetteranlage] at @s run tag @e[distance=..2,type=minecraft:item,tag=!EtiWetWS.3Wasserflasche,nbt={Item:{id:"minecraft:potion",tag:{Potion:"minecraft:water"} } },sort=nearest,limit=1] add EtiWetWS.3Wasserflasche

# Spieler erhalten nach dem Wurf der Wasserflasche den Wert -1 und erhalten so die Chat-Nachricht und gleichzeitig erhält die Wetteranlage den Wert 500 für die Ticks wie sie aktiv ist. Anschließend wird die Wasserflasche entfernt
execute as @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetteranlage] at @s if entity @e[distance=..2,type=minecraft:item,tag=EtiWetWS.3Wasserflasche,sort=nearest,limit=1] run scoreboard players set @a[distance=..5] PZWetWS.3Wert -1
execute as @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetteranlage] at @s if entity @e[distance=..2,type=minecraft:item,tag=EtiWetWS.3Wasserflasche,sort=nearest,limit=1] run scoreboard players set @s PZWetWS.3Wert 500
execute at @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetteranlage] run kill @e[distance=..2,type=minecraft:item,tag=EtiWetWS.3Wasserflasche,sort=nearest,limit=1]

# Wenn die Wetteranlage aktiv ist, wird sie rotiert und lässt Wasserpartikel um sie kreisen
execute as @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetteranlage,scores={PZWetWS.3Wert=1..}] at @s run teleport @s ~ ~ ~ ~2 ~
execute at @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetteranlage,scores={PZWetWS.3Wert=1..}] run particle minecraft:fishing ^ ^1 ^1 0 0 0 0.01 10 force @a[distance=..25]
execute at @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetteranlage,scores={PZWetWS.3Wert=1..}] run particle minecraft:fishing ^ ^1 ^-1 0 0 0 0.01 10 force @a[distance=..25]

# Solange die Wetteranlage mindestens den Wert von eins hat, wird ihr jeden Tick dieser um eins reduziert
scoreboard players remove @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetteranlage,scores={PZWetWS.3Wert=1..}] PZWetWS.3Wert 1

# Wenn die Wetteranlage aktiv ist und ein Spieler auf den Auslöser im Chat geklickt hat, besitzt einen bestimmten Wert, mit dem er das Wetter entsprechend einstellen kann
execute at @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetteranlage,scores={PZWetWS.3Wert=1..}] if entity @a[distance=..5,scores={PZWetWS.3Wert=1}] run data merge entity @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetter,sort=nearest,limit=1] {CustomName:'{"bold":true,"color":"yellow","text":"klares Wetter"}'}
execute at @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetteranlage,scores={PZWetWS.3Wert=1..}] if entity @a[distance=..5,scores={PZWetWS.3Wert=2}] run data merge entity @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetter,sort=nearest,limit=1] {CustomName:'{"bold":true,"color":"aqua","text":"Regen"}'}
execute at @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetteranlage,scores={PZWetWS.3Wert=1..}] if entity @a[distance=..5,scores={PZWetWS.3Wert=3}] run data merge entity @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetter,sort=nearest,limit=1] {CustomName:'{"bold":true,"color":"blue","text":"Gewitter"}'}
execute at @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetteranlage,scores={PZWetWS.3Wert=1..}] if entity @a[distance=..5,scores={PZWetWS.3Wert=4}] run scoreboard players add VarWetWS.3Dauer PZWetWS.3Wert 1
execute at @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetteranlage,scores={PZWetWS.3Wert=1..}] if entity @a[distance=..5,scores={PZWetWS.3Wert=5}] if score VarWetWS.3Dauer PZWetWS.3Wert matches 0.. run scoreboard players remove VarWetWS.3Dauer PZWetWS.3Wert 1

# Wenn die Wetterdauer angeklickt wurde, wird die dauer in den Rüstungsständer für das Wetter gespeichert und anschließend mal 100 gerechnet
execute at @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetteranlage,scores={PZWetWS.3Wert=1..}] if entity @a[distance=..5,scores={PZWetWS.3Wert=4..5}] run scoreboard players operation @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetter] PZWetWS.3Wert = VarWetWS.3Dauer PZWetWS.3Wert
execute at @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetteranlage,scores={PZWetWS.3Wert=1..}] if entity @a[distance=..5,scores={PZWetWS.3Wert=4..5}] run scoreboard players operation @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetter,scores={PZWetWS.3Wert=1..}] PZWetWS.3Wert *= KonstWetWS.3HUNDERT PZWetWS.3Wert
execute at @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetteranlage,scores={PZWetWS.3Wert=1..}] run title @a[distance=..5,scores={PZWetWS.3Wert=4..5}] actionbar ["",{"score":{"name":"@e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetter,sort=nearest,limit=1]","objective":"PZWetWS.3Wert"},"color":"dark_purple","bold":true},{"text":" Ticks: ","color":"gray","bold":true},{"entity":"@e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetter,sort=nearest,limit=1]","nbt":"CustomName","interpret":true}]

# Wenn die Wetteranlage aktiv ist und der Spieler nicht den Wert null besitzt, so erhält er die Chat-Nachricht in der alle Wetteroptionen aufgelistet sind
execute at @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetteranlage,scores={PZWetWS.3Wert=1..}] as @a[distance=..5] unless entity @s[scores={PZWetWS.3Wert=0}] run tellraw @s ["Wetterwandler und -sensor.3: ",{"text":"\nwetter = ","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"Tippe für klares Wetter"} },"clickEvent":{"action":"run_command","value":"/trigger PZWetWS.3Wert set 1"} },{"text":"klares Wetter","color":"gray","bold":true},{"text":"\nwetter = ","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"Tippe für Regen"} },"clickEvent":{"action":"run_command","value":"/trigger PZWetWS.3Wert set 2"} },{"text":"Regen","color":"gray","bold":true},{"text":"\nwetter = ","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"Tippe für Gewitter"} },"clickEvent":{"action":"run_command","value":"/trigger PZWetWS.3Wert set 3"} },{"text":"Gewitter","color":"gray","bold":true},{"text":"\nwetter == ","bold":true},{"entity":"@e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetter,sort=nearest,limit=1]","nbt":"CustomName","interpret":true},{"text":"\ndauer (","bold":true},{"text":"+1","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"Tippe für die Dauer +1"} },"clickEvent":{"action":"run_command","value":"/trigger PZWetWS.3Wert set 4"} },{"text":"!","bold":true},{"text":"-1","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"Tippe für die Dauer -1"} },"clickEvent":{"action":"run_command","value":"/trigger PZWetWS.3Wert set 5"} },{"text":") == ","bold":true},{"score":{"name":"VarWetWS.3Dauer","objective":"PZWetWS.3Wert"},"color":"dark_purple","bold":true}]

# Spieler die keinen Wert besitzen oder einen über null erhalten die Erlaubnis einen Auslöser zu nutzen und bekommen den Wert null zugewiesen
execute at @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetteranlage] as @a[distance=..5] unless entity @s[scores={PZWetWS.3Wert=0}] run scoreboard players enable @s PZWetWS.3Wert
execute at @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetteranlage] as @a[distance=..5] unless entity @s[scores={PZWetWS.3Wert=0}] run scoreboard players set @s PZWetWS.3Wert 0

Variante 3: Stopp-Funktion
Die Stopp-Funktion löscht alle Rüstungsständer, Wasserflaschen und Punktestand-Ziele wieder. Auch das Inventar wird von Wetteranlagen-Rüstungsständern befreit.

Editor Icon wetterwandler_und_-sensor:v3stopp.mcfunction
# Das Punktestand-Ziel wird entfernt
scoreboard objectives remove PZWetWS.3Wert

# Der Rüstungsständer wie die Wasserflaschen werden aus dem Inventar entfernt
clear @a minecraft:armor_stand{wetterwandler_und_-sensor:"v3gegenstand"}
clear @a minecraft:potion{wetterwandler_und_-sensor:"v3gegenstand"}

# Der Kessel der an der Stelle des Rüstungsständers steht wird durch Luft ersetzt
execute at @e[type=minecraft:armor_stand,tag=EtiWetWS.3Wetteranlage] run setblock ~ ~ ~ minecraft:air replace

# Falls die Gegenstände auf dem Boden geworfen wurden, werden sie mit einem Etikett belegt und anschließend werden alle Objekte mit diesem Etikett gelöscht
tag @e[type=minecraft:item,nbt={Item:{wetterwandler_und_-sensor:"v3gegenstand"} }] add EtiWetWS.3Alle
kill @e[type=minecraft:armor_stand,tag=EtiWetWS.3Alle]


Disambig color
Advertisement