Das offizielle Minecraft Wiki twittert hier: Wiki-Twitter  –  Chatte im Wiki-Discord  – Noch keinen Server gefunden? Es gibt einen Wiki-Server

Hi Gamepedia users and contributors! Please complete this survey to help us learn how to better meet your needs in the future. We have one for editors and readers. This should only take about 7 minutes!

Steinbruch-System (Befehle)

Aus Technik Wiki
(Weitergeleitet von Tunnelbohrer (Befehle))
Wechseln zu: Navigation, Suche
Gruppe: Grid Ketten-Befehlsblock.png
Systeme

Grid Roter Sand blass.png mit Mechaniken

Grid Redstone blass.png mit Redstone
                Hier:
Grid Befehlsblock.png mit Befehlen

Die vorgestellte Technik kann in der Schienen-Welt angesehen werden.

Das Steinbruch-System kann, wie der Name schon verrät, Tunnel in einen Berg bohren. Es kann meist von einem Spieler gesteuert werden, dafür muss dieser etwas Brennstoff aufwenden. Je nach Bauart bewegt er sich nur horizontal und kann nur durch die Schwerkraft nach unten gelangen, nicht aber nach oben. Beim Graben droppen die Blöcke und müssen vom Spieler aufgesammelt werden, das Steinbruch-System macht dies nicht von selbst.

Inhaltsverzeichnis

Variante 1[Bearbeiten | Quelltext bearbeiten]

Steinbruch-System (Befehle) Bild 1.1.png Steinbruch-System (Befehle) Bild 1.2.png Steinbruch-System (Befehle) Bild 1.3.png

Den Tunnelbohrer bekommt der Spieler als Rüstungsständer in die Hand und etwas Kohle. Man platziert den Rüstungsständer und es erscheinen zwei schwebende Diamantspitzhacken, die sich ausrichten, sobald der Spieler ein oder mehrere Kohle droppt. Dies füllt seine Bohrzeit auf und anschließend muss der Spieler hinter ihm her laufen und er baut automatisch in die Blickrichtung ein drei mal drei Feld ab. Die Blöcke die dabei droppen können vom Spieler aufgehoben werden.

Einschalten

Wenn man den Hebel auf dem Wiederhol-Befehlsblock umlegt wird auch der Befehlsblock aktiviert, welcher die Start-Funktion auslöst.

Wiederholen

Der Wiederhol-Befehlsblock aktiviert die Zyklus-Funktion jeden Tick, sodass sie ständig ausgeführt wird.

Ausschalten

Legt man den Hebel wieder um, so wird die Stopp-Funktion durch den Befehlsblock ausgelöst.


Befehlsblöcke mit Befehlen:



Variante 1: Start-Funktion
Die Start-Funktion erstellt ein Punktestand-Ziel das die Bohrzeit des Tunnelbohrers speichert und es wird eine Konstante mit dem Wert 1000 angelegt. Darüber hinaus erhält der Spieler einen speziellen Rüstungsständer und 64 Kohle. Als letztes wird ein Kubus aus Granit erstellt, wo der Tunnelbohrer eingesetzt werden kann.

Editor Icon.png technik_wiki:tunnelbohrer/v1start.mcfunction
# Punktestand-Ziel wird erstellt und die Konstante 1000
scoreboard objectives add PZTuBohr.1Bohr dummy ["Tunnelbohrer.1 ",{"text":"Bohrzeit","bold":true}]
scoreboard players set KonstTuBohr.1TAUSEND PZTuBohr.1Bohr 1000

# Der Rüstungsständer samt 64 Kohle werden den Spielern in einem Umkreis von 25 Blöcken gegeben
give @a[distance=..25] minecraft:armor_stand{Tunnelbohrer.1:true,display:{Lore:["Platziere den Rüstungsständer","damit der Bohrer","aufgebaut wird"]},EntityTag:{ShowArms:true,Invisible:true,HandItems:[{id:"minecraft:diamond_pickaxe",Count:1b},{id:"minecraft:diamond_pickaxe",Count:1b}],Tags:["EtiTuBohr.1Alle","EtiTuBohr.1Bohrer"]} }
give @a[distance=..25] minecraft:coal{Tunnelbohrer.1:true,display:{Lore:["Wirf die Kohle","dem Bohrer zu um","ihn zu starten"]} } 64

# Es wird eine Felswand aus Granit erstellt, die durchbohrt werden kann
fill ~20 ~ ~ ~40 ~20 ~20 minecraft:granite replace minecraft:air

Variante 1: Zyklus-Funktion
Die Zyklus-Funktion prüft ob Kohle in der Nähe des Tunnelbohrers gedroppt wurde und multipliziert die Anzahl der Kohlestücke mit Tausend und speichert dies als Bohrzeit im Tunnelbohrer, welche jeden Tick wieder um eins reduziert wird. Solange die Bohrzeit über null ist, kann er Bohrungen durchführen.

Editor Icon.png technik_wiki:tunnelbohrer/v1zyklus.mcfunction
# Wenn Kohle in der Nähe des Bohrers gedroppt wurde, wird ihr ein Etikett gegeben, damit es schneller identifiziert werden kann
execute as @e[type=minecraft:armor_stand,tag=EtiTuBohr.1Bohrer] at @s run tag @e[distance=..3,type=minecraft:item,tag=!EtiTuBohr.1Kohle,nbt={Item:{id:"minecraft:coal"} }] add EtiTuBohr.1Kohle

# Die Anzahl der Kohlestücke als Wert wird in den Punktestand gespeichert
execute as @e[type=minecraft:armor_stand,tag=EtiTuBohr.1Bohrer] at @s as @e[distance=..3,type=minecraft:item,tag=EtiTuBohr.1Kohle,sort=nearest,limit=1] store result score @s PZTuBohr.1Bohr run data get entity @s Item.Count

# Die Anzahl der Kohle wird mit dem Wert 1000 multipliziert und anschließend auf den Bohrer übertragen
execute as @e[type=minecraft:armor_stand,tag=EtiTuBohr.1Bohrer] at @s if entity @e[distance=..3,type=minecraft:item,tag=EtiTuBohr.1Kohle,sort=nearest,limit=1] store result score @s PZTuBohr.1Bohr run scoreboard players operation @e[distance=..3,type=minecraft:item,nbt={Item:{id:"minecraft:coal"} },sort=nearest,limit=1] PZTuBohr.1Bohr *= KonstTuBohr.1TAUSEND PZTuBohr.1Bohr

# Die in der Nähe des Bohrers gedroppte Kohle wird entfernt
execute as @e[type=minecraft:armor_stand,tag=EtiTuBohr.1Bohrer] at @s run kill @e[distance=..3,type=minecraft:item,tag=EtiTuBohr.1Kohle,sort=nearest,limit=1]

# Wenn der Spieler sich dem Bohrer nähert, und dieser noch einen Bohrwert über null besitzt, wird der Bohrer vorauseilen und in Blickrichtung ein Loch vor ihm graben
execute as @e[type=minecraft:armor_stand,tag=EtiTuBohr.1Bohrer,scores={PZTuBohr.1Bohr=1..}] at @s if entity @p[distance=..6] run fill ^1 ^ ^ ^-1 ^2 ^1 minecraft:air destroy
execute as @e[type=minecraft:armor_stand,tag=EtiTuBohr.1Bohrer,scores={PZTuBohr.1Bohr=1..}] at @s rotated as @p[distance=..6] rotated ~ 0 run teleport @s ^ ^ ^0.5 ~ ~

# Solange der Bohrer einen Wert von mindestens eins hat, werden Partikel angezeigt und jeden Tick wird der Wert um eins reduziert
execute at @e[type=minecraft:armor_stand,tag=EtiTuBohr.1Bohrer,scores={PZTuBohr.1Bohr=1..}] run particle minecraft:smoke ~ ~1 ~ 0 0 0 0.01 10 force @a[distance=..25]
scoreboard players remove @e[type=minecraft:armor_stand,tag=EtiTuBohr.1Bohrer,scores={PZTuBohr.1Bohr=1..}] PZTuBohr.1Bohr 1

Variante 1: Stopp-Funktion
Die Stopp-Funktion löscht das Punktestand-Ziel wieder, sowie die Gegenstände die für den Tunnelbohrer benötigt werden oder durch ihn gedroppt sind. Die Felswand aus Granit wird wieder entfernt und die Gegenstände die für die Bohraktion verwendet wurden und auf dem Boden liegen werden mit einem Etikett markiert und anschließend gelöscht.

Editor Icon.png technik_wiki:tunnelbohrer/v1stopp.mcfunction
# Das Punktestand-Ziel wird entfernt
scoreboard objectives remove PZTuBohr.1Bohr

# Alle Gegenstände die für das Bohren benötigt wurden oder entstanden sind, werden gelöscht
clear @a minecraft:armor_stand{Tunnelbohrer.1:true}
clear @a minecraft:coal{Tunnelbohrer.1:true}
clear @a[distance=..15] minecraft:granite

# Die Felswand aus Granit wird entfernt
fill ~18 ~ ~ ~39 ~20 ~20 minecraft:air replace minecraft:granite

# Die gedroppten Granit-Drops, sowie der Gegenstand für den Tunnelbohrer erhalten ein Etikett, sodass alle Objekte mit dem Etikett danach gelöscht werden
execute positioned ~18 ~-1 ~ run tag @e[dx=39,dy=20,dz=20,type=minecraft:item,nbt={Item:{id:"minecraft:granite"} } ] add EtiTuBohr.1Alle
tag @e[type=minecraft:item,nbt={Item:{tag:{Tunnelbohrer.1:true} } } ] add EtiTuBohr.1Alle
kill @e[tag=EtiTuBohr.1Alle]


Disambig color.svg