Technik Wiki
Registrieren
Advertisement
Gruppe: Grid Klebriger Kolben
Anlagen

Grid Roter Sand blass mit Mechaniken

Grid Redstone blass mit Redstone
                Hier:
Grid Befehlsblock mit Befehlen
Verfügbar in:
Wiki Redstone-Welt Redstone-Welt

Die Standort-Markierung wird verwendet um eine gut sichtbare Markierung an einem bestimmten Ort zu haben. Mit der Markierung kann man das Ende eines Parcours kennzeichnen, oder bestimmte Sperrbereiche oder Standort-Sensoren damit kenntlich machen. Sie kann auch für Zonen-Markierungen verwendet werden um einen Bauabschnitt eines Spielers anzuzeigen. Die Markierungen können Rechtecke, Kreise, Polygone oder andere geometrische Körper darstellen.

Variante 1[]

Standort-Markierung (Befehle) Bild 1.1

Mit dieser Standort-Markierung lassen sich Orte mit Kreisen oder Quadraten markieren. Diese kann man erzeugen, in dem man einen der beiden Rüstungsständer an dem entsprechenden Ort platziert. Um die Rüstungsständer herum werden dann die Partikel erzeugt.

Einschalten
  • Befehl 1.1 Allen Spielern in einem Umkreis von 15 Blöcken wird ein Rüstungsständer für Kreis-Markierungen gegeben.
  • Befehl 1.2 Allen Spielern in einem Umkreis von 15 Blöcken wird ein Rüstungsständer für Quadrat-Markierungen gegeben.
Wiederholen
  • Befehl 1.3 Der Kreis-Rüstungsständer wird um fünf Grad im Uhrzeigersinn gedreht.
  • Befehl 1.4 In fünf Meter der Blickrichtung des Kreis-Rüstungsständers folgend, werden zehn Totem-Partikel erzeugt.
  • Befehl 1.5 Der Quadrat-Rüstungsständer wird um 90 Grad gedreht.
  • Befehl 1.6 In fünf Metern dem Blickwinkel des Quadrat-Rüstungsständers folgend, werden zehn Totem-Partikel erzeugt. Die Ausdehnung hängt dabei vom Blickwinkel ab[B1.7].
Ausschalten
  • Befehl 1.8 Die Rüstungsständer im Inventar werden gelöscht.
  • Befehl 1.9 Falls die Rüstungsständer gedroppt wurden, erhalten sie ein Etikett, um danach entfernt werden zu können.
  • Befehl 1.10 Alle Rüstungsständer die platziert wurden oder als Drop herum liegen werden entfernt.

Befehlsblöcke mit Befehlen:
give @a[distance=..15] minecraft:armor_stand{EigStaMa.1Alle:true,display:{Name:'{"text":"Kreis","color":"green","bold":true}',Lore:['"Platziere den Rüstungsständer"','"um die Markierung zu erzeugen"']},EntityTag:{Small:true,Marker:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"Kreis","color":"green","bold":true}',Tags:["EtiStaMa.1Alle","EtiStaMa.1Kreis"]} }
give @a[distance=..15] minecraft:armor_stand{EigStaMa.1Alle:true,display:{Name:'{"text":"Quadrat","color":"green","bold":true}',Lore:['"Platziere den Rüstungsständer"','"um die Markierung zu erzeugen"']},EntityTag:{Small:true,Marker:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"Quadrat","color":"green","bold":true}',Tags:["EtiStaMa.1Alle","EtiStaMa.1Quadrat"],Rotation:[0.0f,0.0f]} }


execute as @e[type=minecraft:armor_stand,tag=EtiStaMa.1Kreis] at @s run teleport @s ~ ~ ~ ~5 0
execute at @e[type=minecraft:armor_stand,tag=EtiStaMa.1Kreis] run particle minecraft:totem_of_undying ^ ^0.5 ^5 0 0 0 0.1 10 force @a[distance=..25]
execute as @e[type=minecraft:armor_stand,tag=EtiStaMa.1Quadrat] at @s run teleport @s ~ ~ ~ ~90 0
execute as @e[type=minecraft:armor_stand,tag=EtiStaMa.1Quadrat,y_rotation=-135..135] unless entity @s[y_rotation=-45..45] at @s run particle minecraft:totem_of_undying ^ ^0.5 ^5.5 0 0 2 0.1 10 force @a[distance=..25]
execute as @e[type=minecraft:armor_stand,tag=EtiStaMa.1Quadrat,y_rotation=135..45] unless entity @s[y_rotation=-135..-45] at @s run particle minecraft:totem_of_undying ^ ^0.5 ^5.5 2 0 0 0.1 10 force @a[distance=..25]


clear @a minecraft:armor_stand{EigStaMa.1Alle:true}
tag @e[type=minecraft:item,nbt={Item:{tag:{EigStaMa.1Alle:true} } }] add EtiStaMa.1Alle
kill @e[tag=EtiStaMa.1Alle]

Variante 2[]

Standort-Markierung (Befehle) Bild 2.1

Mit Hilfe dieser Standort-Markierung lässt sich ein Polygon aufbauen, dass beliebig viele Ecken besitzen kann. Beim Start der Technik erhält man Polygon-Rüstungsständer die man platzieren kann. Wird nur einer platziert passiert sieht man das Polygon noch nicht, aber sobald mehrere solcher Eckpunkte existieren, werden Partikel in Form eines Polygons sichtbar. Man kann das Polygon jederzeit um eine weitere Ecke bereichern, jedoch sollte man darauf achten, dass man immer in der Nähe der Ecke eine neue Ecke platziert, die gerade vom Partikel angelaufen wird, damit die neue Ecke direkt danach angesteuert wird.

Einschalten
  • Befehl 2.1 Es wird ein Punkte-Ziel erstellt, dass die Anzahl der Ecken-Rüstungsständer speichern wird.
  • Befehl 2.2 Allen Spielern in einem Umkreis von 15 Blöcken werden 16 Rüstungsständer für die Ecken des Polygons gegeben.
Wiederholen
  • Befehl 2.3 Wenn es einen neuen Ecken-Rüstungsständer gibt, der noch keinen Wert besitzt, wird zuerst die maximale Eckenanzahl ermittelt und in eine Variable gespeichert. Anschließend bekommt der Rüstungsständer eine neue Nummer.
  • Befehl 2.4 Wenn es keinen Partikel-Markierer gibt, wird an der Position des ersten Ecken-Rüstungsständers ein Partikel-Markierer erzeugt.
  • Befehl 2.5 Der Partikel-Markierer bewegt sich immer zu dem Ecken-Rüstungsständer, der aktuell den Wert eins besitzt.
  • Befehl 1.6 Wenn der Partikel-Markierer den Ecken-Rüstungsständer erreicht hat, wird bei allen Ecken-Rüstungsständer der Wert um eins erhöht und bei dem jenigen bei dem der Wert größer als die maximale Anzahl ist, wird er wieder auf eins gesetzt[B1.7].
  • Befehl 2.8 An der Position des Partikel-Markierer werden Totem-Partikel erzeugt und der Ecken-Rüstungsständer der den Wert eins hat, ebenfalls[B2.9].
Ausschalten
  • Befehl 2.10 Das Punkte-Ziel wird entfernt.
  • Befehl 2.11 Die Rüstungsständer im Inventar werden gelöscht.
  • Befehl 2.12 Falls die Rüstungsständer aus dem Inventar geworfen wurden, erhalten sie ein Etikett, um danach entfernt werden zu können.
  • Befehl 2.13 Der Markierer und alle Rüstungsständer die platziert wurden oder als Drop herum liegen, werden entfernt.

Befehlsblöcke mit Befehlen:
scoreboard objectives add PZStaMa.2Nr dummy ["Standort-Markierung.2: ",{"text":"Eckpunkt-Nummer","bold":true}]
give @a[distance=..15] minecraft:armor_stand{EigStaMa.2Alle:true,display:{Name:'{"text":"Polygon","color":"yellow","bold":true}',Lore:['"Platziere mehrere Rüstungsständer"','"um ein Poligon zu erhalten"']},EntityTag:{Small:true,Marker:true,Invisible:true,NoGravity:true,CustomNameVisible:true,CustomName:'{"text":"Polygon","color":"yellow","bold":true}',Tags:["EtiStaMa.2Alle","EtiStaMa.2Eckpunkt"]} } 16


execute as @e[type=minecraft:armor_stand,tag=EtiStaMa.2Eckpunkt] unless score @s PZStaMa.2Nr matches 0.. store result score PZStaMa.2MaxEckpunkte PZStaMa.2Nr store result score @s PZStaMa.2Nr run scoreboard players add PZStaMa.2Nr PZStaMa.2Nr 1
execute unless entity @e[type=minecraft:marker,tag=EtiStaMa.2Partikel,sort=nearest,limit=1] at @e[type=minecraft:armor_stand,tag=EtiStaMa.2Eckpunkt,scores={PZStaMa.2Nr=1},sort=nearest,limit=1] run summon minecraft:marker ~ ~ ~ {Tags:["EtiStaMa.2Alle","EtiStaMa.2Partikel"]}
execute as @e[type=minecraft:marker,tag=EtiStaMa.2Partikel] at @s run teleport @s ^ ^ ^0.3 facing entity @e[type=minecraft:armor_stand,tag=EtiStaMa.2Eckpunkt,scores={PZStaMa.2Nr=1},sort=nearest,limit=1]
execute as @e[type=minecraft:marker,tag=EtiStaMa.2Partikel] at @s if entity @e[distance=..0.3,type=minecraft:armor_stand,tag=EtiStaMa.2Eckpunkt,scores={PZStaMa.2Nr=1},sort=nearest,limit=1] run scoreboard players add @e[type=minecraft:armor_stand,tag=EtiStaMa.2Eckpunkt] PZStaMa.2Nr 1
execute as @e[type=minecraft:armor_stand,tag=EtiStaMa.2Eckpunkt] if score @s PZStaMa.2Nr > PZStaMa.2MaxEckpunkte PZStaMa.2Nr run scoreboard players set @s PZStaMa.2Nr 1
execute at @e[type=minecraft:marker,tag=EtiStaMa.2Partikel,sort=nearest,limit=1] run particle minecraft:totem_of_undying ~ ~ ~ 0 0 0 0.1 10 force @a[distance=..25]
execute at @e[type=minecraft:armor_stand,tag=EtiStaMa.2Eckpunkt,scores={PZStaMa.2Nr=1},sort=nearest,limit=1] run particle minecraft:totem_of_undying ~ ~ ~ 0 0.2 0 0.1 10 force @a[distance=..25]


scoreboard objectives remove PZStaMa.2Nr
clear @a minecraft:armor_stand{EigStaMa.2Alle:true}
tag @e[type=minecraft:item,nbt={Item:{tag:{EigStaMa.2Alle:true} } }] add EtiStaMa.2Alle
kill @e[tag=EtiStaMa.2Alle]

Variante 3[]

Standort-Markierung (Befehle) Bild 3.1

Diese Standort-Markierung bietet dem Spieler die Möglichkeit, beliebig einstellbar große Kreise zu erzeugen. Man platziert dazu Rüstungsständer und wählt zuvor im Chat eine der Größen für den Radius aus. Die Rüstungsständer bilden das Zentrum um die die Partikel kreisen.

Einschalten
Wiederholen
Ausschalten

Befehlsblöcke mit Befehlen:


Datenpaket


Variante 3: Start-Funktion
Die Start-Funktion erstellt das Punkte-Ziel für das Auslösen im Chat und gibt den Spielern den Kreis-Rüstungsständer.

Editor Icon standort-markierung:v3start.mcfunction
# Das Punkte-Ziel wird erstellt und die Variable gesetzt.
scoreboard objectives add PZStaMa.3Wert trigger ["Standort-Markierung.3: ",{"text":"Wert der Variablen","bold":true}]
scoreboard players set VarStaMa.3Variable PZStaMa.3Wert 5

# Spieler in einem Umkreis von 15 Blöcken erhalten einen Rüstungsständer.
give @a[distance=..15] minecraft:armor_stand{EigStaMa.3Alle:true,display:{Name:'{"text":"Kreis","color":"green","bold":true}',Lore:['"Platziere den Rüstungsständer"','"um eine Markierung zu setzen."','"Um im Chat-Menü"','"Werte zu ändern"','"wähle diesen Rüstungsständer aus."']},EntityTag:{Small:true,Invisible:true,NoGravity:true,CustomNameVisible:true,CustomName:'{"text":"Kreis","color":"green","bold":true}',Tags:["EtiStaMa.3Alle","EtiStaMa.3Zone"]} }


Variante 3: Zyklus-Funktion
Die Zyklus-Funktion ruft die Auslöser-Funktion auf, sofern der Spieler den Rüstungsständer auswählt und sie ruft die Zonen-Funktion auf, die die Markierung erzeugt.

Editor Icon standort-markierung:v3zyklus.mcfunction
# Spieler die den Rüstungsständer in der Schnellleiste ausgewählt haben, erhalten ein Etikett.
tag @a[nbt={SelectedItem:{tag:{EigStaMa.3Alle:true} } }] add EtiStaMa.3Ausgewaehlt

# Damit Spieler beim Auswählen des Rüstungsständers die Auslöser-Nachricht erhalten, wird ihnen ein Wert ohne weitere Funktion gegeben.
scoreboard players set @a[tag=EtiStaMa.3Ausgewaehlt,tag=!EtiStaMa.3Auswahl] PZStaMa.3Wert -99

# Wenn der Spieler den Rüstungsständer ausgewählt hat und nicht den Wert null besitzt, wird die Auslöser-Funktion durch ihn aufgerufen.
execute as @a[tag=EtiStaMa.3Ausgewaehlt] unless entity @s[scores={PZStaMa.3Wert=0}] run function standort-markierung:v3ausloeser

# Je nach Auswahl wird dem Spieler das Etikett gegeben oder genommen.
tag @a[tag=EtiStaMa.3Ausgewaehlt,tag=!EtiStaMa.3Auswahl] add EtiStaMa.3Auswahl
tag @a[tag=!EtiStaMa.3Ausgewaehlt,tag=EtiStaMa.3Auswahl] remove EtiStaMa.3Auswahl

# Das Etikett wird wieder entfernt.
tag @a[tag=EtiStaMa.3Ausgewaehlt] remove EtiStaMa.3Ausgewaehlt

# Vom Rüstungsständer aus, wird die Zonen-Funktion aufgerufen.
execute as @e[type=minecraft:armor_stand,tag=EtiStaMa.3Zone] at @s run function standort-markierung:v3zone


Variante 3: Auslöser-Funktion
Die Auslöser-Funktion gibt dem Spieler im Chat die Optionen aus, die er hat um die Größe des Kreises zu bestimmen.

Editor Icon standort-markierung:v3ausloeser.mcfunction
# Wenn der Spieler eine der fünf einstellbaren Werte ausgelöst hat, wird sein Wert in den der Variable gespeichert.
execute if entity @s[scores={PZStaMa.3Wert=5..30}] run scoreboard players operation VarStaMa.3Variable PZStaMa.3Wert = @s PZStaMa.3Wert

# Der Spieler erhält im Chat alle möglichen Werte zur Auswahl und kann auf diese klicken um sie einzustellen.
tellraw @s ["Standort-Markierung.3:\n",{"text":"radius = ","bold":true},{"text":"wert_5","color":"gray","bold":true,"underlined":true,"hoverEvent":{"action":"show_text","contents":{"text":"Tippe für den Wert 5"} },"clickEvent":{"action":"run_command","value":"/trigger PZStaMa.3Wert set 5"} },"\n",{"text":"radius = ","bold":true},{"text":"wert_10","color":"gray","bold":true,"underlined":true,"hoverEvent":{"action":"show_text","contents":{"text":"Tippe für den Wert 10"} },"clickEvent":{"action":"run_command","value":"/trigger PZStaMa.3Wert set 10"} },"\n",{"text":"radius = ","bold":true},{"text":"wert_15","color":"gray","bold":true,"underlined":true,"hoverEvent":{"action":"show_text","contents":{"text":"Tippe für den Wert 15"} },"clickEvent":{"action":"run_command","value":"/trigger PZStaMa.3Wert set 15"} },"\n",{"text":"radius = ","bold":true},{"text":"wert_20","color":"gray","bold":true,"underlined":true,"hoverEvent":{"action":"show_text","contents":{"text":"Tippe für den Wert 20"} },"clickEvent":{"action":"run_command","value":"/trigger PZStaMa.3Wert set 20"} },"\n",{"text":"radius = ","bold":true},{"text":"wert_25","color":"gray","bold":true,"underlined":true,"hoverEvent":{"action":"show_text","contents":{"text":"Tippe für den Wert 25"} },"clickEvent":{"action":"run_command","value":"/trigger PZStaMa.3Wert set 25"} },"\n",{"text":"radius = ","bold":true},{"text":"wert_30","color":"gray","bold":true,"underlined":true,"hoverEvent":{"action":"show_text","contents":{"text":"Tippe für den Wert 30"} },"clickEvent":{"action":"run_command","value":"/trigger PZStaMa.3Wert set 30"} },"\n",{"text":"radius == ","bold":true},{"text":"wert_","color":"dark_purple","bold":true},{"score":{"name":"VarStaMa.3Variable","objective":"PZStaMa.3Wert"},"color":"dark_purple","bold":true}]

# Der Spieler erhält die Berechtigung den Auslöser zu betätigen und sein Wert wird wieder auf null gesetzt.
scoreboard players enable @s PZStaMa.3Wert
scoreboard players set @s PZStaMa.3Wert 0


Variante 3: Zonen-Funktion
Die Zonen-Funktion speichert die Größe des Kreises und ruft die Partikel-Funktion auf. Ebenfalls wird der Rüstungsständer um das Zentrum gedreht.

Editor Icon standort-markierung:v3zone.mcfunction
# Wenn der Rüstungsständer noch keinen Wert besitzt, erhält er den, der zuletzt vom Spieler eingestellt wurde.
execute unless score @s PZStaMa.3Wert matches 0.. run scoreboard players operation @s PZStaMa.3Wert = VarStaMa.3Variable PZStaMa.3Wert

# Die Variable für die Meter wie weit die Partikel-Funktion gehen soll, wird auf null gesetzt und im Anschluss wird die Funktion geladen. Beim zweiten Aufruf wird dies um 180° gedreht durchgeführt.
scoreboard players set VarStaMa.3Meter PZStaMa.3Wert 0
execute positioned ^ ^ ^5 run function standort-markierung:v3zone_partikel

scoreboard players set VarStaMa.3Meter PZStaMa.3Wert 0
execute rotated ~180 0 positioned ^ ^ ^5 run function standort-markierung:v3zone_partikel

# Der Rüstungsständer wird um drei Grad im Uhrzeigersinn rotiert.
teleport @s ~ ~ ~ ~3 0


Variante 3: Zonen-Partikel-Funktion
Die Zonen-Partikel-Funktion läuft solange vom Zentrum weg, bis sie den gewünschten Abstand erreicht und lässt dann die Partikel erscheinen.

Editor Icon standort-markierung:v3zone_partikel.mcfunction
# Die Variable wird hochgezählt und anschließend wird geprüft ob sie gleich dem Wert der Reichweite entspricht, sodass Partikel entstehen, ansonsten wird die Partikel-Funktion in Blickrichtung um einen Meter nach vorne erneut aufgerufen.
scoreboard players add VarStaMa.3Meter PZStaMa.3Wert 5
execute if score VarStaMa.3Meter PZStaMa.3Wert = @s PZStaMa.3Wert run particle minecraft:totem_of_undying ~ ~ ~ 0 0 0 0.1 10 force @a[distance=..50]
execute if score VarStaMa.3Meter PZStaMa.3Wert <= @s PZStaMa.3Wert positioned ^ ^ ^5 run function standort-markierung:v3zone_partikel


Variante 3: Stopp-Funktion
Die Stopp-Funktion löscht das Punkte-Ziel und die Rüstungsständer wieder.

Editor Icon standort-markierung:v3stopp.mcfunction
# Das Punkte-Ziel wird gelöscht.
scoreboard objectives remove PZStaMa.3Wert

# Das Etikett wird entfernt.
tag @a[tag=EtiStaMa.3Auswahl] remove EtiStaMa.3Auswahl

# Die Rüstungsständer werden aus dem Inventar gelöscht, sowie auf dem Boden als Drop und Objekt.
clear @a minecraft:armor_stand{EigStaMa.3Alle:true}
tag @e[type=minecraft:item,nbt={Item:{tag:{EigStaMa.3Alle:true} } }] add EtiStaMa.3Alle
kill @e[tag=EtiStaMa.3Alle]

Variante 4[]

Standort-Markierung (Befehle) Bild 4.1

Diese Standort-Markierung ermöglicht das dynamische festlegen von Quadraten. Die Quadrat-Größe lässt sich im Chat einstellen und danach muss man den Rüstungsständer in der Welt platzieren und das Quadrat entsteht dort mit der entsprechenden Größe.

Einschalten
Wiederholen
Ausschalten

Befehlsblöcke mit Befehlen:


Datenpaket


Variante 4: Start-Funktion
Die Start-Funktion erstellt ein Auslöser-Punkte-Ziel und gibt den Spielern die Quadrate-Rüstungsständer.

Editor Icon standort-markierung:v4start.mcfunction
# Das Punkte-Ziel wird erstellt und die Variablen gesetzt.
scoreboard objectives add PZStaMa.4Wert trigger ["Standort-Markierung.4: ",{"text":"Wert der Variablen","bold":true}]
scoreboard players set VarStaMa.4Variable PZStaMa.4Wert 5
scoreboard players set KonstStaMa.4MINUSEINS PZStaMa.4Wert -1

# Spieler in einem Umkreis von 15 Blöcken erhalten einen Rüstungsständer.
give @a[distance=..15] minecraft:armor_stand{EigStaMa.4Alle:true,display:{Name:'{"text":"Quadrat","color":"green","bold":true}',Lore:['"Platziere den Rüstungsständer"','"um eine Markierung zu setzen."','"Um im Chat-Menü"','"Werte zu ändern"','"wähle diesen Rüstungsständer aus."']},EntityTag:{Small:true,Invisible:true,NoGravity:true,CustomNameVisible:true,CustomName:'{"text":"Quadrat","color":"green","bold":true}',Tags:["EtiStaMa.4Alle","EtiStaMa.4Zone"]} }


Variante 4: Zyklus-Funktion
Die Zyklus-Funktion ruft die Auslöser-Funktion auf, wenn der Spieler den Rüstungsständer ausgewählt hat und ruft vom Zonen-Rüstungsständer die Zonen-Funktion auf.

Editor Icon standort-markierung:v4zyklus.mcfunction
# Alle Spieler die den Rüstungsständer in der Schnellleiste ausgewählt haben, erhalten ein Etikett.
tag @a[nbt={SelectedItem:{tag:{EigStaMa.4Alle:true} } }] add EtiStaMa.4Ausgewaehlt

# Damit die Spieler eine Nachricht im Chat erhalten bekommen sie einen funktionslosen Wert zugewiesen.
scoreboard players set @a[tag=EtiStaMa.4Ausgewaehlt,tag=!EtiStaMa.4Auswahl] PZStaMa.4Wert -99

# Wenn der Spieler den Rüstungsständer ausgewählt hat und nicht den Wert null besitzt, wird die Auslöser-Funktion durch ihn aufgerufen.
execute as @a[tag=EtiStaMa.4Ausgewaehlt] unless entity @s[scores={PZStaMa.4Wert=0}] run function standort-markierung:v4ausloeser

# Je nach dem ob man den Rüstungsständer ausgewählt hat oder nicht wird das Etikett gegeben oder entfernt.
tag @a[tag=EtiStaMa.4Ausgewaehlt,tag=!EtiStaMa.4Auswahl] add EtiStaMa.4Auswahl
tag @a[tag=!EtiStaMa.4Ausgewaehlt,tag=EtiStaMa.4Auswahl] remove EtiStaMa.4Auswahl

# Das Etikett wird wieder entfernt, damit es nur vorhanden ist, wenn der Rüstungsständer ausgewählt wurde.
tag @a[tag=EtiStaMa.4Ausgewaehlt] remove EtiStaMa.4Ausgewaehlt

# Wenn der Rüstungsständer noch keinen Wert besitzt, erhält er den, der zuletzt vom Spieler eingestellt wurde.
execute as @e[type=minecraft:armor_stand,tag=EtiStaMa.4Zone] unless score @s PZStaMa.4Wert matches 0.. run scoreboard players operation @s PZStaMa.4Wert = VarStaMa.4Variable PZStaMa.4Wert

# Vom Rüstungsständer aus, wird die Zonen-Funktion aufgerufen.
execute as @e[type=minecraft:armor_stand,tag=EtiStaMa.4Zone] at @s run function standort-markierung:v4zone


Variante 4: Auslöser-Funktion
Die Auslöser-Funktion zeigt dem Spieler im Chat, welche Größen das Quadrat haben kann und welche er einstellen kann.

Editor Icon standort-markierung:v4ausloeser.mcfunction
# Wenn der Spieler eine der fünf einstellbaren Werte ausgelöst hat, wird sein Wert in den der Variable gespeichert.
execute if entity @s[scores={PZStaMa.4Wert=5..30}] run scoreboard players operation VarStaMa.4Variable PZStaMa.4Wert = @s PZStaMa.4Wert

# Der Spieler erhält im Chat alle möglichen Werte zur Auswahl und kann auf diese klicken um sie einzustellen.
tellraw @s ["Standort-Markierung.4:\n",{"text":"quadrat = ","bold":true},{"text":"wert_5","color":"gray","bold":true,"underlined":true,"hoverEvent":{"action":"show_text","contents":{"text":"Tippe für den Wert 5"} },"clickEvent":{"action":"run_command","value":"/trigger PZStaMa.4Wert set 5"} },"\n",{"text":"quadrat = ","bold":true},{"text":"wert_10","color":"gray","bold":true,"underlined":true,"hoverEvent":{"action":"show_text","contents":{"text":"Tippe für den Wert 10"} },"clickEvent":{"action":"run_command","value":"/trigger PZStaMa.4Wert set 10"} },"\n",{"text":"quadrat = ","bold":true},{"text":"wert_15","color":"gray","bold":true,"underlined":true,"hoverEvent":{"action":"show_text","contents":{"text":"Tippe für den Wert 15"} },"clickEvent":{"action":"run_command","value":"/trigger PZStaMa.4Wert set 15"} },"\n",{"text":"quadrat = ","bold":true},{"text":"wert_20","color":"gray","bold":true,"underlined":true,"hoverEvent":{"action":"show_text","contents":{"text":"Tippe für den Wert 20"} },"clickEvent":{"action":"run_command","value":"/trigger PZStaMa.4Wert set 20"} },"\n",{"text":"quadrat = ","bold":true},{"text":"wert_25","color":"gray","bold":true,"underlined":true,"hoverEvent":{"action":"show_text","contents":{"text":"Tippe für den Wert 25"} },"clickEvent":{"action":"run_command","value":"/trigger PZStaMa.4Wert set 25"} },"\n",{"text":"quadrat = ","bold":true},{"text":"wert_30","color":"gray","bold":true,"underlined":true,"hoverEvent":{"action":"show_text","contents":{"text":"Tippe für den Wert 30"} },"clickEvent":{"action":"run_command","value":"/trigger PZStaMa.4Wert set 30"} },"\n",{"text":"quadrat == ","bold":true},{"text":"wert_","color":"dark_purple","bold":true},{"score":{"name":"VarStaMa.4Variable","objective":"PZStaMa.4Wert"},"color":"dark_purple","bold":true}]

# Der Spieler erhält die Berechtigung den Auslöser zu betätigen und sein Wert wird wieder auf null gesetzt.
scoreboard players enable @s PZStaMa.4Wert
scoreboard players set @s PZStaMa.4Wert 0


Variante 4: Zonen-Funktion
Die Zonen-Funktion wird vom Rüstungsständer aufgerufen und sorgt dafür, dass die Abstands-Funktionen jeweils um 90 Grad rotiert von einander aufgerufen werden.

Editor Icon standort-markierung:v4zone.mcfunction
# Die Variable wird um eins erhöht um die Rekursion zu zählen.
scoreboard players add VarStaMa.4Zahl PZStaMa.4Wert 1

# Der Abstands-Wert für die Diagonale wird auf null gesetzt und die Längen-Variable erhält die aktuelle Größe als Wert um anschließend sie zu negieren. Daraufhin wird die Abstands-Funktion geladen, die dafür sorgt, dass eine der vier Eckpunkte über die Diagonalen erreicht wird.
scoreboard players set VarStaMa.4Abstand PZStaMa.4Wert 0
scoreboard players operation VarStaMa.4Laenge PZStaMa.4Wert = @s PZStaMa.4Wert
scoreboard players operation VarStaMa.4Laenge PZStaMa.4Wert *= KonstStaMa.4MINUSEINS PZStaMa.4Wert
execute positioned ^5 ^ ^-5 run function standort-markierung:v4zone_abstand

# Die Funktion ruft sich selbst auf, dabei wird die Ausrichtung um 90° gedreht.
execute if score VarStaMa.4Zahl PZStaMa.4Wert matches 1..3 rotated ~90 0 run function standort-markierung:v4zone
execute if score VarStaMa.4Zahl PZStaMa.4Wert matches 4.. run scoreboard players set VarStaMa.4Zahl PZStaMa.4Wert 0


Variante 4: Zonen-Abstands-Funktion
Die Zonen-Abstands-Funktion bewegt sich durch Selbstaufruf diagonal an die Ecke, von wo aus die Partikel-Funktion gestartet wird.

Editor Icon standort-markierung:v4zone_abstand.mcfunction
# Die Abstands-Variable wird um fünf erhöht.
scoreboard players add VarStaMa.4Abstand PZStaMa.4Wert 5

# Sobald die Variable gleich dem Wert der Einstellung entspricht, wird die Partikel-Funktion geladen, ansonsten wird die Abstands-Funktion erneut geladen, sofern der Wert kleiner ist.
execute if score VarStaMa.4Abstand PZStaMa.4Wert = @s PZStaMa.4Wert run function standort-markierung:v4zone_partikel
execute if score VarStaMa.4Abstand PZStaMa.4Wert < @s PZStaMa.4Wert positioned ^5 ^ ^-5 run function standort-markierung:v4zone_abstand


Variante 4: Zonen-Partikel-Funktion
Die Zonen-Partikel-Funktion erzeugt auf dem Weg ständig Partikel. sie ruft sich solange erneut auf, bis der Längen-Wert nicht mehr kleiner der Gesamtlänge ist.

Editor Icon standort-markierung:v4zone_partikel.mcfunction
# Der Totem-Partikel wird erzeugt.
particle minecraft:totem_of_undying ~ ~ ~ 0 0 0 0.1 3 force @a[distance=..50]

# Die Längen-Variable wird um eins erhöht und anschließend wird geprüft ob diese kleiner als die maximale Länge ist. solange das der Fall ist, wird die Partikel-Funktion erneut selbst aufgerufen.
scoreboard players add VarStaMa.4Laenge PZStaMa.4Wert 1
execute if score VarStaMa.4Laenge PZStaMa.4Wert < @s PZStaMa.4Wert positioned ^ ^ ^1 run function standort-markierung:v4zone_partikel


Variante 4: Stopp-Funktion
Die Stopp-Funktion löscht das Punkte-ziel wieder und alle Rüstungsständer im Inventar, als Drop oder als Objekt in der Welt.

Editor Icon standort-markierung:v4stopp.mcfunction
# Das Punkte-Ziel wird gelöscht.
scoreboard objectives remove PZStaMa.4Wert

# Das Etikett wird entfernt.
tag @a[tag=EtiStaMa.4Auswahl] remove EtiStaMa.4Auswahl

# Die Rüstungsständer werden aus dem Inventar gelöscht, sowie auf dem Boden als Drop und Objekt.
clear @a minecraft:armor_stand{EigStaMa.4Alle:true}
tag @e[type=minecraft:item,nbt={Item:{tag:{EigStaMa.4Alle:true} } }] add EtiStaMa.4Alle
kill @e[tag=EtiStaMa.4Alle]


Disambig color
Advertisement