Das offizielle Minecraft Wiki twittert hier: Wiki-Twitter  –  Chatte im Wiki-Discord  – Noch keinen Server gefunden? Es gibt einen Wiki-Server

Schienenverkehrsanlagen/Brückenbauer (Befehle)

Aus Technik Wiki
Wechseln zu: Navigation, Suche
Baustelle.svg
Diese Seite wird gerade von Rostiger Bot neu erstellt oder grundlegend überarbeitet.
Fragen und Vorschläge bitte in die Diskussion. Fortschritt: Grid Redstone-Block.pngGrid Redstone-Block.pngGrid Redstone-Block.pngGrid Redstone-Block.pngGrid Redstone-Block.pngGrid Redstone-Block blass.pngGrid Redstone-Block blass.pngGrid Redstone-Block blass.pngGrid Redstone-Block blass.pngGrid Redstone-Block blass.png


Gruppe: Grid Schiene.png
Schienenverkehrsanlagen

Grid Roter Sand blass.png mit Mechaniken

Grid Redstone blass.png mit Redstone
                Hier:
Grid Befehlsblock.png mit Befehlen

Die vorgestellte Technik kann in der Schienen-Welt angesehen werden.

Mit Hilfe eines Brückenbauers kann man von steilen Klippen aus ein Tal mit Brücken für den Schienenverkehr automatisch bauen lassen. Selbst die Pfeiler werden in einem immer gleich großen Abstand platziert. Hierbei ist ein Brückenbauer einfach ein erweiterter Gleisverleger bzw. baut grundsätzlich auf dem Automobil auf. Man kann auch einen Brückenbauer für die Eisenbahn konstruieren. Die Schiene ist dann zwar nicht direkt funktional, kann aber je nach Eisenbahntyp mit Funktionen erweitert werden. Es spielt auch keine Rolle, in welcher Höhe sich der Brückenbauer befindet, die Brückenpfeiler werden immer komplett bis zum Boden gesetzt.

Variante 1[Bearbeiten | Quelltext bearbeiten]

Schienenverkehrsanlagen Symbol.png
Diese Technik ist noch nicht in der aktuellen Schienen-Welt vorhanden.
In einem der nächsten Updates wird sie dort hinzugefügt werden.

Schienenverkehrsanlagen Brückenbauer (Befehle) Bild 2.1.png Schienenverkehrsanlagen Brückenbauer (Befehle) Bild 2.2.png Schienenverkehrsanlagen Brückenbauer (Befehle) Bild 2.3.png Schienenverkehrsanlagen Brückenbauer (Befehle) Bild 2.4.png

Ähnlich wie ein Gleisverleger setzt der Brückenbauer zuerst ein Gleisbett und darunter das Brückensegment. Danach wird mit Hilfe eines ZählersBefehl 1.1 alle 14 BlöckeBefehl 1.2 ein Pfeiler bis zum Grund platziert. Dabei wird dann auch eine Antriebsschiene mit Redstone-Fackel gesetzt. Wird der Hebel umgelegt, so werden die Punktestand-Ziele erzeugtBefehl 1.3Befehl 1.4 die für das Erfassen der Karottenrute oder das Schleichen des Spielers benötigt werden und der Spieler bekommt eine KarottenruteBefehl 1.5. Wird nun die Karottenrute rechtsgeklickt, so wird mit dem BefehlBefehl 1.6 das grobe Brückensegment erstellt, anschließend sorgen die BefehleBefehl 1.7Befehl 1.8 dafür, dass die unteren Ecken des 3×3 Brückensegments entfernt werden. Hierbei müssen es fill-Befehle sein, da es beim Abbruch und erneuten Starten des Brückenbauers zu Lücken kommen kann, die der normale setblock-Befehl nicht füllen würde. Dann kommt die SchieneBefehl 1.9 samt ihrem GleisbettBefehl 1.10 auf die Brücke. Wenn der Spieler dann dies zum vierzehnten male macht, wird der Zähler dies erkennen und wieder auf null gesetzt. Darauf folgt dann ein komprimierter Befehl der den Pfeiler der Brücke unabhängig des Brückenbauers platziert. Hierbei werden größere Sockel um den Pfeiler gesetzt, wenn dieser ins Meer hineinragt, oder in einen Lavasee. Danach sorgt ein weiterer Ketten-Befehlsblock dafür, dass der Zähler immer sich um eins erhöhtBefehl 1.11. Wenn man die Brücke errichtet hat, kann man den Brückenbauer ausschalten, dabei werden die Punktestand-Ziele gelöscht sowie die Karottenrute in der Hand des Spielers.

Den Brückenbauer kann man so erweitern, dass er zwei GleiseBefehl 1.12Befehl 1.13 samt Gleisbetten legtBefehl 1.14Befehl 1.15. Er setzt sie dann zeitgleich in das Brückenfundament einBefehl 1.16. Alle Befehle müssen dann an die entsprechende Breite angepasst werden, während zwei weitere Befehlsblöcke für das zweite Gleis benötigt werden. Auch müssen dadurch zwei neue Befehlsblöcke gebaut werden, die die Antriebsschiene sowie die Redstone-Fackel setzen.


Befehlsblöcke mit Befehlen:



Variante 1: Start-Funktion

Editor Icon.png technik_wiki:brueckenbauer/v1start.mcfunction
# Die Punktestand-Ziele für die Schleichzeit und für die Materialien werden erstellt
scoreboard objectives add PZBruB.1Schl minecraft.custom:minecraft.sneak_time ["Brückenbauer.1: ",{"text":"Schleichzeit","bold":true}]
scoreboard objectives add PZBruB.1Gleis dummy ["Brückenbauer.1: ",{"text":"Schienen für den Verleger","bold":true}]
scoreboard objectives add PZBruB.1Andes dummy ["Brückenbauer.1: ",{"text":"Andesit für den Verleger","bold":true}]
scoreboard objectives add PZBruB.1Stein dummy ["Brückenbauer.1: ",{"text":"Steine für den Verleger","bold":true}]
scoreboard objectives add PZBruB.1Richt dummy ["Brückenbauer.1: ",{"text":"Richtung des Verleger","bold":true}]

# Der Spieler erhält einen Rüstungsständer, welcher platziert einen Brückenbauer erstellt
give @a[distance=..25] minecraft:armor_stand{display:{Name:"{\"text\":\"Brückenbauer\"}",Lore:["Brückenbauer.1"]},EntityTag:{Invisible:true,Small:true,NoGravity:true,CustomNameVisible:true,CustomName:"{\"text\":\"Brückenbauer\"}",Tags:["EtiBruB.1Alle","EtiBruB.1Verleger","EtiBruB.1Erstellen"],ArmorItems:[{},{},{},{id:"minecraft:magenta_glazed_terracotta",Count:1b} ],Pose:{Head:[0f,0f,180f] } } } 16


Variante 1: Zyklus-Funktion

Editor Icon.png technik_wiki:brueckenbauer/v1zyklus.mcfunction
# Wenn ein Rüstungsständer platziert wird, welcher das entsprechende Etikett besitzt, so wird die Erstellen-Funktion geladen
execute as @e[type=minecraft:armor_stand,tag=EtiBruB.1Erstellen] at @s run function technik_wiki:brueckenbauer/v1erstellen

# Wenn sich ein Spieler im Umkreis von zehn Blöcken um den Brückenbauer befindet, wird dieser entsprechend ausgerichtet
execute as @e[type=minecraft:armor_stand,tag=EtiBruB.1Verleger] at @s if entity @p[distance=..10] rotated ~ 0 run function technik_wiki:brueckenbauer/v1ausrichtung

# Wenn der Spieler im Umkreis schleicht und auf dem Boden steht, wird die Funktion geladen, die den Bau der Brücke startet
execute as @e[type=minecraft:armor_stand,tag=EtiBruB.1Verleger] at @s if entity @p[distance=..10,scores={PZBruB.1Schl=3..},nbt={OnGround:true}] rotated ~180 0 run function technik_wiki:brueckenbauer/v1bruecke

# Falls beim Bau der Brücke ein Pfeiler (Rüstungsständer) erstellt wurde, wird die Pfeiler-Funktion geladen
execute as @e[type=armor_stand,tag=EtiBruB.1Pfeiler] at @s run function technik_wiki:brueckenbauer/v1pfeiler

# Falls der Spieler mindestens drei Ticks lang geschlichen ist, wird ihm die Schleichzeit zurückgesetzt
scoreboard players reset @a[scores={PZBruB.1Schl=3..}] PZBruB.1Schl


Variante 1: Erstellen-Funktion

Editor Icon.png technik_wiki:brueckenbauer/v1erstellen.mcfunction
# Der Spieler erhält die benötigten Materialien, für den Bau der Brücken
give @p[distance=..10] minecraft:rail{display:{Lore:["Brückenbauer.1"] } } 64
give @p[distance=..10] minecraft:andesite{display:{Lore:["Brückenbauer.1"] } } 64
give @p[distance=..10] minecraft:stone{display:{Lore:["Brückenbauer.1"] } } 256

# Alle bisherigen Brückenbauer werden gelöscht, wenn ein neue Brückenbauer erstellt wird
kill @e[distance=0.9..,tag=EtiBruB.1Alle]

# Rüstungsständer mit einem bestimmten Block im Kopfslot werden erstellt, um die Brücken-Blöcke anschaulich zu machen
summon minecraft:armor_stand ~ ~ ~ {Invisible:true,Small:true,NoGravity:true,Marker:true,Tags:["EtiBruB.1Alle","EtiBruB.1Gleis1","EtiBruB.1Gleis","EtiBruB.1EineSpur"],ArmorItems:[{},{},{},{id:"minecraft:rail",Count:1b}]}
summon minecraft:armor_stand ~ ~ ~ {Invisible:true,Small:true,NoGravity:true,Marker:true,Tags:["EtiBruB.1Alle","EtiBruB.1Gleisbett1","EtiBruB.1Gleisbett","EtiBruB.1EineSpur"],ArmorItems:[{},{},{},{id:"minecraft:andesite",Count:1b}]}
summon minecraft:armor_stand ~ ~ ~ {Invisible:true,Small:true,NoGravity:true,Marker:true,Tags:["EtiBruB.1Alle","EtiBruB.1Rechts1","EtiBruB.1Gleisspur","EtiBruB.1EineSpur"],ArmorItems:[{},{},{},{id:"minecraft:smooth_stone",Count:1b}]}
summon minecraft:armor_stand ~ ~ ~ {Invisible:true,Small:true,NoGravity:true,Marker:true,Tags:["EtiBruB.1Alle","EtiBruB.1Links1","EtiBruB.1Gleisspur","EtiBruB.1EineSpur"],ArmorItems:[{},{},{},{id:"minecraft:smooth_stone",Count:1b}]}

# Falls der Brückenbauer Zweigleisig ist, werden weitere Rüstungsständer mit entsprechenden Block im Kopfslot erstellt
execute if entity @s[tag=EtiBruB.1ZweiSpuren] run summon minecraft:armor_stand ~ ~ ~ {Invisible:true,Small:true,NoGravity:true,Marker:true,Tags:["EtiBruB.1Alle","EtiBruB.1Gleis2","EtiBruB.1Gleis"],ArmorItems:[{},{},{},{id:"minecraft:rail",Count:1b}]}
execute if entity @s[tag=EtiBruB.1ZweiSpuren] run summon minecraft:armor_stand ~ ~ ~ {Invisible:true,Small:true,NoGravity:true,Marker:true,Tags:["EtiBruB.1Alle","EtiBruB.1Gleisbett2","EtiBruB.1Gleisbett"],ArmorItems:[{},{},{},{id:"minecraft:andesite",Count:1b}]}
execute if entity @s[tag=EtiBruB.1ZweiSpuren] run summon minecraft:armor_stand ~ ~ ~ {Invisible:true,Small:true,NoGravity:true,Marker:true,Tags:["EtiBruB.1Alle","EtiBruB.1Rechts2","EtiBruB.1Gleisspur"],ArmorItems:[{},{},{},{id:"minecraft:smooth_stone",Count:1b}]}

# Zuletzt wird vom Gleisverleger die Richtung auf null gesetzt und das Etikett entfernt
scoreboard players set @s[tag=EtiBruB.1Erstellen] PZBruB.1Richt 0
tag @s remove EtiBruB.1Erstellen


Variante 1: Ausrichtung-Funktion

Editor Icon.png technik_wiki:brueckenbauer/v1ausrichtung.mcfunction
# Der Brückenbauer schaut zum Spieler
teleport @s ~ ~ ~ facing entity @p feet

# Falls die Raster-Eigenschaft aktiviert ist, wird der Brückenbauer in eine der vier Himmelsrichtungen schauen
execute if entity @s[tag=!EtiBruB.1KeinRaster,y_rotation=135..-135] rotated 180 0 run teleport @s ~ ~ ~ 180 ~
execute if entity @s[tag=!EtiBruB.1KeinRaster,y_rotation=-135..-45] rotated -90 0 run teleport @s ~ ~ ~ -90 ~
execute if entity @s[tag=!EtiBruB.1KeinRaster,y_rotation=-45..45] rotated 0 0 run teleport @s ~ ~ ~ 0 ~
execute if entity @s[tag=!EtiBruB.1KeinRaster,y_rotation=45..135] rotated 90 0 run teleport @s ~ ~ ~ 90 ~

# Die Rüstungsständer mit entsprechenden Block im Kopfslot werden von dem Blickwinkel des Brückenbauers entsprechend ausgerichtet
teleport @e[type=minecraft:armor_stand,tag=EtiBruB.1Gleis1,sort=nearest,limit=1] ^ ^0.5 ^1 facing entity @p feet
teleport @e[type=minecraft:armor_stand,tag=EtiBruB.1Gleisbett1,sort=nearest,limit=1] ^ ^ ^1 facing entity @p feet
teleport @e[type=minecraft:armor_stand,tag=EtiBruB.1Rechts1,sort=nearest,limit=1] ^1 ^ ^1 facing entity @p feet
teleport @e[type=minecraft:armor_stand,tag=EtiBruB.1Links1,sort=nearest,limit=1] ^-1 ^ ^1 facing entity @p feet

# Falls der Brückenbauer für zwei Gleise aktiviert wurde, werden auch die weiteren Rüstungsständer anhand des Blickwinkels entsprechend positioniert
execute if entity @s[tag=EtiBruB.1ZweiSpuren] run teleport @e[type=minecraft:armor_stand,tag=EtiBruB.1Gleis2,sort=nearest,limit=1] ^-2 ^0.5 ^1 facing entity @p feet
execute if entity @s[tag=EtiBruB.1ZweiSpuren] run teleport @e[type=minecraft:armor_stand,tag=EtiBruB.1Gleisbett2,sort=nearest,limit=1] ^-2 ^ ^1 facing entity @p feet
execute if entity @s[tag=EtiBruB.1ZweiSpuren] run teleport @e[type=minecraft:armor_stand,tag=EtiBruB.1Rechts2,sort=nearest,limit=1] ^-3 ^ ^1 facing entity @p feet

# Wenn der Spieler eine Schiene vor den Brückenbauer wirft, wird diese gelöscht und der Brückenbauer wird für zwei Gleise aktiviert
execute if entity @p[distance=1.5..10] run tag @e[distance=..2,type=minecraft:item,tag=!EtiBruB.1ZweiSpuren,nbt={Item:{id:"minecraft:rail",Count:1b} } ] add EtiBruB.1ZweiSpuren
execute if entity @e[distance=..2,type=minecraft:item,tag=EtiBruB.1ZweiSpuren] run tag @s add EtiBruB.1Erstellen
execute if entity @e[distance=..2,type=minecraft:item,tag=EtiBruB.1ZweiSpuren] run tag @s add EtiBruB.1ZweiSpuren
execute if entity @e[distance=..2,type=minecraft:item,tag=EtiBruB.1ZweiSpuren] run tellraw @a[distance=..10] ["Brückenbauer.1: ",{"text":"Der Brückenbauer platziert nun zwei Gleisspuren","bold":true}]
kill @e[distance=..2,type=minecraft:item,tag=EtiBruB.1ZweiSpuren]

# Wenn der Spieler Stein vor den Brückenbauer wirft, so baut der Brückenbauer im weiteren Verlauf die Segmente nach unten
execute if entity @p[distance=1.5..10] run tag @e[distance=..2,type=minecraft:item,tag=!EtiBruB.1NachUnten,nbt={Item:{id:"minecraft:stone",Count:1b} } ] add EtiBruB.1NachUnten
execute if entity @e[distance=..2,type=minecraft:item,tag=EtiBruB.1NachUnten] run scoreboard players remove @s[scores={PZBruB.1Richt=-1..}] PZBruB.1Richt 1
execute if entity @s[scores={PZBruB.1Richt=-2}] if entity @e[distance=..2,type=minecraft:item,tag=EtiBruB.1NachUnten] run tellraw @a[distance=..10] ["Brückenbauer.1: ",{"text":"Der Brückenbauer bewegt sich nun je nach Gelände nach ","bold":true},{"text":"oben, vorwärts oder nach unten","color":"yellow","bold":true}]
execute if entity @s[scores={PZBruB.1Richt=-1}] if entity @e[distance=..2,type=minecraft:item,tag=EtiBruB.1NachUnten] run tellraw @a[distance=..10] ["Brückenbauer.1: ",{"text":"Der Brückenbauer bewegt sich nun nach ","bold":true},{"text":"unten","color":"gold","bold":true}]
execute if entity @s[scores={PZBruB.1Richt=0}] if entity @e[distance=..2,type=minecraft:item,tag=EtiBruB.1NachUnten] run tellraw @a[distance=..10] ["Brückenbauer.1: ",{"text":"Der Brückenbauer bewegt sich nun ","bold":true},{"text":"vorwärts","color":"green","bold":true}]
kill @e[distance=..2,type=minecraft:item,tag=EtiBruB.1NachUnten]

# Wirft der Spieler Andesit vor den Brückenbauer, so baut er weitere Segmente nach oben
execute if entity @p[distance=1.5..10] run tag @e[distance=..2,type=minecraft:item,tag=!EtiBruB.1NachOben,nbt={Item:{id:"minecraft:andesite",Count:1b} } ] add EtiBruB.1NachOben
execute if entity @e[distance=..2,type=minecraft:item,tag=EtiBruB.1NachOben] run scoreboard players add @s[scores={PZBruB.1Richt=..0}] PZBruB.1Richt 1
execute if entity @s[scores={PZBruB.1Richt=1}] if entity @e[distance=..2,type=minecraft:item,tag=EtiBruB.1NachOben] run tellraw @a[distance=..10] ["Brückenbauer.1: ",{"text":"Der Brückenbauer bewegt sich nun nach ","bold":true},{"text":"oben","color":"blue","bold":true}]
execute if entity @s[scores={PZBruB.1Richt=0}] if entity @e[distance=..2,type=minecraft:item,tag=EtiBruB.1NachOben] run tellraw @a[distance=..10] ["Brückenbauer.1: ",{"text":"Der Brückenbauer bewegt sich nun ","bold":true},{"text":"vorwärts","color":"green","bold":true}]
execute if entity @s[scores={PZBruB.1Richt=-1}] if entity @e[distance=..2,type=minecraft:item,tag=EtiBruB.1NachOben] run tellraw @a[distance=..10] ["Brückenbauer.1: ",{"text":"Der Brückenbauer bewegt sich nun nach ","bold":true},{"text":"unten","color":"gold","bold":true}]
kill @e[distance=..2,type=minecraft:item,tag=EtiBruB.1NachOben]

# Das Raster wird der Brückenbauer los, wenn man einen Rüstungsständer vor ihn wirft
execute if entity @p[distance=1.5..10] run tag @e[distance=..2,type=minecraft:item,tag=!EtiBruB.1KeinRaster,nbt={Item:{id:"minecraft:armor_stand",Count:1b} } ] add EtiBruB.1KeinRaster
execute if entity @e[distance=..2,type=minecraft:item,tag=EtiBruB.1KeinRaster] run tag @s add EtiBruB.1KeinRaster
execute if entity @e[distance=..2,type=minecraft:item,tag=EtiBruB.1KeinRaster] run tellraw @a[distance=..10] ["Brückenbauer.1: ",{"text":"Der Brückenbauer ist nicht mehr am Raster gebunden und kann nun auch diagonale Gleisspuren verlegen","bold":true}]
kill @e[distance=..2,type=minecraft:item,tag=EtiBruB.1KeinRaster]


Variante 1: Brücke-Funktion

Editor Icon.png technik_wiki:brueckenbauer/v1bruecke.mcfunction
# Um den Spieler einfacher erkennen zu können, wird ihm zeitweilig ein Etikett gegeben
tag @p[distance=..10,scores={PZBruB.1Schl=1..}] add EtiBruB.1Spieler

# Jedes Material des Spielers wird ausgelesen und in ein Punktestand-Ziel gespeichert
execute as @p[distance=..10,tag=EtiBruB.1Spieler] store result score @s PZBruB.1Gleis run clear @s minecraft:rail 0
execute as @p[distance=..10,tag=EtiBruB.1Spieler] store result score @s PZBruB.1Andes run clear @s minecraft:andesite 0
execute as @p[distance=..10,tag=EtiBruB.1Spieler] store result score @s PZBruB.1Stein run clear @s minecraft:stone 0

# Wenn die Anzahl der Materialien ausreichend ist, wird ihm die entsprechende Anzahl entfernt
clear @p[distance=..10,tag=EtiBruB.1Spieler,scores={PZBruB.1Gleis=2..,PZBruB.1Andes=2..,PZBruB.1Stein=10..}] minecraft:rail 1
clear @p[distance=..10,tag=EtiBruB.1Spieler,scores={PZBruB.1Gleis=2..,PZBruB.1Andes=2..,PZBruB.1Stein=10..}] minecraft:andesite 1
clear @p[distance=..10,tag=EtiBruB.1Spieler,scores={PZBruB.1Gleis=2..,PZBruB.1Andes=2..,PZBruB.1Stein=10..}] minecraft:stone 6

# Wenn der Brückenbauer für zwei Fahrspuren aktiviert wurde, werden weitere Materialien abgezogen
execute if entity @s[tag=EtiBruB.1ZweiSpuren] run clear @p[distance=..10,tag=EtiBruB.1Spieler,scores={PZBruB.1Gleis=2..,PZBruB.1Andes=2..,PZBruB.1Stein=10..}] minecraft:rail 1
execute if entity @s[tag=EtiBruB.1ZweiSpuren] run clear @p[distance=..10,tag=EtiBruB.1Spieler,scores={PZBruB.1Gleis=2..,PZBruB.1Andes=2..,PZBruB.1Stein=10..}] minecraft:stone 4

# Hat der Spieler genug Materialien bei sich gehabt, so wird die Funktion für das Brücken verlegen aufgerufen
execute if entity @p[tag=EtiBruB.1Spieler,scores={PZBruB.1Gleis=2..,PZBruB.1Andes=2..,PZBruB.1Stein=10..}] run function technik_wiki:brueckenbauer/v1bruecke_verlegen_1
execute as @p[distance=..10,tag=EtiBruB.1Spieler] unless entity @s[scores={PZBruB.1Gleis=2..,PZBruB.1Andes=2..,PZBruB.1Stein=10..}] run tellraw @s ["Brückenbauer.1 ",{"text":"Du hast zu wenig Blöcke bei dir!","bold":true}]

# Zu guter letzt wird das Etikett zur vereinfachten Erkennung des Spielers wieder entfernt
tag @p[distance=..10,tag=EtiBruB.1Spieler] remove EtiBruB.1Spieler


Variante 1: Brücke-Verlegen-1-Funktion

Editor Icon.png technik_wiki:brueckenbauer/v1bruecke_verlegen_1.mcfunction
# Die Brückensegmente, die Gleisfahrspur und das Gleisbett werden platziert. Zuvor wird, falls der Brückenbauer sich im Untegrund befindet, ein Luftraum erstellt und ggf. verglast, damit keine Flüssigkeiten eindringen
execute at @e[distance=..5,type=minecraft:armor_stand,tag=EtiBruB.1Gleisbett,sort=nearest,limit=2] align xyz positioned ~0.5 ~0.5 ~0.5 rotated ~ 0 run fill ^2 ^ ^1 ^-2 ^4 ^-4 minecraft:light_gray_stained_glass replace #technik_wiki:brueckenbauer/v1berg_und_meeres_bloecke
execute at @e[distance=..5,type=minecraft:armor_stand,tag=EtiBruB.1Gleisbett,sort=nearest,limit=2] align xyz positioned ~0.5 ~0.5 ~0.5 rotated ~ 0 run fill ^1 ^1 ^ ^-1 ^3 ^-1 minecraft:air replace
execute at @e[distance=..5,type=minecraft:armor_stand,tag=EtiBruB.1Gleisbett,sort=nearest,limit=2] rotated ~ 0 run fill ~ ~-1 ~ ~ ~-2 ~ minecraft:smooth_stone replace
execute at @e[distance=..5,type=minecraft:armor_stand,tag=EtiBruB.1Gleisbett,sort=nearest,limit=2] rotated ~ 0 run setblock ~ ~ ~ minecraft:andesite replace
execute at @e[distance=..5,type=minecraft:armor_stand,tag=EtiBruB.1Gleisspur,sort=nearest,limit=3] rotated ~ 0 run fill ~ ~ ~ ~ ~-1 ~ minecraft:smooth_stone replace
execute at @e[distance=..5,type=minecraft:armor_stand,tag=EtiBruB.1Gleis,sort=nearest,limit=2] rotated ~ 0 run setblock ~ ~1 ~ minecraft:rail replace

# Jeder Meter wird gezählt und wenn der Brückenbauer vierzehn Blöcke weit ist, wird die Funktion geladen. Falls der Brückenverleger in Richtung diagonal nach oben fährt, wird der Wert schon bei sechs Metern auf vierzehn gesetzt, damit ebenfalls die Funktion ausgeführt wird.
scoreboard players add @s PZBruB.1Schl 1
scoreboard players set @s[scores={PZBruB.1Richt=1,PZBruB.1Schl=6..}] PZBruB.1Schl 14
execute if entity @s[scores={PZBruB.1Schl=14..}] run function technik_wiki:brueckenbauer/v1bruecke_verlegen_2
scoreboard players set @s[scores={PZBruB.1Schl=14..}] PZBruB.1Schl 0

# Der Brückenbauer wird horizontal einen Block nach von vorne teleportiert
execute rotated ~ 0 run teleport @s ^ ^ ^1

# Falls der Brückenbauer die Richtungseinstellung -2 besitzt, dann wird er je nach Gelände entsprechend angepasst und teleportiert
execute at @s[scores={PZBruB.1Richt=-2}] rotated ~ 0 unless block ^ ^ ^1 minecraft:air unless block ^ ^ ^1 #minecraft:rails run teleport @s ~ ~1 ~
execute at @s[scores={PZBruB.1Richt=-2}] rotated ~ 0 if block ^ ^-1 ^1 minecraft:air run teleport @s ~ ~-1 ~
execute at @s[scores={PZBruB.1Richt=-2}] rotated ~ 0 if block ^ ^-1 ^-1 #minecraft:rails run teleport @s ~ ~-1 ~

# Falls der Brückenbauer nach unten oder nach oben fahren soll, wird er entsprechend neu positioniert
execute at @s[scores={PZBruB.1Richt=-1}] rotated ~ 0 run teleport @s ~ ~-1 ~
execute at @s[scores={PZBruB.1Richt=1}] rotated ~ 0 run teleport @s ~ ~1 ~


Variante 1: Brücke-Verlegen-2-Funktion

Editor Icon.png technik_wiki:brueckenbauer/v1bruecke_verlegen_2.mcfunction
# Die Oberleitung wird erstellt
setblock ^1 ^ ^-1 minecraft:stone_bricks replace
setblock ^1 ^1 ^-1 minecraft:spruce_fence replace
setblock ^1 ^2 ^-1 minecraft:spruce_planks replace
setblock ^ ^1 ^-1 minecraft:powered_rail replace

# Je nach Blickrichtung, wird die Redstone-Fackel entsprechend ausgerichtet platziert
execute if entity @s[y_rotation=135..-135] run setblock ^ ^2 ^-1 minecraft:redstone_wall_torch[facing=west] replace
execute if entity @s[y_rotation=-135..-45] run setblock ^ ^2 ^-1 minecraft:redstone_wall_torch[facing=north] replace
execute if entity @s[y_rotation=-45..45] run setblock ^ ^2 ^-1 minecraft:redstone_wall_torch[facing=east] replace
execute if entity @s[y_rotation=45..135] run setblock ^ ^2 ^-1 minecraft:redstone_wall_torch[facing=south] replace

# Falls der Brückenbauer für zwei Gleisspuren ausgelegt wurde, wird für das zweite Gleis ebenfalls eine Redstone-Fackel samt Antriebsschiene platziert
execute if entity @s[tag=EtiBruB.1ZweiSpuren] run setblock ^2 ^1 ^-1 minecraft:powered_rail replace
execute if entity @s[tag=EtiBruB.1ZweiSpuren,y_rotation=135..-135] run setblock ^2 ^2 ^-1 minecraft:redstone_wall_torch[facing=east] replace
execute if entity @s[tag=EtiBruB.1ZweiSpuren,y_rotation=-135..-45] run setblock ^2 ^2 ^-1 minecraft:redstone_wall_torch[facing=south] replace
execute if entity @s[tag=EtiBruB.1ZweiSpuren,y_rotation=-45..45] run setblock ^2 ^2 ^-1 minecraft:redstone_wall_torch[facing=west] replace
execute if entity @s[tag=EtiBruB.1ZweiSpuren,y_rotation=45..135] run setblock ^2 ^2 ^-1 minecraft:redstone_wall_torch[facing=north] replace

# Falls der Brückenbauer sich unterm Meer befindet, wurden Glasblöcke platziert. Manche davon werden nun durch Steinziegel ersetzt, um daraus einen Ring zu bilden, der die Glasfassade hält
execute at @e[distance=..5,type=minecraft:armor_stand,tag=EtiBruB.1Gleisbett,sort=nearest,limit=2] align xyz positioned ~0.5 ~0.5 ~0.5 rotated ~ 0 run fill ^2 ^ ^ ^-2 ^4 ^ minecraft:stone_bricks replace minecraft:light_gray_stained_glass

# Ein Rüstungsständer, der den Pfeiler konstruieren wird, wird platziert und falls der Brückenbauer zwei Spuren hat, wird der Pfeiler mittig zentriert
execute align y run summon minecraft:armor_stand ^ ^-2 ^-1 {Small:true,Invulnerable:true,NoGravity:true,Tags:["EtiBruB.1Alle","EtiBruB.1Pfeiler"]}
execute align y if entity @s[tag=EtiBruB.1ZweiSpuren] run teleport @e[type=minecraft:armor_stand,tag=EtiBruB.1Pfeiler] ^1 ^-2 ^-1


Variante 1: Pfeiler-Funktion

Editor Icon.png technik_wiki:brueckenbauer/v1pfeiler.mcfunction
# Pro Ebene wird ein 3x3 Bereich mit glatten Stein ausgefüllt. Falls der Pfeiler in eine Flüssigkeit eintaucht, wird der Sockel breiter
fill ~-1 ~ ~-1 ~1 ~1 ~1 minecraft:smooth_stone replace minecraft:air
teleport @s ~ ~-1 ~
execute if block ~ ~-1 ~ minecraft:water run fill ~-2 ~ ~-2 ~2 ~ ~2 minecraft:smooth_stone replace #technik_wiki:brueckenbauer/v1berg_und_meeres_bloecke
execute at @s unless block ~ ~ ~ minecraft:air unless block ~ ~ ~ #technik_wiki:brueckenbauer/v1berg_und_meeres_bloecke run fill ~-2 ~3 ~-2 ~2 ~-10 ~2 minecraft:smooth_stone replace #technik_wiki:brueckenbauer/v1berg_und_meeres_bloecke
execute at @s unless block ~ ~ ~ minecraft:air unless block ~ ~ ~ #technik_wiki:brueckenbauer/v1berg_und_meeres_bloecke run kill @s


Variante 1: Stopp-Funktion

Editor Icon.png technik_wiki:brueckenbauer/v1stopp.mcfunction
# Die Punktestand-Ziele werden gelöscht
scoreboard objectives remove PZBruB.1Schl
scoreboard objectives remove PZBruB.1Gleis
scoreboard objectives remove PZBruB.1Andes
scoreboard objectives remove PZBruB.1Stein
scoreboard objectives remove PZBruB.1Richt

# Alle Gegenstände für den Brückenbauer werden wieder entfernt
clear @a[distance=..25] minecraft:armor_stand{display:{Lore:["Brückenbauer.1"] } }
clear @a[distance=..25] minecraft:rail{display:{Lore:["Brückenbauer.1"] } }
clear @a[distance=..25] minecraft:stone{display:{Lore:["Brückenbauer.1"] } }
clear @a[distance=..25] minecraft:andesite{display:{Lore:["Brückenbauer.1"] } }

# Der Brückenbauer, wie auch Gegenstände die auf dem Boden liegen werden entfernt
kill @e[tag=EtiBruB.1Alle]
kill @e[type=minecraft:item,nbt={tag:{display:{Lore:["Brückenbauer.1"] } } } ]

Variante 2[Bearbeiten | Quelltext bearbeiten]

Schienenverkehrsanlagen Symbol.png
Diese Technik ist noch nicht in der aktuellen Schienen-Welt vorhanden.
In einem der nächsten Updates wird sie dort hinzugefügt werden.

Schienenverkehrsanlagen Brückenbauer (Befehle) Bild 1.1.png Schienenverkehrsanlagen Brückenbauer (Befehle) Bild 1.2.png Schienenverkehrsanlagen Brückenbauer (Befehle) Bild 1.3.png Schienenverkehrsanlagen Brückenbauer (Befehle) Bild 1.4.png

Mit der ersten Variante lassen sich Brücken über Land und Meer bauen. Damit man aber auch Seebrücken welche unter dem Meeresspiegel verlaufen, erstellen kann, wurde der Brückenbauer um eine platzierbare Glasfassade erweitert. Diese schützt vor eindringendem Wasser, welches die Hebel oder Redstone-Fackel zerstören würde. Das gleiche gilt auch für die Seebrücke an sich. So wird zuerst ein 4×5 großer Glaskasten durch den BefehlBefehl 2.1 auf das Brückensegment gesetzt, welches dann durch den BefehlBefehl 2.2 ausgehöhlt wird. Zuvor jedoch, wurden die Schienen gesetzt und in einem Abstand von 14 Blöcken, platziert der komprimierte Befehl Antriebsschienen. Die Variante wurde so konzipiert, dass auch unter dem Meer das Wasser nicht in den gerade gesetzten Glastunnel eindringen kann. Denn die Glasfassade wird erst dann ausgehöhlt, wenn diese bereits eine weitere Schicht vor dem Eindringen von Wasser schützt. Sonst aber gleicht sich der Brückenbauer sehr mit der ersten Variante.

Genau die gleiche Vorgehensweise kann man auch bei einem zweigleisigen System für Brücken nutzen. Die GlasfassadeBefehl 2.3 sowie die BrückeBefehl 2.4 müssen entsprechend verbreitert werden, während der Pfeiler, der durch den komprimierten Befehl gesetzt wird, bei seiner Größe bleibt. Es werden vier neue Befehlsblöcke gebraucht, die für das zweite GleisBefehl 2.5Befehl 2.6Befehl 2.7Befehl 2.8 sorgen.


Befehlsblöcke mit Befehlen:



Variante 2: Start-Funktion

Editor Icon.png technik_wiki:brueckenbauer/v2start.mcfunction
# Dem Spieler werden drei Rüstungsständer gegeben die bestimmte Brückenbauteile erzeugen
give @a[distance=..25] minecraft:armor_stand{Brueckenbauer.2:true,display:{Name:"{\"text\":\"Brückenstrecke\"}"},EntityTag:{Tags:["EtiBruB.2Alle","EtiBruB.2Bauwerk","EtiBruB.2Brueckenstrecke"]} } 1
give @a[distance=..25] minecraft:armor_stand{Brueckenbauer.2:true,display:{Name:"{\"text\":\"Pfeilersockel\"}"},EntityTag:{Tags:["EtiBruB.2Alle","EtiBruB.2Bauwerk","EtiBruB.2Pfeilersockel"]} } 1
give @a[distance=..25] minecraft:armor_stand{Brueckenbauer.2:true,display:{Name:"{\"text\":\"Pfeiler\"}"},EntityTag:{Tags:["EtiBruB.2Alle","EtiBruB.2Bauwerk","EtiBruB.2Pfeiler"]} } 1


Variante 2: Zyklus-Funktion

Editor Icon.png technik_wiki:brueckenbauer/v2zyklus.mcfunction
# Sobald der Rüstungsständer platziert ist, wird für diesen die entsprechende Funktion aufgerufen
execute as @e[type=minecraft:armor_stand,tag=EtiBruB.2Brueckenstrecke] at @s run function technik_wiki:brueckenbauer/v2bruecke

# Falls einer der entsprechenden Rüstungsständer platziert wird, wird ein Konstruktionsblock platziert, der später mit dem Redstone-Block die Konstruktion lädt
execute as @e[type=minecraft:armor_stand,tag=EtiBruB.2Pfeilersockel] at @s run setblock ~ ~ ~ minecraft:structure_block{rotation:"NONE",mode:"LOAD",posX:-1,posY:0,posZ:-1,name:"technik_wiki:brueckenbauer/v2pfeilersockel"} replace
execute as @e[type=minecraft:armor_stand,tag=EtiBruB.2Pfeiler] at @s run setblock ~ ~ ~ minecraft:structure_block{rotation:"NONE",mode:"LOAD",posX:-1,posY:0,posZ:-1,name:"technik_wiki:brueckenbauer/v2pfeiler"} replace

# Sobald einer der Rüstungsständer platziert wurde, wird ein Redstone-Block einen Block nebendran platziert um die Konstruktion zu laden
execute at @e[type=minecraft:armor_stand,tag=EtiBruB.2Bauwerk] run setblock ~ ~ ~1 minecraft:redstone_block replace

# Der platzierte Rüstungsständer wird anschließend gelöscht
kill @e[type=minecraft:armor_stand,tag=EtiBruB.2Bauwerk]


Variante 2: Brücke-Funktion

Editor Icon.png technik_wiki:brueckenbauer/v2bruecke.mcfunction
# Je nach Blickwinkel des Spielers wird der entsprechende Konstruktionsblock platziert
execute as @p if entity @s[y_rotation=135..45] unless entity @s[y_rotation=-135..-45] run setblock ~ ~ ~ minecraft:structure_block{rotation:"NONE",mode:"LOAD",posX:-1,posY:0,posZ:-1,name:"technik_wiki:brueckenbauer/v2brueckenstrecke"} replace
execute as @p if entity @s[y_rotation=-135..135] unless entity @s[y_rotation=-45..45] run setblock ~ ~ ~ minecraft:structure_block{rotation:"CLOCKWISE_90",mode:"LOAD",posX:1,posY:0,posZ:-1,name:"technik_wiki:brueckenbauer/v2brueckenstrecke"} replace


Variante 2: Stopp-Funktion

Editor Icon.png technik_wiki:brueckenbauer/v2stopp.mcfunction
# Löscht alle Gegenstände aus dem Inventar
clear @a[distance=..25] minecraft:armor_stand{Brueckenbauer.2:true}

# Gegenstände für den Brückenbauer erhalten das Etikett, welches im Anschluss auch für alle anderen Brückenbauer verwendet wird um sie zu löschen
tag @e[type=minecraft:item,nbt={Item:{tag:{Brueckenbauer.2:true} } }] add EtiBruB.2Alle
kill @e[tag=EtiBruB.2Alle]

Variante 3[Bearbeiten | Quelltext bearbeiten]

Schienenverkehrsanlagen Symbol.png
Diese Technik ist noch nicht in der aktuellen Schienen-Welt vorhanden.
In einem der nächsten Updates wird sie dort hinzugefügt werden.

Schienenverkehrsanlagen Brückenbauer (Befehle) Bild 3.1.png Schienenverkehrsanlagen Brückenbauer (Befehle) Bild 3.2.png Schienenverkehrsanlagen Brückenbauer (Befehle) Bild 3.3.png Schienenverkehrsanlagen Brückenbauer (Befehle) Bild 3.4.png

Der Brückenbauer baut für die Eisenbahn extra vorgefertigte Wege als Brücke. Der BefehlBefehl 3.1 sorgt für die Fortbewegung. Der BefehlBefehl 3.2 setzt das Brückensegment, der BefehlBefehl 3.3 das Gleisbett und die BefehleBefehl 3.4Befehl 3.5 sorgen dann für eine Abrundung. Die BefehleBefehl 3.6Befehl 3.7 sorgen für die Gleise. Ein Zähler gibt jeden zweiten TaktBefehl 3.8 des Wiederhol-Befehlsblockes an den BefehlBefehl 3.9, damit die Holzplanken gesetzt werden. Es gibt aber noch einen zweiten Zähler, der beim 14. Takt ein Signal an den Ketten-Befehlsblock mit komprimierten Befehl abgibt, der dafür sorgt, dass der Brückenpfeiler errichtet wird. Die beiden Zähler werden pro Takt um eins erhöhtBefehl 3.10Befehl 3.11. Wird der Brückenverleger ausgeschaltet, so werden die Punktestand-Ziele gelöscht und die Karottenrute aus der Hand genommenBefehl 3.12Befehl 3.13Befehl 3.14Befehl 3.15Befehl 3.16.

Der Brückenbauer für beide Schienen ist relativ einfach erweitert. Es wird auf einer Seite eine vollständige Schiene platziertBefehl 3.17Befehl 3.18Befehl 3.19Befehl 3.20. Anschließend wird diese fertige Schiene einfach kopiert und auf die andere Seite parallel zu der ersten gesetztBefehl 3.21. wird ein weitere Befehlsblöcke angebracht werden sowie drei Befehlsblöcke für den zweiten Pfeiler. Genauso müssen alle Befehle an die breitere Brücke angepasst werdenBefehl 3.22Befehl 3.23Befehl 3.24. Ebenso muss der Ketten-Befehlsblock so angepasst werden, dass der komprimierte Befehl auf einem soliden Block landet.


Befehlsblöcke mit Befehlen:
fill ~-4 ~ ~-4 ~-4 ~-2 ~2 iron_block
scoreboard players reset @p[r=25,score_Brueckenzaeler5_min=2] Brueckenzaeler5
fill ~-3 ~ ~-3 ~-3 ~ ~1 wooden_slab 1
setblock ~-2 ~ ~ stone_brick_stairs 2
setblock ~-1 ~-1 ~-2 stone_brick_stairs 3
fill ~-4 ~-2 ~1 ~-4 ~-2 ~-3 stone 5
fill ~-4 ~-4 ~3 ~-5 ~-4 ~3 air
fill ~-4 ~-4 ~-2 ~-5 ~-4 ~-2 air
scoreboard players add @p[r=25] Brueckenzaeler5 1
scoreboard players add @p[r=25] Brueckenzaeler5b 1


clone ~ ~ ~ ~3 ~-2 ~2 ~1 ~-2 ~ replace move


scoreboard objectives remove Bruecke5a
scoreboard objectives remove Bruecke5b
clear @p[r=10] minecraft:carrot_on_a_stick 0 9999
scoreboard objectives remove Brueckenzaeler5
scoreboard objectives remove Brueckenzaeler5b

Befehlsblöcke mit Befehlen:
fill ~-4 ~ ~-8 ~-4 ~-1 ~6 iron_block
scoreboard players reset @p[r=25,score_Brueckenzaeler6_min=2] Brueckenzaeler6
fill ~-3 ~ ~5 ~-3 ~ ~1 wooden_slab 1
setblock ~-2 ~ ~4 stone_brick_stairs 2
setblock ~-1 ~-1 ~2 stone_brick_stairs 3
fill ~-4 ~-2 ~5 ~-4 ~-2 ~-7 stone 5
fill ~-4 ~-4 ~6 ~-4 ~-4 ~-6 iron_block


clone ~-3 ~-1 ~6 ~-3 ~-1 ~2 ~-3 ~-1 ~-6


Disambig color.svg