Technik Wiki
Registrieren
Advertisement
Gruppe: Grid Schiene
Schienenverkehrsanlagen

Grid Roter Sand blass mit Mechaniken

Grid Redstone mit Redstone
                Hier:
Grid Befehlsblock mit Befehlen
Verfügbar in:
Wiki Schienen-Welt Schienen-Welt

Das Schnellgleis gibt die Möglichkeit, schneller mit einer Lore über Schienen zu fahren, als es eigentlich technisch von Minecraft her möglich ist. Man kann Loren auf zwei Möglichkeiten ohne Zutun des Spielers beschleunigen, zum einen mit dem Befehl /data ... Motion und zum anderen mit dem Befehl /teleport.

Die Loren werden beim Schnellgleis stark beschleunigt und teleportiert, dadurch nimmt man keine ruckartigen Bewegungen wahr (wegen /teleport) und ist nicht an die Maximalgeschwindigkeit gebunden (mit /data).

Diese Antriebstechniken können auch durch einen Lorenaufzug ergänzt werden.

Variante 1[]

Schnellgleis (Befehle) Bild 1.1 Schnellgleis (Befehle) Bild 1.2 Schnellgleis (Befehle) Bild 1.3 Schnellgleis (Befehle) Bild 1.4

Dieses Schnellgleis beschleunigt spezielle Loren um ein vielfaches, solange man in dieser sitzt. Beim Einschalten erhält man eine spezielle Lore, welche man auf ein beliebiges Gleis setzen kann. Sitz man in der Lore muss man eine der Tasten W, A, S oder D drücken um die Lore zu beschleunigen. Dieser Vorgang kann manchmal sehr lange dauern, daher sollte man die Lore auf ein Gefälle setzen, auf dem sie herunterfährt, dann zieht die Technik besser. Sobald die Lore beschleunigt, kann man gemütlich die Landschaft betrachten und dabei zusehen wie man mit einem Affen Zahn durch die Gegend düst. Sobald man aussteigt, wird die Beschleunigung nicht mehr durchgeführt und die Lore kommt nach paar Metern zum Halten.

Einschalten
  • Befehl 1.1 Das Punkte-Ziel wird erstellt. es wird benutzt um die Ticks zu bestimmen und um die Richtung der Lore zu berechnen.
  • Befehl 1.2 Spieler erhalten die Lore, mit der man auf den Schienen sehr schnell unterwegs sein kann.
  • Befehl 1.3 Der Chunk wird dauerhaft geladen, damit man sich auch weiter von der Technik entfernen kann.
Wiederholen
  • Befehl 1.4 Die Tick-Variable wird jeden Tick um eins erhöht.
  • Befehl 1.5 Wenn die Lore platziert wurde, besitzt sie die Namens-Eigenschaft, auf die geprüft wird. Ist sie vorhanden, bekommt die Lore ein spezielles Etikett und der Name wird in der Welt sichtbar gemacht.
  • Befehl 1.6 Wenn ein Spieler in dieser Lore sitzt, wird die Beschleunigung in X-Richtung der Lore ausgelesen und verstärkt. Ebenfalls wird dieser Wert auch in das Punkte-Ziel der Lore gespeichert.
  • Befehl 1.7 Je nach Richtung wird die Lore in X-Richtung der Achse bewegt oder entgegengesetzt[B1.8].
  • Befehl 1.9 Die Beschleunigung der Lore in Z-Richtung wird ausgelesen und verstärkt. Ebenso wird dieser Wert in das Punkte-Ziel gespeichert um die Richtung zu bestimmen.
  • Befehl 1.10 Je nach Richtung wird die Lore in Z-Richtung der Achse bewegt oder entgegengesetzt[B1.11].
  • Befehl 1.12 Alle viertel Sekunde wird die Tick-Variable wieder auf null zurück gesetzt.
Ausschalten

Befehlsblöcke mit Befehlen:
scoreboard objectives add PZSchGl.1Wert dummy ["Schnellgleis.1: ",{"text":"Zeit und Richtung","bold":true}]
give @a minecraft:minecart{EigSchGl.1Alle:true,display:{Name:'{"text":"Schnellgleis-Lore","color":"dark_purple","bold":true}',Lore:['"Platziere die Lore"','"auf die Schiene"','"und bewege sie mit WASD,"','"damit sie automatisch fährt."'] } }


scoreboard players add VarSchGl.1Tick PZSchGl.1Wert 1
execute if score VarSchGl.1Tick PZSchGl.1Wert matches 5.. as @e[type=minecraft:minecart,tag=!EtiSchGl.1Lore,name="Schnellgleis-Lore"] run data merge entity @s {CustomNameVisible:true,Tags:["EtiSchGl.1Alle","EtiSchGl.1Lore"]}
execute if score VarSchGl.1Tick PZSchGl.1Wert matches 5.. as @e[type=minecraft:minecart,tag=EtiSchGl.1Lore] on passengers on vehicle at @s if block ~ ~ ~ #minecraft:rails store result score @s PZSchGl.1Wert store result entity @s Motion[0] double 1 run data get entity @s Motion[0] 3
execute if score VarSchGl.1Tick PZSchGl.1Wert matches 5.. as @e[type=minecraft:minecart,tag=EtiSchGl.1Lore,scores={PZSchGl.1Wert=1..}] on passengers on vehicle at @s if block ~2 ~ ~ #minecraft:rails run teleport @s ~2 ~ ~
execute if score VarSchGl.1Tick PZSchGl.1Wert matches 5.. as @e[type=minecraft:minecart,tag=EtiSchGl.1Lore,scores={PZSchGl.1Wert=..-1}] on passengers on vehicle at @s if block ~-2 ~ ~ #minecraft:rails run teleport @s ~-2 ~ ~
execute if score VarSchGl.1Tick PZSchGl.1Wert matches 5.. as @e[type=minecraft:minecart,tag=EtiSchGl.1Lore] on passengers on vehicle at @s if block ~ ~ ~ #minecraft:rails store result score @s PZSchGl.1Wert store result entity @s Motion[2] double 1 run data get entity @s Motion[2] 3
execute if score VarSchGl.1Tick PZSchGl.1Wert matches 5.. as @e[type=minecraft:minecart,tag=EtiSchGl.1Lore,scores={PZSchGl.1Wert=1..}] on passengers on vehicle at @s if block ~ ~ ~2 #minecraft:rails run teleport @s ~ ~ ~2
execute if score VarSchGl.1Tick PZSchGl.1Wert matches 5.. as @e[type=minecraft:minecart,tag=EtiSchGl.1Lore,scores={PZSchGl.1Wert=..-1}] on passengers on vehicle at @s if block ~ ~ ~-2 #minecraft:rails run teleport @s ~ ~ ~-2
execute if score VarSchGl.1Tick PZSchGl.1Wert matches 5.. run scoreboard players set VarSchGl.1Tick PZSchGl.1Wert 0


scoreboard objectives remove PZSchGl.1Wert
clear @a minecraft:minecart{EigSchGl.1Alle:true}
clear @a minecraft:minecart{display:{Name:'{"bold":true,"color":"dark_purple","text":"Schnellgleis-Lore"}'} }
execute as @e[type=minecraft:item] unless entity @s[nbt=!{Item:{tag:{EigSchGl.1Alle:true} } },nbt=!{Item:{tag:{display:{Name:'{"bold":true,"color":"dark_purple","text":"Schnellgleis-Lore"}'} } } }] run kill @s
kill @e[tag=EtiSchGl.1Alle]
forceload remove ~ ~

Variante 2[]

Schnellgleis (Befehle) Bild 2.1 Schnellgleis (Befehle) Bild 2.2 Schnellgleis (Befehle) Bild 2.3 Schnellgleis (Befehle) Bild 2.4

Mit diesem Schnellgleis werden vorgefertigte Loren extrem schnell. Beim Einschalten wird jedem Spieler in der Nähe eine besondere Lore gegeben, die man auf Schienen platzieren kann. Setzt man sich hinein, so muss man die Tasten W, A, S oder D drücken. Es kann manchmal etwas länger dauern bis die Lore so durchstartet. Um dies etwas schneller zu ermöglichen, hilft es wenn man die Lore an eine Steigung platziert, dann fährt sie die Steigung hinab und beginnt zu rasen. Nun kann der Spieler einfach zuschauen, wie an ihm die ganze Landschaft im rasanten Tempo vorbeizieht. Jegliche Gleisstecken sind möglich, jedoch sind Kerzen gerade Strecken am aller besten geeignet. Wenn man aus der Lore aussteigt, hört die Beschleunigung der Lore auf, sie kann aber einige Meter noch weiter rollen, bis sie zum Stehen kommt.

Einschalten
  • Befehl 2.1 Auf dem Wiederhol-Befehlsblock befindet sich ein Hebel. Legt man ihn um, wird zuerst der Befehlsblock mit der Start-Funktion schnellgleis:v2start aktiviert.
Wiederholen
Ausschalten

Befehlsblöcke mit Befehlen:



Datenpaket


Variante 2: Start-Funktion
Die Start-Funktion gibt dem Spieler eine besondere Lore und erstellt das Punkte-Ziel.

Editor Icon schnellgleis:v2start.mcfunction
# Das Punkte-Ziel für die Zeit-Berechnung und die Richtungswerte wird erstellt.
scoreboard objectives add PZSchGl.2Wert dummy ["Schnellgleis.2: ",{"text":"Zeit und Richtung","bold":true}]

# Allen Spielern im Umkreis wird eine spezielle Lore gegeben, die man platzieren muss um die hohen Geschwindigkeiten zu erhalten.
give @a[distance=..15] minecraft:minecart{EigSchGl.2Alle:true,display:{Name:'{"text":"Schnellgleis-Lore","color":"dark_purple","bold":true}',Lore:['"Platziere die Lore"','"auf die Schiene"','"und bewege sie mit WASD,"','"damit sie automatisch fährt."'] } }

# Damit man sich deutlich davon entfernen kann.
forceload add ~ ~


Variante 2: Zyklus-Funktion
Die Zyklus-Funktion prüft, ob der Spieler in der speziellen Lore sitzt und ruft davon abhängig alle viertel Sekunde die Sitzen-Funktion auf.

Editor Icon schnellgleis:v2zyklus.mcfunction
# Jeden Tick wird die Variable um eins erhöht, um eine Viertel-Sekunde zu erfassen.
scoreboard players add VarSchGl.2Tick PZSchGl.2Wert 1

# Wenn die spezielle Lore platziert wird, so besitzt sie eine bestimmte Namens-Eigenschaft, die geprüft werden kann.
execute if score VarSchGl.2Tick PZSchGl.2Wert matches 5.. as @e[type=minecraft:minecart,tag=!EtiSchGl.2Lore,name="Schnellgleis-Lore"] run data merge entity @s {CustomNameVisible:true,Tags:["EtiSchGl.2Alle","EtiSchGl.2Lore"]}

# Nur wenn der Spieler in der speziellen Lore sitzt, wird die Sitzen-Funktion geladen.
execute if score VarSchGl.2Tick PZSchGl.2Wert matches 5.. as @e[type=minecraft:minecart,tag=EtiSchGl.2Lore] on passengers on vehicle at @s if block ~ ~ ~ #minecraft:rails run function schnellgleis:v2sitzen

# Die Variable wird wieder auf null gesetzt, damit es wieder von vorne los gehen kann.
execute if score VarSchGl.2Tick PZSchGl.2Wert matches 5.. run scoreboard players set VarSchGl.2Tick PZSchGl.2Wert 0


Variante 2: Sitzen-Funktion
Die Sitzen-Funktion ließt die Beschleunigung der Lore aus und ruft dann die Fahren-Funktion auf.

Editor Icon schnellgleis:v2sitzen.mcfunction
# Die X- und Z-Beschleunigung wird um den Faktor drei ausgelesen und sowohl wieder in die Beschleunigung zurück gespeichert als auch jeweils in eine Variable für die entsprechende Richtung. Dadurch können diese in der Fahren-Funktion verwendet werden.
execute store result score VarSchGl.2XRichtung PZSchGl.2Wert store result entity @s Motion[0] double 1 run data get entity @s Motion[0] 3
execute store result score VarSchGl.2ZRichtung PZSchGl.2Wert store result entity @s Motion[2] double 1 run data get entity @s Motion[2] 3

# Die Fahren-Variable wird gesetzt und anschließend in der Fahren-Funktion verwendet.
scoreboard players set VarSchGl.2Fahren PZSchGl.2Wert 0
function schnellgleis:v2fahren


Variante 2: Fahren-Funktion
Die Fahren-Funktion ruft sich fünf mal selbst auf und schaut in welche Richtung die Lore sich derzeit beschleunigt und teleportiert sie in diese Richtung, sodass sie noch schneller wird.

Editor Icon schnellgleis:v2fahren.mcfunction
# Je nach X-Richtung wird die Lore in die X-Richtung um einen Block nach vorne bewegt.
execute if score VarSchGl.2XRichtung PZSchGl.2Wert matches 1.. at @s if block ~1 ~ ~ #minecraft:rails run teleport @s ~1 ~ ~
execute if score VarSchGl.2XRichtung PZSchGl.2Wert matches ..-1 at @s if block ~-1 ~ ~ #minecraft:rails run teleport @s ~-1 ~ ~

# Je nach Z-Richtung wird die Lore in die Z-Richtung um einen Block nach vorne bewegt.
execute if score VarSchGl.2ZRichtung PZSchGl.2Wert matches 1.. at @s if block ~ ~ ~1 #minecraft:rails run teleport @s ~ ~ ~1
execute if score VarSchGl.2ZRichtung PZSchGl.2Wert matches ..-1 at @s if block ~ ~ ~-1 #minecraft:rails run teleport @s ~ ~ ~-1

# Die Fahren-Funktion ruft sich insgesamt fünf mal auf, sodass die Lore extrem beschleunigen kann, aber immer nur, wenn sie sich noch auf Gleisen befindet.
scoreboard players add VarSchGl.2Fahren PZSchGl.2Wert 1
execute if score VarSchGl.2Fahren PZSchGl.2Wert matches ..5 run function schnellgleis:v2fahren


Variante 2: Stopp-Funktion
Die Stopp-Funktion löscht das Punkte-Ziel wieder und Loren im Inventar, also Drop auf den Boden und als Objekt in der Welt.

Editor Icon schnellgleis:v2stopp.mcfunction
# Das Punkte-Ziel wird entfernt.
scoreboard objectives remove PZSchGl.2Wert

# Die Lore wird aus dem Inventar gelöscht, da sie beim Abbaue droppt und andere Eigenschaften besitzt, werden beide Varianten geprüft und gelöscht.
clear @a minecraft:minecart{EigSchGl.2Alle:true}
clear @a minecraft:minecart{display:{Name:'{"bold":true,"color":"dark_purple","text":"Schnellgleis-Lore"}'} }

# Falls die Lore gedroppt wurde, wird sie entfernt und die platzierte Lore ebenso.
execute as @e[type=minecraft:item] unless entity @s[nbt=!{Item:{tag:{EigSchGl.2Alle:true} } },nbt=!{Item:{tag:{display:{Name:'{"bold":true,"color":"dark_purple","text":"Schnellgleis-Lore"}'} } } }] run kill @s
kill @e[tag=EtiSchGl.2Alle]

# Der Chunk wird wieder entladen.
forceload remove ~ ~


Disambig color
Advertisement