Das offizielle Minecraft Wiki twittert hier: Wiki-Twitter  –  Chatte im Wiki-Discord  – Noch keinen Server gefunden? Es gibt einen Wiki-Server

Hi Gamepedia users and contributors! Please complete this survey to help us learn how to better meet your needs in the future. We have one for editors and readers. This should only take about 7 minutes!

Sprungfeld (Befehle)

Aus Technik Wiki
Wechseln zu: Navigation, Suche
Gruppe: Grid Schleimblock.png
Verkehrsanlagen

Grid Roter Sand blass.png mit Mechaniken

Grid Redstone.png mit Redstone
                Hier:
Grid Befehlsblock.png mit Befehlen

Die vorgestellte Technik kann in der Mechanik-Welt angesehen werden.

Sprungfelder ermöglichen den Spielern insbesondere in Lobbies auf Minispielen das schnellere Reisen von einem Ort zum anderen.

Inhaltsverzeichnis

Variante 1[Bearbeiten | Quelltext bearbeiten]

Roter Sand.png
Diese neue oder überarbeitete Technik ist noch nicht in der aktuellen Mechanik-Welt vorhanden.
In einem der nächsten Updates wird sie dort hinzugefügt werden.

Sprungfeld (Befehle) Bild 1.1.png Sprungfeld (Befehle) Bild 1.2.png

Das Sprungfeld katapultiert Spieler einige Meter weit nach vorne, wenn diese auf dieses laufen. Es kann mit Hilfe von Rüstungsständern platziert werden.

Einschalten

Beim Einschalten wird ein Punktestand-Ziel erstellt und Rüstungsständer für die Sprungfelder ins Inventar gelegt.

  • Befehl 1.1 Das Punktestand-Ziel für die Zeit die der Spieler in der Luft verbringt, wird erstellt.
  • Befehl 1.2 Es wird in die Inventare der Spieler in einem Umkreis von 15 Metern, 16 Rüstungsständer gelegt. Diese können platziert werden um Sprungfelder zu erstellen.
Wiederholen

Spieler die auf Sprungfelder laufen werden in die Lüfte katapultiert und erhalten Schutzeffekte beim Landen. An der Position von platzierten Sprungfeldern wird sichergestellt, dass sich dort Sprungfeldblöcke aufhalten.

  • Befehl 1.3 Wenn ein Spieler sich auf einem Sprungfeld befindet, erhält er den Wert null, damit er später bestimmte Effekte bekommt.
  • Befehl 1.4 Damit die Statuseffekte exakt nur solange wirken wie der Spieler sie auch besitzen soll, werden ihm sämtliche Effekte entfernt, wenn er mindestens einen Tick in der Luft ist.
  • Befehl 1.5 Spieler die den Wert null besitzen, erhalten den Effekt Schwebekraft.
  • Befehl 1.6 Ebenfalls erhalten Spieler dann auch den Geschwindigkeitseffekt.
  • Befehl 1.7 Solange Spieler sich in der Luft aufhalten (Wert mindestens bei eins) wird ihnen der Schutz-Effekt gegeben, damit sie keinen Fallschaden erleiden, wenn sie wieder auf den Boden aufkommen.
  • Befehl 1.8 Spieler die auf das Sprungfeld gestiegen sind besitzen mindestens den Wert null und dieser wird jeden Tick um eins erhöht, solange sich dieser nicht über 200 befindet.
  • Befehl 1.9 Wenn Spieler die das Sprungfeld benutzt haben, mindestens vier Ticks in der Luft waren, wieder den Boden erreicht haben, erhalten den Wert minus eins, damit wird signalisiert, das sie nicht in der Luft sind.
  • Befehl 1.10 An der Position des Rüstungsständers wird überprüft ob sich dort ein Redstone-Block befindet, andernfalls wird dieser dort platziert.
  • Befehl 1.11 Ebenfalls wird an der Position des Rüstungsständers überprüft ob sich dort auch eine goldene Wägeplatte aufhält, auch hier wird sie platziert, wenn sich dort keine befindet.
Ausschalten

Das Punktestand-Ziel wird gelöscht und alle Sprungfelder, sowie die Gegenstände werden entfernt.

  • Befehl 1.12 Das Punktestand-Ziel wird gelöscht.
  • Befehl 1.13 An der Position der Rüstungsständer werden die zwei Sprungfeldblöcke durch Luft ersetzt.
  • Befehl 1.14 Falls Gegenstände auf den Boden gedroppt wurden, erhalten sie ein Etikett.
  • Befehl 1.15 Alle Rüstungsständer oder Gegenstände für die Sprungfelder werden gelöscht.
  • Befehl 1.16 Wenn noch Gegenstände für Sprungfelder im Inventar von Spielern sich noch dort befinden, werden sie gelöscht.

Befehlsblöcke mit Befehlen:
scoreboard objectives add PZSprFe.1Luft dummy ["Sprungfeld.1: ",{"text":"Zeit in der Luft","bold":true}]
give @a[distance=..15] minecraft:armor_stand{sprungfeld:"v1gegenstand",display:{Name:'{"text":"Sprungfeld","color":"red","bold":true}',Lore:['"Platziere den Rüstungsständer"','"auf dem Boden um"','"ein Sprungfeld zu erhalten"']},EntityTag:{Invisible:true,NoGravity:true,CustomNameVisible:true,CustomName:'{"text":"Sprungfeld","color":"red","bold":true}',Tags:["EtiSprFe.1Alle","EtiSprFe.1Sprungfeld"] } } 16


execute as @a[distance=..50] at @s if block ~ ~ ~ minecraft:light_weighted_pressure_plate[power=1] if block ~ ~-1 ~ minecraft:redstone_block run scoreboard players set @s PZSprFe.1Luft 0
effect clear @a[scores={PZSprFe.1Luft=1..}]
effect give @a[scores={PZSprFe.1Luft=0}] minecraft:levitation 4 127 true
effect give @a[scores={PZSprFe.1Luft=0}] minecraft:speed 1 255 true
effect give @a[scores={PZSprFe.1Luft=1..}] minecraft:resistance 1 255 true
scoreboard players add @a[scores={PZSprFe.1Luft=0..200}] PZSprFe.1Luft 1
scoreboard players set @a[scores={PZSprFe.1Luft=4..},nbt={OnGround:true}] PZSprFe.1Luft -1
execute at @e[type=minecraft:armor_stand,tag=EtiSprFe.1Sprungfeld] unless block ~ ~ ~ minecraft:redstone_block run setblock ~ ~ ~ minecraft:redstone_block replace
execute at @e[type=minecraft:armor_stand,tag=EtiSprFe.1Sprungfeld] unless block ~ ~1 ~ minecraft:light_weighted_pressure_plate run setblock ~ ~1 ~ minecraft:light_weighted_pressure_plate replace


scoreboard objectives remove PZSprFe.1Luft
execute at @e[type=minecraft:armor_stand,tag=EtiSprFe.1Sprungfeld] run fill ~ ~1 ~ ~ ~ ~ minecraft:air replace
tag @e[type=minecraft:item,nbt={Item:{tag:{sprungfeld:"v1gegenstand"} } }] add EtiSprFe.1Alle
kill @e[tag=EtiSprFe.1Alle]
clear @a minecraft:armor_stand{sprungfeld:"v1gegenstand"}