Das offizielle Minecraft Wiki twittert hier: Wiki-Twitter  –  Chatte im Wiki-Discord  – Noch keinen Server gefunden? Es gibt einen Wiki-Server

Hello there! We are conducting a survey to better understand the user experience in making a first edit. If you have ever made an edit on Gamepedia, please fill out the survey. Thank you!

Zähler (Befehle)

Aus Technik Wiki
(Weitergeleitet von Schaltnetze/Zähler (Befehle))
Wechseln zu: Navigation, Suche
Gruppe: Grid Redstone-Verstärker.png
Schaltnetze

Grid Roter Sand blass.png mit Mechaniken

Grid Redstone.png mit Redstone
                Hier:
Grid Befehlsblock.png mit Befehlen

Die vorgestellte Technik kann in der Redstone-Welt angesehen werden.

Grid Redstone-Block.png mehr Redstone

Ein Zähler kann Werte um eine bestimmte Anzahl erhöhen. Er kann auch als Countdown (fürs Runterzählen) benutzt werden, dann muss einfach ein bestimmter Wert vorher eingetragen werden und der Zähler zählt runter bis der Schlusswert erreicht wurde.

Variante 1[Bearbeiten | Quelltext bearbeiten]

Redstone-Schaltkreise Symbol.png
Diese neue oder überarbeitete Technik ist noch nicht in der aktuellen Redstone-Welt vorhanden.
In einem der nächsten Updates wird sie dort hinzugefügt werden.

Zähler (Befehle) Bild 1.1.png

Dieser Zähler ermöglicht es, dass man eine Variable hochzählen kann. Man klickt in dem Chat auf die Variable und diese erhöht sich um eins.

Einschalten
  • Befehl 1.1 Das Auslöser-Punktestand-Ziel (trigger) wird erstellt.
  • Befehl 1.2 Die Ergebnis-Variable mit dem Wert null wird gesetzt.
Wiederholen
  • Befehl 1.3 Wenn man auf die Variable im Chat-Fenster geklickt hat, wird die Ergebnis-Variable um eins erhöht.
  • Befehl 1.4 Wenn die Ergebnis-Variable angelegt wurde, wird nach Spielern in einem Umkreis von 25 Metern Ausschau gehalten und nur wenn sie nicht den Wert null besitzen erhalten sie die Chat-Nachricht. In dieser wird die Variable mit aktuellen Wert angezeigt. Auf diese kann man klicken, um den Wert um eins zu erhöhen.
  • Befehl 1.5 Spieler die im Umkreis von 25 Metern nicht den Wert null besitzen, erhalten die Erlaubnis für den Auslöser auszulösen und erhalten den Wert null[B1.6].
Ausschalten
  • Befehl 1.7 Das Punktestand-Ziel wird gelöscht und somit auch die Variable.

Befehlsblöcke mit Befehlen:
scoreboard objectives add PZZaehl.1Wert trigger ["Zähler.1: ",{"text":"Wert der Variablen","bold":true}]
scoreboard players set VarZaehl.1Ergebnis PZZaehl.1Wert 0


execute if entity @a[distance=..25,scores={PZZaehl.1Wert=1}] run scoreboard players add VarZaehl.1Ergebnis PZZaehl.1Wert 1
execute if score VarZaehl.1Ergebnis PZZaehl.1Wert matches 0.. as @a[distance=..25] unless entity @s[scores={PZZaehl.1Wert=0}] run tellraw @s ["Zähler.1: ",{"text":"\nvar + 1 = ","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"Tippe für den Wert + 1"} },"clickEvent":{"action":"run_command","value":"/trigger PZZaehl.1Wert set 1"} },{"score":{"name":"VarZaehl.1Ergebnis","objective":"PZZaehl.1Wert"},"color":"dark_purple","bold":true}]
execute as @a[distance=..25] unless entity @s[scores={PZZaehl.1Wert=0}] run scoreboard players enable @s PZZaehl.1Wert
execute as @a[distance=..25] unless entity @s[scores={PZZaehl.1Wert=0}] run scoreboard players set @s PZZaehl.1Wert 0


scoreboard objectives remove PZZaehl.1Wert

Variante 2[Bearbeiten | Quelltext bearbeiten]

Redstone-Schaltkreise Symbol.png
Diese neue oder überarbeitete Technik ist noch nicht in der aktuellen Redstone-Welt vorhanden.
In einem der nächsten Updates wird sie dort hinzugefügt werden.

Zähler (Befehle) Bild 2.1.png

Mit diesem Zähler lässt sich eine Variable um einen eingestellten Wert hochzählen. Man stellt zuerst die Variable auf einen bestimmten Wert und die Ergebnis-Variable wird um diesen Wert anschließend erhöht.

Einschalten
  • Befehl 2.1 Das Auslöser-Punktestand-Ziel wird erstellt.
  • Befehl 2.2 Die Ergebnis-Variable und die Variable werden mit dem Wert null gesetzt, in dem sie in einer Rechenoperation gleichgesetzt werden. Wenn Variablen wie in diesen Fall noch keine Wert besitzen, erhalten sie automatisch den Wert null.
Wiederholen
  • Befehl 2.3 Wenn man auf die Variable im Chat-Fenster geklickt hat, wird die Variable um eins erhöht.
  • Befehl 2.4 Wenn man auf die Ergebnis-Variable geklickt hat, wird der neue Wert aus dem bisherigen Ergebnis plus dem Wert der Variable zusammen addiert und in die Ergebnis-Variable gesteckt.
  • Befehl 2.5 Wenn die Ergebnis-Variable angelegt wurde, wird nach Spielern in einem Umkreis von 25 Metern Ausschau gehalten und nur wenn sie nicht den Wert null besitzen erhalten sie die Chat-Nachricht. In dieser werden die Variablen mit aktuellen Wert angezeigt. Auf diese kann man klicken, um zum einen den Wert der Variable um eins zu erhöhen oder um den Wert der Ergebnis-Variable um den Wert der Variable zu erhöhen.
  • Befehl 2.6 Spieler die im Umkreis von 25 Metern nicht den Wert null besitzen, erhalten die Erlaubnis für den Auslöser auszulösen und erhalten den Wert null[B2.7].
Ausschalten
  • Befehl 2.8 Das Punktestand-Ziel wird entfernt und somit auch alle Variablen.

Befehlsblöcke mit Befehlen:
scoreboard objectives add PZZaehl.2Wert trigger ["Zähler.2: ",{"text":"Wert der Variablen","bold":true}]
scoreboard players operation VarZaehl.2Ergebnis PZZaehl.2Wert = VarZaehl.2Variable PZZaehl.2Wert


execute if entity @a[distance=..25,scores={PZZaehl.2Wert=1}] run scoreboard players add VarZaehl.2Variable PZZaehl.2Wert 1
execute if entity @a[distance=..25,scores={PZZaehl.2Wert=2}] run scoreboard players operation VarZaehl.2Ergebnis PZZaehl.2Wert += VarZaehl.2Variable PZZaehl.2Wert
execute if score VarZaehl.2Ergebnis PZZaehl.2Wert matches 0.. as @a[distance=..25] unless entity @s[scores={PZZaehl.2Wert=0}] run tellraw @s ["Zähler.2: ",{"text":"\nwert + 1 = ","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"Tippe für den Wert"} },"clickEvent":{"action":"run_command","value":"/trigger PZZaehl.2Wert set 1"} },{"score":{"name":"VarZaehl.2Variable","objective":"PZZaehl.2Wert"},"color":"dark_purple","bold":true},{"text":"\nvar + wert = ","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"Tippe für die Variable"} },"clickEvent":{"action":"run_command","value":"/trigger PZZaehl.2Wert set 2"} },{"score":{"name":"VarZaehl.2Ergebnis","objective":"PZZaehl.2Wert"},"color":"dark_purple","bold":true}]
execute as @a[distance=..25] unless entity @s[scores={PZZaehl.2Wert=0}] run scoreboard players enable @s PZZaehl.2Wert
execute as @a[distance=..25] unless entity @s[scores={PZZaehl.2Wert=0}] run scoreboard players set @s PZZaehl.2Wert 0


scoreboard objectives remove PZZaehl.2Wert

Variante 3[Bearbeiten | Quelltext bearbeiten]

Redstone-Schaltkreise Symbol.png
Diese neue oder überarbeitete Technik ist noch nicht in der aktuellen Redstone-Welt vorhanden.
In einem der nächsten Updates wird sie dort hinzugefügt werden.

Zähler (Befehle) Bild 3.1.png

Dieser Zähler ermöglicht es einen Countdown zu erstellen, der in der Schnellzugriffsleiste angezeigt wird. Den Startwert kann über die Chat-Nachricht einstellen.

Einschalten
  • Befehl 3.1 Das Auslöser-Punktestand-Ziel wird erstellt.
  • Befehl 3.2 Die Variablen für den Countdown, für das Ergebnis und für das Hochzählen werden angelegt. Dazu wird der Wert der Variable in die Ergebnis-Variable gespeichert und anschließend in die Countdown-Variable.
Wiederholen
  • Befehl 3.3 Wenn man auf die Variable im Chat-Fenster geklickt hat, wird die Variable um eins erhöht.
  • Befehl 3.4 Wenn man auf die Ergebnis-Variable geklickt hat, wird der neue Wert aus dem bisherigen Ergebnis plus dem Wert der Variable zusammen addiert und in die Ergebnis-Variable gesteckt.
  • Befehl 3.5 Wenn man auf Countdown geklickt hat, wird in die Countdown-Variable der Wert der Ergebnis-Variable gespeichert.
  • Befehl 3.6 Wenn der Wert der Countdown-Variable mindestens eins oder größer ist, wird allen Spielern im Umkreis von 25 Metern über der Schnellzugriffsleiste der aktuelle Wert der Countdown-Variable angezeigt. Ebenfalls wird der Wert der Countdown-Variable um eins verringert[B3.7].
  • Befehl 3.8 Wenn die Ergebnis-Variable angelegt wurde, wird nach Spielern in einem Umkreis von 25 Metern Ausschau gehalten und nur wenn sie nicht den Wert null besitzen erhalten sie die Chat-Nachricht. In dieser werden die Variablen mit aktuellen Wert angezeigt. Auf diese kann man klicken, um zum einen den Wert der Variable um eins zu erhöhen oder um den Wert der Ergebnis-Variable um den Wert der Variable zu erhöhen. Ebenfalls kann man auf den Countdown klicken um diesen zu starten.
  • Befehl 3.9 Spieler die im Umkreis von 25 Metern nicht den Wert null besitzen, erhalten die Erlaubnis für den Auslöser auszulösen und erhalten den Wert null[B3.10].
Ausschalten
  • Befehl 3.11 Das Punktestand-Ziel wird wieder entfernt und somit auch die Variablen.

Befehlsblöcke mit Befehlen:
scoreboard objectives add PZZaehl.3Wert trigger ["Zähler.3: ",{"text":"Wert der Variablen","bold":true}]
execute store result score VarZaehl.3Countdown PZZaehl.3Wert run scoreboard players operation VarZaehl.3Ergebnis PZZaehl.3Wert = VarZaehl.3Variable PZZaehl.3Wert


execute if entity @a[distance=..25,scores={PZZaehl.3Wert=1}] run scoreboard players add VarZaehl.3Variable PZZaehl.3Wert 1
execute if entity @a[distance=..25,scores={PZZaehl.3Wert=2}] run scoreboard players operation VarZaehl.3Ergebnis PZZaehl.3Wert += VarZaehl.3Variable PZZaehl.3Wert
execute if entity @a[distance=..25,scores={PZZaehl.3Wert=3}] run scoreboard players operation VarZaehl.3Countdown PZZaehl.3Wert = VarZaehl.3Ergebnis PZZaehl.3Wert
execute if score VarZaehl.3Countdown PZZaehl.3Wert matches 1.. run title @a[distance=..25] actionbar ["",{"score":{"name":"VarZaehl.3Countdown","objective":"PZZaehl.3Wert"},"color":"dark_purple","bold":true}]
execute if score VarZaehl.3Countdown PZZaehl.3Wert matches 1.. run scoreboard players remove VarZaehl.3Countdown PZZaehl.3Wert 1
execute if score VarZaehl.3Ergebnis PZZaehl.3Wert matches 0.. as @a[distance=..25] unless entity @s[scores={PZZaehl.3Wert=0}] run tellraw @s ["Zähler.3: ",{"text":"\nwert + 1 = ","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"Tippe für den Wert"} },"clickEvent":{"action":"run_command","value":"/trigger PZZaehl.3Wert set 1"} },{"score":{"name":"VarZaehl.3Variable","objective":"PZZaehl.3Wert"},"color":"dark_purple","bold":true},{"text":"\nvar + wert = ","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"Tippe für die Variable"} },"clickEvent":{"action":"run_command","value":"/trigger PZZaehl.3Wert set 2"} },{"score":{"name":"VarZaehl.3Ergebnis","objective":"PZZaehl.3Wert"},"color":"dark_purple","bold":true},{"text":"\ncountdown(var)","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"Tippe für den Countdown"} },"clickEvent":{"action":"run_command","value":"/trigger PZZaehl.3Wert set 3"} }]
execute as @a[distance=..25] unless entity @s[scores={PZZaehl.3Wert=0}] run scoreboard players enable @s PZZaehl.3Wert
execute as @a[distance=..25] unless entity @s[scores={PZZaehl.3Wert=0}] run scoreboard players set @s PZZaehl.3Wert 0


scoreboard objectives remove PZZaehl.3Wert

Variante 4[Bearbeiten | Quelltext bearbeiten]

Redstone-Schaltkreise Symbol.png
Diese neue oder überarbeitete Technik ist noch nicht in der aktuellen Redstone-Welt vorhanden.
In einem der nächsten Updates wird sie dort hinzugefügt werden.

Zähler (Befehle) Bild 4.1.png Zähler (Befehle) Bild 4.2.png

Dieser Zähler ermöglicht das Einstellen eines Countdwon-Wertes welcher dann runterzählt. Dabei zeigt eine Bossleiste den aktuellen Stand an.

Einschalten
  • Befehl 4.1 Wenn der Hebel umgelegt wird, wird die Start-Funktion gestartet.
Wiederholen
  • Befehl 4.2 Beim Einschalten wird auch der Wiederhol-Befehlsblock gestartet, der jeden Tick die Zyklus-Funktion lädt.
Ausschalten
  • Befehl 4.3 Wenn der Hebel wieder in Ausgangsstellung zurück gelegt wird, wird die Stopp-Funktion ausgelöst und schaltet alles wieder ab.

Befehlsblöcke mit Befehlen:


Variante 4: Start-Funktion
Die Start-Funktion erstellt eine Bossleiste, das Auslöser-Punktestand-Ziel und drei Variablen.

Editor Icon.png zaehler:v4start.mcfunction
# Die Bossleiste für den Counrdown wird erstellt und mit violett ausgestattet und für alle Spieler in einem Umkreis von 25 Metern sichtbar gemacht.
bossbar add zaehler:v4countdown ["",{"text":"Countdown","bold":true}]
bossbar set zaehler:v4countdown color purple
bossbar set zaehler:v4countdown players @a[distance=..25]

# Das Auslöser-Punktestand-Ziel wird erstellt.
scoreboard objectives add PZZaehl.4Wert trigger ["Zähler.4: ",{"text":"Wert der Variablen","bold":true}]

# Die Variablen werden mit den entsprechenden Werten gesetzt.
scoreboard players set VarZaehl.4Variable PZZaehl.4Wert 0
scoreboard players set VarZaehl.4Ergebnis PZZaehl.4Wert 0
scoreboard players set VarZaehl.4Countdown PZZaehl.4Wert 0

Variante 4: Zyklus-Funktion
Die Zyklus-Funktion ermöglicht über den Chat, die Einstellung des Countdowns. Wird der Countdown gestartet, so läuft er jede Sekunde (20 Ticks) um einen Wert nach unten, bis er null erreicht. Dabei wird das mit einer Bossleiste noch visuell untermalt.

Editor Icon.png zaehler:v4zyklus.mcfunction
# Wenn die Wert-Variable angeklickt wurde, wird diese um eins erhöht. Wenn die Variable angeklickt wurde, wird auf sie der Wert der Wert-Variable darauf addiert. Wenn der Countdown angeklickt wurde, wird der Wert der Ergebnis-Variable in die Countdown-Variable gespeichert und anschließend wird dieser Wert in die Bossleiste als maximaler Wert gespeichert.
execute if entity @a[distance=..25,scores={PZZaehl.4Wert=1}] run scoreboard players add VarZaehl.4Variable PZZaehl.4Wert 1
execute if entity @a[distance=..25,scores={PZZaehl.4Wert=2}] run scoreboard players operation VarZaehl.4Ergebnis PZZaehl.4Wert += VarZaehl.4Variable PZZaehl.4Wert
execute if entity @a[distance=..25,scores={PZZaehl.4Wert=3}] store result bossbar zaehler:v4countdown max run scoreboard players operation VarZaehl.4Countdown PZZaehl.4Wert = VarZaehl.4Ergebnis PZZaehl.4Wert

# Wenn die Countdown-Variable über null liegt, wird der Wert der Tick-Variable um eins reduziert, sie wird in der Schnellzugriffsleite ausgegeben, der Wert der Countdown-Variable selbst wird um eins reduziert und anschließend in die Bossleiste übertragen und der Wert der Tick-Variable wird auf 20 gesetzt.
execute if score VarZaehl.4Countdown PZZaehl.4Wert matches 1.. run scoreboard players remove VarZaehl.4Tick PZZaehl.4Wert 1
execute if score VarZaehl.4Countdown PZZaehl.4Wert matches 1.. if score VarZaehl.4Tick PZZaehl.4Wert matches ..-1 run title @a[distance=..25] actionbar ["",{"score":{"name":"VarZaehl.4Countdown","objective":"PZZaehl.4Wert"},"color":"dark_purple","bold":true}]
execute if score VarZaehl.4Countdown PZZaehl.4Wert matches 1.. if score VarZaehl.4Tick PZZaehl.4Wert matches ..-1 store result bossbar zaehler:v4countdown value run scoreboard players remove VarZaehl.4Countdown PZZaehl.4Wert 1
execute if score VarZaehl.4Countdown PZZaehl.4Wert matches 1.. if score VarZaehl.4Tick PZZaehl.4Wert matches ..-1 run scoreboard players set VarZaehl.4Tick PZZaehl.4Wert 20

# Wenn die Ergebnis-Variable exisitiert, werden alle Spieler in einem Umkreis von 25 Metern ausgewählt und geprüft ob sie nicht den Wert null besitzen. Wenn das zutrifft, erhalten sie eine Chat-Nachricht, in der sie die Variablen erhöhen und den Countdown starten können.
execute if score VarZaehl.4Ergebnis PZZaehl.4Wert matches 0.. as @a[distance=..25] unless entity @s[scores={PZZaehl.4Wert=0}] run tellraw @s ["Zähler.4: ",{"text":"\nwert + 1 = ","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"Tippe für den Wert"} },"clickEvent":{"action":"run_command","value":"/trigger PZZaehl.4Wert set 1"} },{"score":{"name":"VarZaehl.4Variable","objective":"PZZaehl.4Wert"},"color":"dark_purple","bold":true},{"text":"\nvar + wert = ","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"Tippe für die Variable"} },"clickEvent":{"action":"run_command","value":"/trigger PZZaehl.4Wert set 2"} },{"score":{"name":"VarZaehl.4Ergebnis","objective":"PZZaehl.4Wert"},"color":"dark_purple","bold":true},{"text":"\ncountdown(var)","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"Tippe für den Countdown"} },"clickEvent":{"action":"run_command","value":"/trigger PZZaehl.4Wert set 3"} }]

# Spieler die nicht den Wert null besitzen erhalten die Erlaubnis für den Auslöser und erhalten den Wert null.
execute as @a[distance=..25] unless entity @s[scores={PZZaehl.4Wert=0}] run scoreboard players enable @s PZZaehl.4Wert
execute as @a[distance=..25] unless entity @s[scores={PZZaehl.4Wert=0}] run scoreboard players set @s PZZaehl.4Wert 0

Variante 4: Stopp-Funktion
Die Stopp-Funktion entfernt die Bossleiste und das Punktestand-Ziel wieder.

Editor Icon.png zaehler:v4stopp.mcfunction
# Die Bossleiste wird entfernt.
bossbar remove zaehler:v4countdown

# Das Punktestand-Ziel wird entfernt.
scoreboard objectives remove PZZaehl.4Wert