Werkzeug-System (Befehle)

Aus Technik Wiki
Wechseln zu: Navigation, Suche
Gruppe: Grid Ketten-Befehlsblock.png
Systeme

Grid Roter Sand blass.png mit Mechaniken

Grid Redstone blass.png mit Redstone
                Hier:
Grid Befehlsblock.png mit Befehlen
Verfügbar in:
Wiki Mechanik-Welt.png Mechanik-Welt

Das Werkzeug-System ermöglicht es, einem Spieler der sich im Überlebensmodus befindet, seine Werkzeuge mit Verzauberungen auszustatten, die über ihre normalen Verzauberungen hinaus auch neue Eigenschaften besitzen. So kann zum Beispiel eine Hacke mit Haltbarkeit verzaubert werden, die dann in der Lage ist, mit nur einen Linksklick mehrere Feldfrüchte auf einmal abzubauen. Und die Verzauberungsstufe bestimmt den Abbau-Radius der Hacke.

Inhaltsverzeichnis

Variante 1[Bearbeiten | Quelltext bearbeiten]

Wiki Mechanik-Welt.png
Diese neue oder überarbeitete Technik ist noch nicht in der aktuellen Mechanik-Welt vorhanden.
In einem der nächsten Updates wird sie dort hinzugefügt werden.

Werkzeug-System (Befehle) Bild 1.1.png Werkzeug-System (Befehle) Bild 1.2.png

Dieses Werkzeug-System ermöglicht einem Spieler, insbesondere im Überlebensmodus, dass dieser mit einer beliebigen Hacke die mit Haltbarkeit verzaubert ist, vor ihm in einem Radius, welcher abhängig von der Verzauberungsstufe ist, ein größeres Feld mit nur einem Schlag abzuernten. Hierbei befinden sich drei Befehlsblöcke am Ausgangspunkt, wo alles stattfinden wird. Die Funktionen sind geschachtelt programmiert, sodass sie recht effizient sind, falls niemand gerade mit diesem System Feldfrüchte erntet.

Einschalten
  • Befehl 1.1 Auf dem Wiederhol-Befehlsblock befindet sich ein Hebel. Legt man ihn um, wird zuerst der Befehlsblock mit der Start-Funktion werkzeug-system:v1start aktiviert.
Wiederholen
Ausschalten

Befehlsblöcke mit Befehlen:



Variante 1: Start-Funktion
Zuerst werden alle Punktestand-Ziele erstellt.

  • Zeile 2 ein dummy-Ziel für die Verzauberungsstufe wird angelegt.
  • Zeile 3 ein dummy-Ziel für die Haltbarkeitsstufe wird angelegt.
  • Zeile 5 ein Statistik-Ziel für das Abbauen von Weizen wird erstellt.
  • Zeile 6 ein Ziel für Karotten.
  • Zeile 7 ein Ziel für Kartoffeln.
  • Zeile 8 ein Ziel für rote Bete.

Auch erhält der Spieler fünf Hacken mit verschiedenen Materialien und Verzauberungsstufen, wobei die Verzauberungsstufe nicht vom Material abhängig ist.

Der Spielmodus wird angepasst.

  • Zeile 18 der Spieler wird auch in den Überlebensmodus gesetzt, falls er es nicht schon ist.

Als letztes wird noch von dem Befehlsblock aus, ein großes Feld mit Weizen, Karotten, Kartoffeln und rote Bete erstellt. Denn die Position des Befehlsblockes wurde nicht verändert.

  • Zeile 21 Zuerst wird Ackerboden über ein großes Quadrat um den Befehlsblock erstellt, wo sich nur Luft befindet.
  • Zeile 22 einen Block darüber werden dann Weizen, Karotten[Z23], Kartoffeln[Z24] und rote Bete[Z25] von der höchsten Wachstumsstufe platziert. Auch nur dort wo sich Luft befindet.
  • Zeile 27 damit die Ackerböden nicht austrocknen, wird Wasser in vier Ecken platziert.
  • Zeile 28 Wasser wird in eine weitere Ecke platziert.
  • Zeile 29 Wasser wird in eine weitere Ecke platziert.
  • Zeile 30 Wasser wird in eine weitere Ecke platziert.
Editor Icon.png werkzeug-system:v1start.mcfunction
# Punkte-Ziele werden erstellt.
scoreboard objectives add PZWerkS.1Verz dummy ["Werkzeug-System.1: ",{"text":"Verzauberungsstufe","bold":true}]
scoreboard objectives add PZWerkS.1Haltb dummy ["Werkzeug-System.1: ",{"text":"Haltbarkeit","bold":true}]

scoreboard objectives add PZWerkS.1Weizen minecraft.mined:minecraft.wheat ["Werkzeug-System.1: ",{"text":"Weizen geerntet","bold":true}]
scoreboard objectives add PZWerkS.1Karotte minecraft.mined:minecraft.carrots ["Werkzeug-System.1: ",{"text":"Karotten geerntet","bold":true}]
scoreboard objectives add PZWerkS.1Kartoff minecraft.mined:minecraft.potatoes ["Werkzeug-System.1: ",{"text":"Kartoffeln geerntet","bold":true}]
scoreboard objectives add PZWerkS.1Bete minecraft.mined:minecraft.beetroots ["Werkzeug-System.1: ",{"text":"Rote Bete geerntet","bold":true}]

# Die fünf verschiedenen Hacken mit verschiedenen Verzauberungsstufen werden dem Spieler gegeben.
give @a[distance=..25] minecraft:wooden_hoe{werzeug-system:"v1gegenstand",Enchantments:[{id:"minecraft:unbreaking",lvl:1s}],display:{Lore:['"Klicke mit der linken Maustaste"','"mit Hacke um Feldfrüchte"','"in einem bestimmten"','"Umkreis zu ernten"'] } }
give @a[distance=..25] minecraft:stone_hoe{werzeug-system:"v1gegenstand",Enchantments:[{id:"minecraft:unbreaking",lvl:2s}],display:{Lore:['"Klicke mit der linken Maustaste"','"mit Hacke um Feldfrüchte"','"in einem bestimmten"','"Umkreis zu ernten"'] } }
give @a[distance=..25] minecraft:iron_hoe{werzeug-system:"v1gegenstand",Enchantments:[{id:"minecraft:unbreaking",lvl:3s}],display:{Lore:['"Klicke mit der linken Maustaste"','"mit Hacke um Feldfrüchte"','"in einem bestimmten"','"Umkreis zu ernten"'] } }
give @a[distance=..25] minecraft:golden_hoe{werzeug-system:"v1gegenstand",Enchantments:[{id:"minecraft:unbreaking",lvl:4s}],display:{Lore:['"Klicke mit der linken Maustaste"','"mit Hacke um Feldfrüchte"','"in einem bestimmten"','"Umkreis zu ernten"'] } }
give @a[distance=..25] minecraft:diamond_hoe{werzeug-system:"v1gegenstand",Enchantments:[{id:"minecraft:unbreaking",lvl:5s}],display:{Lore:['"Klicke mit der linken Maustaste"','"mit Hacke um Feldfrüchte"','"in einem bestimmten"','"Umkreis zu ernten"'] } }

# Den Spielmodus auf Überleben setzen.
gamemode survival @a[distance=..25,gamemode=!survival]

# Ackerboden samt Wasserquellen und ausgewachsenen Feldfrüchte werden um die Befehlsquelle platziert.
fill ~-15 ~ ~-15 ~15 ~ ~15 minecraft:farmland[moisture=7] replace minecraft:air
fill ~-15 ~1 ~-15 ~ ~1 ~ minecraft:wheat[age=7] replace minecraft:air
fill ~15 ~1 ~-15 ~1 ~1 ~ minecraft:carrots[age=7] replace minecraft:air
fill ~15 ~1 ~15 ~1 ~1 ~ minecraft:potatoes[age=7] replace minecraft:air
fill ~-15 ~1 ~15 ~ ~1 ~ minecraft:beetroots[age=3] replace minecraft:air

setblock ~-7 ~ ~-7 minecraft:water replace
setblock ~7 ~ ~-7 minecraft:water replace
setblock ~-7 ~ ~7 minecraft:water replace
setblock ~7 ~ ~7 minecraft:water replace


Variante 1: Zyklus-Funktion
Die Zyklus-Funktion werkzeug-system:v1zyklus wird jeden Tick vom Wiederhol-Befehlsblock geladen.

  • Zeile 2 Nun wird geschaut, ob der Spieler Weizen,
  • Zeile 3 Karotten,
  • Zeile 4 Kartoffeln oder
  • Zeile 5 rote Bete abgebaut hat. Wenn der Spieler eine dieser Feldfrüchte erntet, wird sein Punktestand bei einem dieser Punktestand-Zielen hochgezählt, sodass ihm in diesem Moment ein Etikett gegeben werden kann. Das Etikett wird genutzt um zu schauen ob der Spieler eines der vier Feldfrüchte geerntet hat.
  • Zeile 8 Nur wenn der Spieler eine der Feldfrüchte abgebaut hat, wird die Funktion geladen. Sonst wird sie nicht aufgerufen und übersprungen.

Danach werden die eventuell hochgezählten Punktestände wieder zurückgesetzt und das für alle Feldfrucht-Punktestände.

  • Zeile 17 Anschließend wird das Etikett selbst wieder entfernt.
Editor Icon.png werkzeug-system:v1zyklus.mcfunction
# Etikette werden vergeben, falls man Ackerpflanzen abbaut.
tag @a[scores={PZWerkS.1Weizen=1..}] add EtiWerkS.1Ernte
tag @a[scores={PZWerkS.1Karotte=1..}] add EtiWerkS.1Ernte
tag @a[scores={PZWerkS.1Kartoff=1..}] add EtiWerkS.1Ernte
tag @a[scores={PZWerkS.1Bete=1..}] add EtiWerkS.1Ernte

# Nur für die Spieler wird die Funktion aufgerufen, die tatsächlich eine Ackerpflanze geerntet haben.
execute as @a[tag=EtiWerkS.1Ernte] run function werkzeug-system:v1hacke_stufe

# Den Punktestand für das Ernten der Ackerpflanze wieder zurücksetzen.
scoreboard players reset @a[tag=EtiWerkS.1Ernte] PZWerkS.1Weizen
scoreboard players reset @a[tag=EtiWerkS.1Ernte] PZWerkS.1Karotte
scoreboard players reset @a[tag=EtiWerkS.1Ernte] PZWerkS.1Kartoff
scoreboard players reset @a[tag=EtiWerkS.1Ernte] PZWerkS.1Bete

# Das Etikett für die Ernte wieder entfernen.
tag @a[tag=EtiWerkS.1Ernte] remove EtiWerkS.1Ernte


Variante 1: Hacke-Stufe-Funktion
Wenn der Spieler Feldfrüchte tatsächlich geerntet hat, wird die Funktion geladen und ausgeführt. Nun folgt wieder eine Reihe an Abfragen, ob der Spieler eine Hacke eines bestimmten Materials in der Schnellzugriffsleiste ausgewählt hat. Wenn der Spieler eine Hacke ausgewählt hat, bekommt er ein weiteres Etikett, dass dies damit präsentiert.

Wenn der Spieler eine der Hacken in der Hand hält, und somit ein Etikett besitzt, wird seine Verzauberungsstufe auf der Hacke ausgelesen, falls die Verzauberung der Hacke "Haltbarkeit" ist.

  • Zeile 9 die Verzauberungsstufe wird in das Punktestand-Ziel des Spielers übertragen, in dem der Pfad der Verzauberung ausgelesen wird.

Wenn der Spieler das Etikett besitzt und eine Verzauberungsstufe, so wird die Funktion aufgerufen.

Anschließend wird die Beschädigung der Hacke um eins Erhöht.

  • Zeile 15 Indem die Hacke-Haltbarkeits-Funktion geladen wird.

Danach wird der Punktestand und das Etikett wieder entfernt.

  • Zeile 18 der Punktestand für die Verzauberungsstufe wird zurückgesetzt.
  • Zeile 19 und das Etikett für die Hacken wird wieder entfernt.
Editor Icon.png werkzeug-system:v1hacke_stufe.mcfunction
# Wenn man eine Hacke in der Schnellzugriffsleiste ausgewählt hat, erhält man ein Etikett.
tag @s[nbt={SelectedItem:{id:"minecraft:wooden_hoe"} } ] add EtiWerkS.1Hacke
tag @s[nbt={SelectedItem:{id:"minecraft:stone_hoe"} } ] add EtiWerkS.1Hacke
tag @s[nbt={SelectedItem:{id:"minecraft:iron_hoe"} } ] add EtiWerkS.1Hacke
tag @s[nbt={SelectedItem:{id:"minecraft:golden_hoe"} } ] add EtiWerkS.1Hacke
tag @s[nbt={SelectedItem:{id:"minecraft:diamond_hoe"} } ] add EtiWerkS.1Hacke

# Bei Spielern die ihre Hacke mit Haltbarkeit verzaubert haben, wird dessen Verzauberungsstufe in einem Punktestand-Ziel gespeichert.
execute store result score @s[tag=EtiWerkS.1Hacke,nbt={SelectedItem:{tag:{Enchantments:[{id:"minecraft:unbreaking"} ] } } } ] PZWerkS.1Verz run data get entity @s SelectedItem.tag.Enchantments[{"id":"minecraft:unbreaking"}].lvl

# Nur wenn die Hacke verzaubert ist, wird die Funktion zwei Blöcke vor dem Spieler aufgerufen.
execute if entity @s[tag=EtiWerkS.1Hacke,scores={PZWerkS.1Verz=1..}] at @s rotated ~90 0 positioned ^2 ^1 ^ run function werkzeug-system:v1bereich_stufe

# Die Beschädigung wird um eins erhöht, wenn die Hacke verzaubert war, in dem die Hacke-Haltbarkeit-Funktion geladen wird.
execute at @s[tag=EtiWerkS.1Hacke,scores={PZWerkS.1Verz=1..}] run function werkzeug-system:v1hacke_haltbarkeit

# Wenn der Spieler eine verzauberte Hacke besaß wird sein Punktestand zurück gesetzt und das Etikett wird entfernt.
scoreboard players reset @s[scores={PZWerkS.1Verz=1..}] PZWerkS.1Verz
tag @s[tag=EtiWerkS.1Hacke] remove EtiWerkS.1Hacke


Variante 1: Bereich-Stufen-Funktion
Wenn der Spieler eine Hacke in der Hand hält, wird die Funktion aufgerufen. Der Aufruf erfolgt mit drei Positionsanpassungen, so wird die aktuelle Position vom Spieler übernommen, aber mit der Rotation um 90° und in Blickrichtung 2 Blöcke nach links und einen nach oben. Kurz gesagt, das alles geschieht damit am Ende die Funktion genau zwei Blöcke vor dem Spieler in Blickrichtung aufgerufen wird und das ohne Neigungsabweichungen.

Die Stufe eins wird direkt ohne Test verfahren.

  • Zeile 2 Da bereits sichergestellt ist, dass der Spieler mindestens über die Verzauberungsstufe eins verfügt, wird ohne weitere Tests die Funktion werkzeug-system:v1ernten aufgerufen.

Die Funktion ruft nun in einer Kaskade an verschiedenen Koordinaten die Ernte-Funktion auf. Um die Größe des Aberntegebiets anhand der Verzauberungsstufe abhängig zu machen, wird jetzt stets abgefragt, welche Stufe der Spieler für den Verzauberungs-Punktestand besitzt.

  • Zeile 5 je größer der Punktestand, umso mehr Ernte-Funktionen werden in einem größeren Gebiet geladen.
  • Zeile 6 dabei wird nur bei Stufe zwei, nur bei zwei Befehlen die exakte Stufe abgefragt.
  • Zeile 7 da bei höheren Stufen der gleiche Abbau-Bereich von weiteren Ernte-Funktionen abgedeckt wird.
Editor Icon.png werkzeug-system:v1bereich_stufe.mcfunction
# Ab Stufe 1 und höher.
function werkzeug-system:v1ernten

# Ab Stufe 2 und höher.
execute if entity @s[scores={PZWerkS.1Verz=2..}] positioned ~1 ~ ~1 run function werkzeug-system:v1ernten
execute if entity @s[scores={PZWerkS.1Verz=2}] positioned ~-1 ~ ~1 run function werkzeug-system:v1ernten
execute if entity @s[scores={PZWerkS.1Verz=2}] positioned ~1 ~ ~-1 run function werkzeug-system:v1ernten
execute if entity @s[scores={PZWerkS.1Verz=2..}] positioned ~-1 ~ ~-1 run function werkzeug-system:v1ernten

# Ab Stufe 3 und höher.
execute if entity @s[scores={PZWerkS.1Verz=3..}] positioned ~2 ~ ~2 run function werkzeug-system:v1ernten
execute if entity @s[scores={PZWerkS.1Verz=3..}] positioned ~-2 ~ ~2 run function werkzeug-system:v1ernten
execute if entity @s[scores={PZWerkS.1Verz=3..}] positioned ~2 ~ ~-2 run function werkzeug-system:v1ernten
execute if entity @s[scores={PZWerkS.1Verz=3..}] positioned ~-2 ~ ~-2 run function werkzeug-system:v1ernten

# Ab Stufe 4 und höher.
execute if entity @s[scores={PZWerkS.1Verz=4..}] positioned ~3 ~ ~3 run function werkzeug-system:v1ernten
execute if entity @s[scores={PZWerkS.1Verz=4..}] positioned ~-3 ~ ~3 run function werkzeug-system:v1ernten
execute if entity @s[scores={PZWerkS.1Verz=4..}] positioned ~3 ~ ~-3 run function werkzeug-system:v1ernten
execute if entity @s[scores={PZWerkS.1Verz=4..}] positioned ~-3 ~ ~-3 run function werkzeug-system:v1ernten

execute if entity @s[scores={PZWerkS.1Verz=4..}] positioned ~3 ~ ~ run function werkzeug-system:v1ernten
execute if entity @s[scores={PZWerkS.1Verz=4..}] positioned ~-3 ~ ~ run function werkzeug-system:v1ernten
execute if entity @s[scores={PZWerkS.1Verz=4..}] positioned ~ ~ ~3 run function werkzeug-system:v1ernten
execute if entity @s[scores={PZWerkS.1Verz=4..}] positioned ~ ~ ~-3 run function werkzeug-system:v1ernten

# Ab Stufe 5 und eventuell höher.
execute if entity @s[scores={PZWerkS.1Verz=5..}] positioned ~4 ~ ~4 run function werkzeug-system:v1ernten
execute if entity @s[scores={PZWerkS.1Verz=5..}] positioned ~-4 ~ ~4 run function werkzeug-system:v1ernten
execute if entity @s[scores={PZWerkS.1Verz=5..}] positioned ~4 ~ ~-4 run function werkzeug-system:v1ernten
execute if entity @s[scores={PZWerkS.1Verz=5..}] positioned ~-4 ~ ~-4 run function werkzeug-system:v1ernten


Variante 1: Ernte-Funktion
Die Bereich-Stufen-Funktion ruft hierbei je nach Punktestandswert der Verzauberungsstufe des Spielers in einer Kaskade die Ernte-Funktion in verschiedenen Positionen auf (Diese wiederum erntet in einem 3 * 3 Bereich alle Feldfrüchte.), dadurch wird der Abernteradius nach und nach immer weiter angehoben.

  • Zeile 2 Der Aberntebefel arbeitet dabei mit einem Alias #werkzeug-system:v1pflanzen, das alle Feldfrüchte beinhaltet, damit die if-block-Bedingung nicht für alle Feldfrüchte einzeln geschrieben werden muss.
Editor Icon.png werkzeug-system:v1ernten.mcfunction
# Ein 3 * 3 Bereich wird geerntet, wenn sich vor Ort die Ackerpflanzen befinden.
execute if block ~1 ~ ~ #werkzeug-system:v1pflanzen run setblock ~1 ~ ~ minecraft:air destroy
execute if block ~ ~ ~ #werkzeug-system:v1pflanzen run setblock ~ ~ ~ minecraft:air destroy
execute if block ~-1 ~ ~ #werkzeug-system:v1pflanzen run setblock ~-1 ~ ~ minecraft:air destroy

execute if block ~1 ~ ~1 #werkzeug-system:v1pflanzen run setblock ~1 ~ ~1 minecraft:air destroy
execute if block ~ ~ ~1 #werkzeug-system:v1pflanzen run setblock ~ ~ ~1 minecraft:air destroy
execute if block ~-1 ~ ~1 #werkzeug-system:v1pflanzen run setblock ~-1 ~ ~1 minecraft:air destroy

execute if block ~1 ~ ~-1 #werkzeug-system:v1pflanzen run setblock ~1 ~ ~-1 minecraft:air destroy
execute if block ~ ~ ~-1 #werkzeug-system:v1pflanzen run setblock ~ ~ ~-1 minecraft:air destroy
execute if block ~-1 ~ ~-1 #werkzeug-system:v1pflanzen run setblock ~-1 ~ ~-1 minecraft:air destroy
JSON Icon.png werkzeug-system:v1pflanzen.json
{
  "values": [
    "minecraft:wheat",
    "minecraft:carrots",
    "minecraft:potatoes",
    "minecraft:beetroots"
  ]
}


Variante 1: Hacke-Haltbarkeit-Funktion
Die Hacke-Haltbarkeits-Funktion sorgt dafür, dass die verwendete Hacke ihre Haltbarkeit um eins verliert.

Editor Icon.png werkzeug-system:v1hacke_haltbarkeit.mcfunction
# Ein Drop wird direkt beim Spieler erzeugt, ohne das er aufgehoben werden kann. Der Drop erhält alle Daten der gehaltenen Hacke.
summon minecraft:item ~ ~ ~ {NoGravity:true,PickupDelay:32767s,Tags:["EtiWerkS.1Drop"],Item:{id:"minecraft:wooden_hoe",Count:1b} }
data modify entity @e[type=minecraft:item,tag=EtiWerkS.1Drop,sort=nearest,limit=1] Item set from entity @s SelectedItem

# Die aktuelle Haltbarkeit wird ausgelesen, in einen Punkte-Wert gespeichert und um eins erhöht und anschließend wieder in der Hacke gesepichert.
execute as @e[type=minecraft:item,tag=EtiWerkS.1Drop,sort=nearest,limit=1] store result score @s PZWerkS.1Haltb run data get entity @s Item.tag.Damage
execute as @e[type=minecraft:item,tag=EtiWerkS.1Drop,sort=nearest,limit=1] store result entity @s Item.tag.Damage int 1 run scoreboard players add @s PZWerkS.1Haltb 1

# Damit eventuell geerntete Feldfrüchte nicht den Slot der Hacke belegen wird ihre Aufhebezeit verlängert.
execute as @e[distance=..2,type=minecraft:item,tag=!EtiWerkS.1Drop] run data merge entity @s {PickupDelay:2s}

# Damit die neue Hacke an die Inventar-Position kommen kann, werden 35 Boote gegeben, die das Invetar füllen. Anschließend wird die Hacke im Inventarplatz gelöscht und die Drop-Hacke kann dann sofort aufgesammelt werden. Danach werden die Boote gelöscht.
give @s minecraft:oak_boat{EigWerkS.1InventarBelegen:true} 35
kill @e[distance=..2,type=minecraft:item,nbt={Item:{tag:{EigWerkS.1InventarBelegen:true} } }]
replaceitem entity @s weapon.mainhand minecraft:air
data merge entity @e[type=minecraft:item,tag=EtiWerkS.1Drop,sort=nearest,limit=1] {PickupDelay:0s}
clear @s minecraft:oak_boat{EigWerkS.1InventarBelegen:true}


Variante 1: Stopp-Funktion
Zuerst werden alle Punktestand-Ziele wieder entfernt.

Anschließend werden die noch eventuell im Inventar vorhandenen Hacken entfernt.

Alle Feldfrüchte und Samen werden aus dem Inventar entfernt.

Der Spieler wird anschließend in den Kreativmodus zurück versetzt

  • Zeile 26 Nur wenn man sich nicht im Kreativmodus befindet wird man in diesen gesetzt.

Hiernach werden alle Ackerböden samt Feldfrüchte entfernt

Als letztes werden die herumliegenden Feldfrüchte und eventuell herumliegenden Hacken entfernt

  • Zeile 35 gibt das Etikett für Weizen, Weizenkörner[Z36], Karotten[Z37], Kartoffeln[Z38], giftige Kartoffeln[Z39], rote Bete[Z40] und Rote-Bete-Samen[Z41].
  • Zeile 42 gibt das Etikett den Hacken.
  • Zeile 43 damit all diese Gegenstände anschließend gelöscht werden können.
Editor Icon.png werkzeug-system:v1stopp.mcfunction
# Punkte-Ziele werden entfernt.
scoreboard objectives remove PZWerkS.1Verz
scoreboard objectives remove PZWerkS.1Haltb

scoreboard objectives remove PZWerkS.1Weizen
scoreboard objectives remove PZWerkS.1Karotte
scoreboard objectives remove PZWerkS.1Kartoff
scoreboard objectives remove PZWerkS.1Bete

# Hacken werden entfernt.
clear @a minecraft:wooden_hoe{werzeug-system:"v1gegenstand"}
clear @a minecraft:stone_hoe{werzeug-system:"v1gegenstand"}
clear @a minecraft:iron_hoe{werzeug-system:"v1gegenstand"}
clear @a minecraft:golden_hoe{werzeug-system:"v1gegenstand"}
clear @a minecraft:diamond_hoe{werzeug-system:"v1gegenstand"}

clear @a[distance=..25] minecraft:wheat
clear @a[distance=..25] minecraft:wheat_seeds
clear @a[distance=..25] minecraft:carrot
clear @a[distance=..25] minecraft:potato
clear @a[distance=..25] minecraft:poisonous_potato
clear @a[distance=..25] minecraft:beetroot
clear @a[distance=..25] minecraft:beetroot_seeds

# Den Spielmodus auf Kreativ setzen.
gamemode creative @a[distance=..25,gamemode=!creative]

# Ackerboden und Karotten werden um die Befehlsquelle entfernt.
fill ~-16 ~1 ~-16 ~16 ~1 ~16 minecraft:air replace minecraft:carrots
fill ~-16 ~ ~-16 ~16 ~ ~16 minecraft:air replace minecraft:water
fill ~-16 ~ ~-16 ~16 ~ ~16 minecraft:air replace minecraft:dirt
fill ~-16 ~ ~-16 ~16 ~ ~16 minecraft:air replace minecraft:farmland

# Die herumliegenden Karotten werden entfernt.
tag @e[distance=..25,type=minecraft:item,nbt={Item:{id:"minecraft:wheat"} } ] add EtiWerkS.1Alle
tag @e[distance=..25,type=minecraft:item,nbt={Item:{id:"minecraft:wheat_seeds"} } ] add EtiWerkS.1Alle
tag @e[distance=..25,type=minecraft:item,nbt={Item:{id:"minecraft:carrot"} } ] add EtiWerkS.1Alle
tag @e[distance=..25,type=minecraft:item,nbt={Item:{id:"minecraft:potato"} } ] add EtiWerkS.1Alle
tag @e[distance=..25,type=minecraft:item,nbt={Item:{id:"minecraft:poisonous_potato"} } ] add EtiWerkS.1Alle
tag @e[distance=..25,type=minecraft:item,nbt={Item:{id:"minecraft:beetroot"} } ] add EtiWerkS.1Alle
tag @e[distance=..25,type=minecraft:item,nbt={Item:{id:"minecraft:beetroot_seeds"} } ] add EtiWerkS.1Alle
tag @e[distance=..25,type=minecraft:item,nbt={Item:{tag:{werzeug-system:"v1gegenstand"} } } ] add EtiWerkS.1Alle
kill @e[tag=EtiWerkS.1Alle]


Disambig color.svg
 
Grid Grasblock.png
Auch im Minecraft Wiki wird das Thema dieser Technik behandelt:
Werkzeug