Technik Wiki
Registrieren
Advertisement
Gruppe: Grid Werkbank
Grundmodule

Grid Roter Sand mit Mechaniken

Grid Redstone mit Redstone
                Hier:
Grid Befehlsblock mit Befehlen
Verfügbar in:
Wiki Redstone-Welt Redstone-Welt

Grid Redstone-Block mehr Redstone

Eine Signalleitung überträgt Signale von einem Ort zu einem anderen. Hierbei benötigt das Signal ein Medium in dem sich bewegen kann. Befehlssignale durchlaufen Befehlsblöcke, sie können aber auch durch die Luft oder durch andere Blöcke übertragen werden. Hierbei kann am Ende der Leitung ein Block sein, der darauf reagieren kann.

Variante 1[]

Signalleitung (Befehle) Bild 1.1 Signalleitung (Befehle) Bild 1.2 Signalleitung (Befehle) Bild 1.3

Mit dieser Signalleitung lassen sich Signale über Rüstungsständer die in bestimmte Richtungen zeigen übertragen. Dazu platziert man die Rüstungsständer auf gelben Beton und wählt dann einen verbliebenen Rüstungsständer in der Schnellleiste aus. Dann wird der gelbe Beton in einen roten umgewandelt und der Rüstungsständer auf dem Block sendet rote Partikel in seine Richtung weiter. Alle Rüstungsständer die von diesen Partikeln berührt werden, fangen an zu leuchten und können das Signal in eine neue Richtung weiterleiten. Hierbei frischen sie das Signal auf, sodass es wieder etwas weiter wandern kann. Ansonsten ist nach 60 Ticks Schluss.

Einschalten
  • Befehl 1.1 Spieler die im Umkreis von 15 Blöcken um die Befehlsblöcke stehen bekommen einen Rüstungsständer mit speziellen Eigenschaften. So ist er klein, zeigt seine Arme, ist Schwerkraftunabhängig und besitzt einen angepassten Namen. Darüber hinaus verfügt der Gegenstand auch über NBT-Eigenschaften, die zum Erfassen im Inventar verwendet werden.
  • Befehl 1.2 Ebenfalls erhalten die Spieler gelben Beton, um die Leitung damit bauen zu können.
Wiederholen
  • Befehl 1.3 Alle Spieler die in der Schnellleiste den Rüstungsständer ausgewählt haben, welche eine Eigenschaft besitzt, erhalten ein Etikett zur Markierung.
  • Befehl 1.4 Wenn die Spieler gerade in diesem Tick den Rüstungsständer ausgewählt haben, wird im Umkreis von fünf Blöcken geprüft ob sich in der Nähe des Spielers Rüstungsständer aufhalten. Von der Position der Rüstungsständer wird dann der Block unter ihnen durch roten Beton ersetzt, sofern der Block gelb war.
  • Befehl 1.5 Wie der Befehl darüber, nur mit dem Unterschied, dass wenn die Spieler den Rüstungsständer nicht mehr ausgewählt haben, der rote Beton unter den Rüstungsständern wieder zu gelb umgewandelt wird.
  • Befehl 1.6 Damit man exakt den einen Tick erfassen kann in dem der Rüstungsständer ausgewählt wurde, wird den Spielern ein Etikett gegeben.
  • Befehl 1.7 Falls die Spieler den Rüstungsständer nicht mehr ausgewählt haben, besitzen sie jedoch das Etikett zur Auswahl, welches dann auch entfernt wird.
  • Befehl 1.8 Damit der Spieler nur dann das Etikett besitzt wenn er den Rüstungsständer in dem gleichen Tick ausgewählt hat, wird es ihm am Schluss wieder entfernt.
  • Befehl 1.9 Von der Position der Rüstungsständern wird eine Partikelwolke erzeugt, sofern unter dem Rüstungsständer ein roter Betonblock ist.
  • Befehl 1.10 Rüstungsständer die von Partikelwolken berührt wurden, erhalten einen Leuchteffekt für genau eine Sekunde, damit dieser Effekt sofort wieder verschwindet, wenn kein Signal (Partikelwolke) anliegt.
  • Befehl 1.11 Damit die Partikelwolke in die Richtung sich bewegen kann, in die der letzte Rüstungsständer blickt, wird die Partikelwolke so ausgerichtet, dass sie in die gleiche Richtung zeigt, sofern sie gerade nah beim Rüstungsständer verweilt.
  • Befehl 1.12 Damit das Signal zu sehen ist, wird ein Partikel-Effekt an der Position der Partikelwolke ausgelöst.
  • Befehl 1.13 Damit sich die Partikelwolke bewegt, wird sie jeden Tick um drittel Meter in Blickrichtung nach vorne bewegt.
Ausschalten
  • Befehl 1.14 Alle Rüstungsständer im Inventar werden entfernt.
  • Befehl 1.15 Alle gelben Betonblöcke werden aus dem Inventar entfernt.
  • Befehl 1.16 Falls das Auswahl-Etikett noch vorhanden ist, da es sein kann, dass der Spieler es beim Auswählen noch besaß, wird es wieder entfernt.
  • Befehl 1.17 Alle Drops der Signalleitung, die man gedroppt hat, besitzen bestimmte NBT-Eigenschaften. Diese bekommen ein Etikett.
  • Befehl 1.18 Alle Objekte mit dem Etikett werden entfernt.

Befehlsblöcke mit Befehlen:
give @a[distance=..15] minecraft:armor_stand{EigSigLe.1Alle:true,EigSigLe.1Signal:true,Enchantments:[{id:-1}],display:{Name:'{"text":"Signal-Geber","color":"yellow","bold":true}',Lore:['"Platziere den Rüstungsständer"','"um einen Empfänger"','"zu erstellen und wähle"','"den Rüstungsständer kurz aus,"','"um ein Signal an den nächsten"','"Empfänger weiterzuleiten."'] },EntityTag:{Small:true,ShowArms:true,NoGravity:true,CustomNameVisible:true,CustomName:'{"text":"Signal-Leitung","color":"red","bold":true}',Tags:["EtiSigLe.1Alle","EtiSigLe.1Empfaenger"],Pose:{LeftArm:[270f,0f,0f],RightArm:[270f,0f,0f]} } } 16
give @a[distance=..15] minecraft:yellow_concrete{EigSigLe.1Alle:true} 64


tag @a[nbt={SelectedItem:{tag:{EigSigLe.1Signal:true} } }] add EtiSigLe.1Ausgewaehlt
execute as @a[tag=EtiSigLe.1Ausgewaehlt,tag=!EtiSigLe.1Auswahl] at @s at @e[distance=..5,type=minecraft:armor_stand,tag=EtiSigLe.1Empfaenger] run fill ~ ~-1 ~ ~ ~-1 ~ minecraft:red_concrete replace minecraft:yellow_concrete
execute as @a[tag=!EtiSigLe.1Ausgewaehlt,tag=EtiSigLe.1Auswahl] at @s at @e[distance=..5,type=minecraft:armor_stand,tag=EtiSigLe.1Empfaenger] run fill ~ ~-1 ~ ~ ~-1 ~ minecraft:yellow_concrete replace minecraft:red_concrete
tag @a[tag=EtiSigLe.1Ausgewaehlt,tag=!EtiSigLe.1Auswahl] add EtiSigLe.1Auswahl
tag @a[tag=!EtiSigLe.1Ausgewaehlt,tag=EtiSigLe.1Auswahl] remove EtiSigLe.1Auswahl
tag @a[tag=EtiSigLe.1Ausgewaehlt] remove EtiSigLe.1Ausgewaehlt
execute at @e[type=minecraft:armor_stand,tag=EtiSigLe.1Empfaenger] if block ~ ~-1 ~ minecraft:red_concrete run summon minecraft:area_effect_cloud ~ ~1 ~ {Duration:60,Particle:"minecraft:block minecraft:air",Tags:["EtiSigLe.1Alle","EtiSigLe.1Signal"]}
execute at @e[type=minecraft:area_effect_cloud,tag=EtiSigLe.1Signal] positioned ~ ~-1 ~ run effect give @e[distance=..0.2,type=minecraft:armor_stand,tag=EtiSigLe.1Empfaenger,sort=nearest,limit=1] minecraft:glowing 1 1 false
execute at @e[type=minecraft:armor_stand,tag=EtiSigLe.1Empfaenger] positioned ~ ~1 ~ as @e[distance=..0.2,type=minecraft:area_effect_cloud,tag=EtiSigLe.1Signal] store success entity @s Age int 1 run teleport @s ~ ~ ~ ~ ~
execute at @e[type=minecraft:area_effect_cloud,tag=EtiSigLe.1Signal] run particle minecraft:block minecraft:redstone_block ~ ~ ~ 0 0 0 0.1 1 force @a[distance=..25]
execute as @e[type=minecraft:area_effect_cloud,tag=EtiSigLe.1Signal] at @s run teleport @s ^ ^ ^0.3


clear @a minecraft:armor_stand{EigSigLe.1Alle:true}
clear @a minecraft:yellow_concrete{EigSigLe.1Alle:true}
tag @a[tag=EtiSigLe.1Auswahl] remove EtiSigLe.1Auswahl
tag @e[type=minecraft:item,nbt={Item:{tag:{EigSigLe.1Alle:true} } }] add EtiSigLe.1Alle
kill @e[tag=EtiSigLe.1Alle]

Variante 2[]

Signalleitung (Befehle) Bild 2.1 Signalleitung (Befehle) Bild 2.2 Signalleitung (Befehle) Bild 2.3

Mit dieser Signalleitung ist es möglich ein Signal für eine kurze Zeitdauer zu übermitteln. Man erhält einen Stock und gelben Beton. Den Beton kann man beliebig aufbauen und daraus beliebige Leitungen bauen. Danach stellt man sich auf ein Anfangsstück oder einer anderen beliebigen Position auf den gelben Beton und wählt dann den Stock aus. Immer dann wenn man ihn auswählt, wird ein kurzes Signal durch alle gelben Betonblöcke hindurchgeleitet. Damit man das Signal sehen kann, werden die Betonblöcke umgefärbt. Nach einer kurzen Zeit jedoch färben sich die Betonblöcke wieder in gelb um und das Signal ist vorbei.

Einschalten
  • Befehl 2.1 Auf dem Wiederhol-Befehlsblock befindet sich ein Hebel. Legt man ihn um, wird zuerst der Befehlsblock mit der Start-Funktion signalleitung:v2start aktiviert.
Wiederholen
Ausschalten

Befehlsblöcke mit Befehlen:



Datenpaket


Variante 2: Start-Funktion
Die Start-Funktion erstellt das Punkte-Ziel und gibt den Spielern den Stock und die Betonblöcke.

Editor Icon signalleitung:v2start.mcfunction
# Ein Punkte-Ziel wird erstellt.
scoreboard objectives add PZSigLe.2Wert dummy ["Signalleitung.2: ",{"text":"Wert der Signale","bold":true}]

# Ein Stock mit speziellen Eigenschaften wird Spielern im Umkreis von 15 Blöcke gegeben.
give @a[distance=..15] minecraft:stick{EigSigLe.2Alle:true,EigSigLe.2Stock:true,Enchantments:[{id:-1}],display:{Name:'{"text":"Signal","color":"dark_purple","bold":true}',Lore:['"Wähle den Stock aus"','"um unter dir den"','"Block zu aktivieren."'] } }

# Gelber Beton, der als Leitung verwendet werden kann, wird den Spielern gegeben.
give @a[distance=..15] minecraft:yellow_concrete{EigSigLe.2Alle:true} 64

# Der Chunk wird dauerhaft geladen.
forceload add ~ ~

Variante 2: Zyklus-Funktion
Die Zyklus-Funktion prüft ob der Spieler den Stock ausgewählt hat und nur dann wird eine Partikelwolke erzeugt, von der aus die Farben-Funktion aufgerufen wird.

Editor Icon signalleitung:v2zyklus.mcfunction
# Wenn der Spieler den Stock ausgewählt hat, wird ihm ein Etikett gegeben.
tag @a[nbt={SelectedItem:{tag:{EigSigLe.2Stock:true} } }] add EtiSigLe.2Ausgewaehlt

# Wenn der Spieler gerade den Stock ausgewählt hat, wird eine Partikelwolke erzeugt, falls sich unter dem spieler gelber Beton aufhält.
execute at @a[tag=EtiSigLe.2Ausgewaehlt,tag=!EtiSigLe.2Auswahl] align xz if block ~0.5 ~-1 ~0.5 minecraft:yellow_concrete run summon minecraft:area_effect_cloud ~0.5 ~-1 ~0.5 {Duration:15,Tags:["EtiSigLe.2Alle","EtiSigLe.2Signal"]}

# Das Etikett wird vergeben um den Tick der Auswahl oder Abwahl zu erfassen.
tag @a[tag=EtiSigLe.2Ausgewaehlt,tag=!EtiSigLe.2Auswahl] add EtiSigLe.2Auswahl
tag @a[tag=!EtiSigLe.2Ausgewaehlt,tag=EtiSigLe.2Auswahl] remove EtiSigLe.2Auswahl

# Das Etikett wird wieder entfernt.
tag @a[tag=EtiSigLe.2Ausgewaehlt] remove EtiSigLe.2Ausgewaehlt

# Wenn sich die Partikelwolke im Beton befindet, wird die Farben-Funktion aufgerufen.
execute as @e[type=minecraft:area_effect_cloud,tag=EtiSigLe.2Signal] at @s if block ~ ~ ~ #signalleitung:v2leitung run function signalleitung:v2farbe

Variante 2: Farbe-Funktion
Die Farben-Funktion setzt den Betonblock mit entsprechender Farbe und ruft die Signal-Funktion auf, sofern das Signal noch ganz frisch ist.

Editor Icon signalleitung:v2farbe.mcfunction
# Es wird immer violetter Beton platziert, bevor getestet wird welche Farbe platziert werden soll.
setblock ~ ~ ~ minecraft:purple_concrete replace

# Der Zahlenwert von dem Alter wird ausgelesen und in einen Punkte-Ziel der Partikelwolke gespeichert.
execute store result score @s PZSigLe.2Wert run data get entity @s Age

# Wenn der Wert bei eins liegt, wird die Signal-Funktion geladen.
execute if entity @s[scores={PZSigLe.2Wert=1}] run function signalleitung:v2signal

# Verschiedene Betonfarben werden platziert.
execute unless entity @s[scores={PZSigLe.2Wert=7..9}] run setblock ~ ~ ~ minecraft:red_concrete replace
execute unless entity @s[scores={PZSigLe.2Wert=5..11}] run setblock ~ ~ ~ minecraft:orange_concrete replace
execute unless entity @s[scores={PZSigLe.2Wert=3..13}] run setblock ~ ~ ~ minecraft:yellow_concrete replace

Variante 2: Signal-Funktion
Die Signal-Funktion versucht in alle sechs Richtungen neue Partikelwolken zu erzeugen, sofern dort gelbe Betonblöcke vorhanden sind.

Editor Icon signalleitung:v2signal.mcfunction
# Es wird in allen sechs Richtungen geprüft ob sich dort ein gelber Beton befindet und nur dann wird jeweils dort eine neue Partikelwolke erzeugt.
execute positioned ~1 ~ ~ if block ~ ~ ~ minecraft:yellow_concrete unless entity @e[distance=..0.5,type=minecraft:area_effect_cloud,tag=EtiSigLe.2Signal] run summon minecraft:area_effect_cloud ~ ~ ~ {Duration:15,Tags:["EtiSigLe.2Alle","EtiSigLe.2Signal"]}

execute positioned ~-1 ~ ~ if block ~ ~ ~ minecraft:yellow_concrete unless entity @e[distance=..0.5,type=minecraft:area_effect_cloud,tag=EtiSigLe.2Signal] run summon minecraft:area_effect_cloud ~ ~ ~ {Duration:15,Tags:["EtiSigLe.2Alle","EtiSigLe.2Signal"]}

execute positioned ~ ~1 ~ if block ~ ~ ~ minecraft:yellow_concrete unless entity @e[distance=..0.5,type=minecraft:area_effect_cloud,tag=EtiSigLe.2Signal] run summon minecraft:area_effect_cloud ~ ~ ~ {Duration:15,Tags:["EtiSigLe.2Alle","EtiSigLe.2Signal"]}

execute positioned ~ ~-1 ~ if block ~ ~ ~ minecraft:yellow_concrete unless entity @e[distance=..0.5,type=minecraft:area_effect_cloud,tag=EtiSigLe.2Signal] run summon minecraft:area_effect_cloud ~ ~ ~ {Duration:15,Tags:["EtiSigLe.2Alle","EtiSigLe.2Signal"]}

execute positioned ~ ~ ~1 if block ~ ~ ~ minecraft:yellow_concrete unless entity @e[distance=..0.5,type=minecraft:area_effect_cloud,tag=EtiSigLe.2Signal] run summon minecraft:area_effect_cloud ~ ~ ~ {Duration:15,Tags:["EtiSigLe.2Alle","EtiSigLe.2Signal"]}

execute positioned ~ ~ ~-1 if block ~ ~ ~ minecraft:yellow_concrete unless entity @e[distance=..0.5,type=minecraft:area_effect_cloud,tag=EtiSigLe.2Signal] run summon minecraft:area_effect_cloud ~ ~ ~ {Duration:15,Tags:["EtiSigLe.2Alle","EtiSigLe.2Signal"]}

Variante 2: Stopp-Funktion
Die Stopp-Funktion löscht das Punkte-Ziel und die Objekte wieder. Alle Gegenstände die noch im Inventar liegen werden ebenfalls gelöscht.

Editor Icon signalleitung:v2stopp.mcfunction
# Das Punkte-Ziel wird entfernt.
scoreboard objectives remove PZSigLe.2Wert

# Das eventuell noch vorhandene Etikett wird entfernt.
tag @a[tag=EtiSigLe.2Auswahl] remove EtiSigLe.2Auswahl

# Stöcke und Betons werden entfernt.
clear @a minecraft:stick{EigSigLe.2Alle:true}
clear @a minecraft:yellow_concrete{EigSigLe.2Alle:true}

# Alle Objekte mit dem Etikett werden entfernt.
tag @e[type=minecraft:item,nbt={Item:{tag:{EigSigLe.2Alle:true} } }] add EtiSigLe.2Alle
kill @e[tag=EtiSigLe.2Alle]

# Der Chunk wird entladen.
forceload remove ~ ~

Variante 3[]

Signalleitung (Befehle) Bild 3.1 Signalleitung (Befehle) Bild 3.2 Signalleitung (Befehle) Bild 3.3 Signalleitung (Befehle) Bild 3.4

Ähnlich wie bei Variante 2 kann man aus gelben Betonblöcken Leiterbahnen bauen und dann sich selbst auf solch einer Bahn positionieren. Anschließend wählt man den Stock aus und die Signale laufen über die gesamten Betonblöcke hindurch. Hierbei bleibt das Signal jedoch solange bestehen, solange man den Stock nicht abgewählt hat. Nur dann färben sich die Blöcke wieder in gelb um, ansonsten bleiben sie violett.

Einschalten
  • Befehl 3.1 Auf dem Wiederhol-Befehlsblock befindet sich ein Hebel. Legt man ihn um, wird zuerst der Befehlsblock mit der Start-Funktion signalleitung:v3start aktiviert.
Wiederholen
Ausschalten

Befehlsblöcke mit Befehlen:



Datenpaket


Variante 3: Start-Funktion
Die Start-Funktion erstellt das Punkte-Ziel und gibt den Spielern den Stock und gelbe Betonblöcke.

Editor Icon signalleitung:v3start.mcfunction
# Es wird ein Punkte-Ziel erstellt.
scoreboard objectives add PZSigLe.3Wert dummy ["Signalleitung.3: ",{"text":"Wert der Signale","bold":true}]

# Den Spielern wird ein Stock mit speziellen Eigenschaften gegeben.
give @a[distance=..15] minecraft:stick{EigSigLe.3Alle:true,EigSigLe.3Stock:true,Enchantments:[{id:-1}],display:{Name:'{"text":"Signal","color":"dark_purple","bold":true}',Lore:['"Wähle den Stock aus"','"um unter dir den"','"Block zu aktivieren."'] } }

# Ebenfalls bekommen sie gelben Beton, den sie als Leitung verwenden können.
give @a[distance=..15] minecraft:yellow_concrete{EigSigLe.3Alle:true} 64

# Der Chunk wird dauerhaft geladen.
forceload add ~ ~

Variante 3: Zyklus-Funktion
Die Zyklus-Funktion prüft ob der Spieler den Stock ausgewählt oder abgewählt hat und erstellt oder entfernt dann die Markierer. Wenn Markierer existieren wird von diesen die Farben-Funktion aufgerufen.

Editor Icon signalleitung:v3zyklus.mcfunction
# Wenn der Spieler den Stock ausgewählt hat, wird ihm ein Etikett gegeben.
tag @a[nbt={SelectedItem:{tag:{EigSigLe.3Stock:true} } }] add EtiSigLe.3Ausgewaehlt

# Wenn er den Stock gerade ausgewählt hat, wird unter ihm geprüft ob unter ihm gelber beton ist. Nur dann wird ein Markierer erzeugt.
execute at @a[tag=EtiSigLe.3Ausgewaehlt,tag=!EtiSigLe.3Auswahl] align xz if block ~0.5 ~-1 ~0.5 minecraft:yellow_concrete run summon minecraft:marker ~0.5 ~-1 ~0.5 {Small:true,NoGravity:true,Marker:true,Invisible:true,Tags:["EtiSigLe.3Alle","EtiSigLe.3Signal"]}

# Wenn er gerade nicht mehr den Stock ausgewählt hat, wird dem Markierer ein Etikett vergeben.
execute at @a[tag=!EtiSigLe.3Ausgewaehlt,tag=EtiSigLe.3Auswahl] align xz positioned ~0.5 ~-1 ~0.5 run tag @e[distance=..0.5,type=minecraft:marker,tag=EtiSigLe.3Signal,sort=nearest,limit=1] add EtiSigLe.3Erloschen

# Je nach dem ob der Spieler den stock gerade ausgewählt hat oder nicht wird ein Etikett vergeben.
tag @a[tag=EtiSigLe.3Ausgewaehlt,tag=!EtiSigLe.3Auswahl] add EtiSigLe.3Auswahl
tag @a[tag=!EtiSigLe.3Ausgewaehlt,tag=EtiSigLe.3Auswahl] remove EtiSigLe.3Auswahl

# Das Etikett wird entfernt.
tag @a[tag=EtiSigLe.3Ausgewaehlt] remove EtiSigLe.3Ausgewaehlt

# Wenn ein Markierer das Etikett besitzt vergibt er es an seine Nachbarn ebenfalls.
execute at @e[type=minecraft:marker,tag=EtiSigLe.3Signal,tag=EtiSigLe.3Erloschen] run tag @e[distance=..1.2,type=minecraft:marker,tag=EtiSigLe.3Signal,sort=nearest,limit=7] add EtiSigLe.3Erloschen

# Wenn der Markierer in Beton steckt, wird die Farben-Funktion geladen.
execute as @e[type=minecraft:marker,tag=EtiSigLe.3Signal] at @s if block ~ ~ ~ #signalleitung:v3leitung run function signalleitung:v3farbe

Variante 3: Farbe-Funktion
Die Farben-Funktion addiert jeden Tick den Markierern einen Wert hinzu und anhand der Werte wird die entsprechende Farbe platziert. Ist das Signal ganz frisch, wird die Signal-Funktion aufgerufen.

Editor Icon signalleitung:v3farbe.mcfunction
# Der violette Beton wird immer platziert und weiter unten entscheidet der Wert ob sich die Farbe ändert.
setblock ~ ~ ~ minecraft:purple_concrete replace

# Der Wert von Markierern wird bis zum Wert acht hochgezählt danach wird pausiert. Er wird weitergezählt wenn er das entsprechende Etikett erhalten hat.
execute if entity @s[tag=!EtiSigLe.3Erloschen] unless entity @s[scores={PZSigLe.3Wert=8..}] run scoreboard players add @s PZSigLe.3Wert 1
scoreboard players add @s[tag=EtiSigLe.3Erloschen] PZSigLe.3Wert 1

# Wenn das Signal nicht erloschen ist und der Wert bei eins liegt, wird die Signal-Funktion aufgerufen.
execute if entity @s[tag=!EtiSigLe.3Erloschen,scores={PZSigLe.3Wert=1}] run function signalleitung:v3signal

# Es werden verschiedene Farben platziert, abhängängig des Wertes.
execute unless entity @s[scores={PZSigLe.3Wert=7..9}] run setblock ~ ~ ~ minecraft:red_concrete replace
execute unless entity @s[scores={PZSigLe.3Wert=5..11}] run setblock ~ ~ ~ minecraft:orange_concrete replace
execute unless entity @s[scores={PZSigLe.3Wert=3..13}] run setblock ~ ~ ~ minecraft:yellow_concrete replace

# Ist das Signal erloschen und die Signalstärke überschritten, wird der Markierer entfernt.
kill @s[tag=EtiSigLe.3Erloschen,scores={PZSigLe.3Wert=16..}]

Variante 3: Signal-Funktion
Die Signal-Funktion versucht in jede Richtung ein neues Signal in form von Markierern zu erzeugen, dort wo Betonblöcke existieren wird dies geschehen.

Editor Icon signalleitung:v3signal.mcfunction
# Es wird in allen sechs Richtungen geprüft ob sich dort gelber Beton befindet und nur dann wird ein Markierer an der Stelle positioniert.
execute positioned ~1 ~ ~ if block ~ ~ ~ minecraft:yellow_concrete unless entity @e[distance=..0.5,type=minecraft:marker,tag=EtiSigLe.3Signal] run summon minecraft:marker ~ ~ ~ {Tags:["EtiSigLe.3Alle","EtiSigLe.3Signal"]}

execute positioned ~-1 ~ ~ if block ~ ~ ~ minecraft:yellow_concrete unless entity @e[distance=..0.5,type=minecraft:marker,tag=EtiSigLe.3Signal] run summon minecraft:marker ~ ~ ~ {Tags:["EtiSigLe.3Alle","EtiSigLe.3Signal"]}

execute positioned ~ ~1 ~ if block ~ ~ ~ minecraft:yellow_concrete unless entity @e[distance=..0.5,type=minecraft:marker,tag=EtiSigLe.3Signal] run summon minecraft:marker ~ ~ ~ {Tags:["EtiSigLe.3Alle","EtiSigLe.3Signal"]}

execute positioned ~ ~-1 ~ if block ~ ~ ~ minecraft:yellow_concrete unless entity @e[distance=..0.5,type=minecraft:marker,tag=EtiSigLe.3Signal] run summon minecraft:marker ~ ~ ~ {Tags:["EtiSigLe.3Alle","EtiSigLe.3Signal"]}

execute positioned ~ ~ ~1 if block ~ ~ ~ minecraft:yellow_concrete unless entity @e[distance=..0.5,type=minecraft:marker,tag=EtiSigLe.3Signal] run summon minecraft:marker ~ ~ ~ {Tags:["EtiSigLe.3Alle","EtiSigLe.3Signal"]}

execute positioned ~ ~ ~-1 if block ~ ~ ~ minecraft:yellow_concrete unless entity @e[distance=..0.5,type=minecraft:marker,tag=EtiSigLe.3Signal] run summon minecraft:marker ~ ~ ~ {Tags:["EtiSigLe.3Alle","EtiSigLe.3Signal"]}

Variante 3: Stopp-Funktion
Die Stop-Funktion löscht das Punkte-Ziel, die Gegenstände im Inventar und alle Objekte wieder.

Editor Icon signalleitung:v3stopp.mcfunction
# Das Punkte-Ziel wird entfernt.
scoreboard objectives remove PZSigLe.3Wert

# Das eventuell vorhandene Etikett wird entfernt.
tag @a[tag=EtiSigLe.3Auswahl] remove EtiSigLe.3Auswahl

# Der Stock und der Beton werden entfernt.
clear @a minecraft:stick{EigSigLe.3Alle:true}
clear @a minecraft:yellow_concrete{EigSigLe.3Alle:true}

# alle Objekte mit dem Etikett werden entfernt.
tag @e[type=minecraft:item,nbt={Item:{tag:{EigSigLe.3Alle:true} } }] add EtiSigLe.3Alle
kill @e[tag=EtiSigLe.3Alle]

# Der geladene chunk wird wieder entladen.
forceload remove ~ ~
Advertisement