Das offizielle Minecraft Wiki twittert hier: Wiki-Twitter  –  Chatte im Wiki-Discord  – Noch keinen Server gefunden? Es gibt einen Wiki-Server

Objekt-Steuerung (Befehle)

Aus Technik Wiki
Wechseln zu: Navigation, Suche
Gruppe: Grid Klebriger Kolben.png
Anlagen

Grid Roter Sand blass.png mit Mechaniken

Grid Redstone blass.png mit Redstone
                Hier:
Grid Befehlsblock.png mit Befehlen

Die vorgestellte Technik kann in der Redstone-Welt angesehen werden.

Die Objekt-Steuerung ermöglicht das Ausrichten und Positionieren von Objekten durch die Einwirkung des Spielers. Objekte wie beispielsweise Rüstungsständer werden so teleporitert, dass sie stehts paar Meter vor dem Steuerkreuz erscheinen. Das Objekt kann auch den Spieler folgen, auch können mehrere Objekte so gesteuert werden dass sie eine Art Schlange bilden.

Um den Rüstungsständer leichter zu konfigurieren, wird die Seite Rüstungsständer-Generator empfohlen.

Variante 1[Bearbeiten | Quelltext bearbeiten]

Redstone-Schaltkreise Symbol.png
Diese neue oder überarbeitete Technik ist noch nicht in der aktuellen Redstone-Welt vorhanden.
In einem der nächsten Updates wird sie dort hinzugefügt werden.

Objekt-Steuerung (Befehle) Bild 1.1.png

Mit dieser Objekt-Steuerung lässt sich ein Rüstungsständer so bewegen, dass er immer zwei Meter vor dem Fadenkreuz des Spielers befindet.

Einschalten
  • Befehl 1.1 Ein Rüstungsständer, der klein und schwerkraftunabhängig ist und ein Etikett besitzt, wird erzeugt
Wiederholen
  • Befehl 1.2 Dieser Rüstungsständer führt für sich an der Position des Spielers, welcher maximal 25 Meter weit sein darf, den teleport-Befehl aus. Dabei wird der Rüstungsständer einen Block über und zwei Blöcke vor dem Spieler teleportiert. Hierbei schaut der Rüstungsständer auch noch zu diesem Spieler.
Ausschalten
  • Befehl 1.3 Der Rüstungsständer wird anhand des Etiketts erkannt und gelöscht.

Befehlsblöcke mit Befehlen:
summon minecraft:armor_stand ~ ~3 ~ {Small:true,NoGravity:true,Tags:["EtiObjSt.1Alle"]}


execute as @e[type=minecraft:armor_stand,tag=EtiObjSt.1Alle] at @p[distance=..25] run teleport @s ^ ^1 ^2 facing entity @p


kill @e[type=minecraft:armor_stand,tag=EtiObjSt.1Alle]

Variante 2[Bearbeiten | Quelltext bearbeiten]

Redstone-Schaltkreise Symbol.png
Diese neue oder überarbeitete Technik ist noch nicht in der aktuellen Redstone-Welt vorhanden.
In einem der nächsten Updates wird sie dort hinzugefügt werden.

Objekt-Steuerung (Befehle) Bild 2.1.png

Mit dieser Objekt-Steuerung lässt sich ein Rüstungsständer so bearbeiten, dass er dem nächsten Spieler verfolgt. Der Rüstungsständer beachtet dabei aber keine Hindernisse, er bewegt sich durch alles hindurch um den Spieler zu erreichen.

Einschalten
  • Befehl 2.1 Es wird ein Rüstungsständer erzeugt. Dieser ist klein, schwerkraftunabhängig, besitzt ein Etikett um von anderen unterschieden werden zu können. Seine Arme werden angezeigt und diese befinden sich auf waagerechter Lage.
Wiederholen
  • Befehl 2.2 Der Rüstungsständer führt von sich aus an seiner eigenen Position den teleport-Befehl aus. Der Rüstungsständer wird 0.2 Meter in seine Blickrichtung nach vorne teleportiert, hierbei schaut er auf den nächsten Spieler in einem Umkreis von 25 Metern. Das führt dazu dass er sich langsam aber stetig diesem Spieler nähert, bis er ihn erreicht.
Ausschalten
  • Befehl 2.3 Der Rüstungsständer wird anhand des Etiketts erkannt und gelöscht.

Befehlsblöcke mit Befehlen:
summon minecraft:armor_stand ~ ~3 ~ {Small:true,NoGravity:true,Tags:["EtiObjSt.2Alle"],ShowArms:true,Pose:{LeftArm:[260.0f,0.0f,0.0f],RightArm:[260.0f,0.0f,0.0f]}


execute as @e[type=minecraft:armor_stand,tag=EtiObjSt.2Alle] at @s run teleport @s ^ ^ ^0.2 facing entity @p[distance=1..25]


kill @e[type=minecraft:armor_stand,tag=EtiObjSt.2Alle]

Variante 3[Bearbeiten | Quelltext bearbeiten]

Redstone-Schaltkreise Symbol.png
Diese neue oder überarbeitete Technik ist noch nicht in der aktuellen Redstone-Welt vorhanden.
In einem der nächsten Updates wird sie dort hinzugefügt werden.

Objekt-Steuerung (Befehle) Bild 3.1.png

Diese Objekt-Steuerung lässt einen Rüstungsständer um einen zweiten kreisen und dabei wird der zweite immer über dem Spieler positioniert.

Einschalten
  • Befehl 3.1 Es wird ein Rüstungsständer erzeugt. Dieser ist klein, schwerkraftunabhängig, besitzt zwei Etiketten um von anderen unterschieden werden zu können. Seine Arme werden angezeigt und diese befinden sich auf waagerechter Lage. Gleiches gilt für den zweiten Rüstungsständer[B3.2]. Beide Rüstungsständer besitzen ein gemeinsames Etikett um sie alle zu erfassen und jeweils ein eigenes, dass genau einen dieser Rüstungsständern zugeordnet ist.
Wiederholen
  • Befehl 3.3 Der Begleiter-Rüstungsständer führt für sich an der Position des nächsten Spielers aber mit der eigenen Rotation einen teleport-Befehl aus. Dies führt dazu dass er zwei Blöcke immer über dem Spieler teleportiert wird, aber sich ständig weiter rotiert, weil die alte Rotation mit einfließt.
  • Befehl 3.4 Der Begleiter-Rüstungsständer führt diesmal an seiner eigenen Position den teleport-Befehl aus. Hier wird der Dreher-Rüstungsständer, der sich um den Begleiter-Rüstungsständer drehen soll, fünf Meter vor dem Begleiter-Rüstungsständer teleportiert, aber sodass er genau zu ihm schaut.
Ausschalten
  • Befehl 3.5 Die beiden Rüstungsständer werden anhand des gemeinsamen Etiketts erkannt und entfernt.

Befehlsblöcke mit Befehlen:
summon minecraft:armor_stand ~ ~3 ~ {Small:true,NoGravity:true,Tags:["EtiObjSt.3Alle","EtiObjSt.3Begleiter"],ShowArms:true,Pose:{LeftArm:[260.0f,0.0f,0.0f],RightArm:[260.0f,0.0f,0.0f]} }
summon minecraft:armor_stand ~ ~3 ~ {Small:true,NoGravity:true,Tags:["EtiObjSt.3Alle","EtiObjSt.3Dreher"],ShowArms:true,Pose:{LeftArm:[260.0f,0.0f,0.0f],RightArm:[260.0f,0.0f,0.0f]} }


execute as @e[type=minecraft:armor_stand,tag=EtiObjSt.3Begleiter] at @p[distance=..25] rotated as @s run teleport @s ~ ~2 ~ ~5 ~
execute as @e[type=minecraft:armor_stand,tag=EtiObjSt.3Begleiter] at @s run teleport @e[type=minecraft:armor_stand,tag=EtiObjSt.3Dreher] ^ ^ ^5 facing entity @s eyes


kill @e[type=minecraft:armor_stand,tag=EtiObjSt.3Alle]

Variante 4[Bearbeiten | Quelltext bearbeiten]

Redstone-Schaltkreise Symbol.png
Diese neue oder überarbeitete Technik ist noch nicht in der aktuellen Redstone-Welt vorhanden.
In einem der nächsten Updates wird sie dort hinzugefügt werden.

Objekt-Steuerung (Befehle) Bild 4.1.png

Diese Objekt-Steuerung lässt vier Rüstungsständer vor, hinter und zu beiden Seiten positionieren. Auch die Blickrichtung des Spielers beeinflusst die Rüstungsständer wo sie sich um den Spieler befinden sollen.

Einschalten
  • Befehl 4.1 Für das Erzeugen von vier Rüstungsständern werden diese auf einem fallenden Block erzeugt, welcher nur für einen Tick vorhanden ist. Die vier Rüstungsständer sind klein, schwerkraftunabhängig, besitzen alle ein gemeinsames Etikett und ein eigenes.
Wiederholen
  • Befehl 4.2 Der nächstgelegene Spieler in einem Umkreis von 25 Metern führt an seiner Position mit einer relativen Rotation von 90° auf der Horizontale einen teleport-Befehl aus. Dieser wird durch die relative Rotation nicht drei Meter links von ihm positioniert sondern vor ihm. Die relative Rotation hat den Sinn dass der Rüstungsständer sich nur horizontal durch die Blickrichtung des Spieler sich beeinflussen lässt, nicht aber vertikal.
  • Befehl 4.3 Das gleiche wird mit den drei weiteren Rüstungsständern ebenfalls durchgeführt[B4.4][B4.5]. Dies jeweils in einer horizontalen Rotation um jeweils 90° um den Spieler versetzt.
Ausschalten
  • Befehl 4.6 Die vier Rüstungsständer werden anhand des gemeinsamen Etiketts erkannt und entfernt.

Befehlsblöcke mit Befehlen:
summon minecraft:falling_block ~ ~3 ~ {Passengers:[{id:"minecraft:armor_stand",Small:true,NoGravity:true,Tags:["EtiObjSt.4Alle","EtiObjSt.4BegleiterNorden"]},{id:"minecraft:armor_stand",Small:true,NoGravity:true,Tags:["EtiObjSt.4Alle","EtiObjSt.4BegleiterOsten"]},{id:"minecraft:armor_stand",Small:true,NoGravity:true,Tags:["EtiObjSt.4Alle","EtiObjSt.4BegleiterSueden"]},{id:"minecraft:armor_stand",Small:true,NoGravity:true,Tags:["EtiObjSt.4Alle","EtiObjSt.4BegleiterWesten"] } ] }


execute as @p[distance=..25] at @s rotated ~90 ~ run teleport @e[type=minecraft:armor_stand,tag=EtiObjSt.4BegleiterNorden,sort=nearest,limit=1] ^3 ^ ^ facing entity @s eyes
execute as @p[distance=..25] at @s run teleport @e[type=minecraft:armor_stand,tag=EtiObjSt.4BegleiterOsten,sort=nearest,limit=1] ^3 ^ ^ facing entity @s eyes
execute as @p[distance=..25] at @s rotated ~90 ~ run teleport @e[type=minecraft:armor_stand,tag=EtiObjSt.4BegleiterSueden,sort=nearest,limit=1] ^-3 ^ ^ facing entity @s eyes
execute as @p[distance=..25] at @s run teleport @e[type=minecraft:armor_stand,tag=EtiObjSt.4BegleiterWesten,sort=nearest,limit=1] ^-3 ^ ^ facing entity @s eyes


kill @e[type=minecraft:armor_stand,tag=EtiObjSt.4Alle]

Variante 5[Bearbeiten | Quelltext bearbeiten]

Redstone-Schaltkreise Symbol.png
Diese neue oder überarbeitete Technik ist noch nicht in der aktuellen Redstone-Welt vorhanden.
In einem der nächsten Updates wird sie dort hinzugefügt werden.

Objekt-Steuerung (Befehle) Bild 5.1.png

Diese Steuerung für Objekte, lässt einen Rüstungsständer vertikal um einen zweiten Rüstungsständer kreisen.

Einschalten
  • Befehl 5.1 Es wird ein Rüstungsständer erzeugt, der klein, schwerelos und zwei Etiketten besitzt.
  • Befehl 5.2 Ein zweiter Rüstungsständer mit den gleichen Eigenschaften, aber mit einem anderen Etikett wird erzeugt.
Wiederholen
  • Befehl 5.3 Wenn der Mitte-Rüstungsständer ein Rotations-Etikett besitzt führt er an seiner Position den teleport-Befehl aus. Das sorgt dafür, dass er sich nach oben rotiert.
  • Befehl 5.4 Falls er das Etikett nicht besitzt, wird er nach unten rotiert.
  • Befehl 5.5 Solange der Mitte-Rüstungsständer nach ganz oben oder nach ganz unten rotiert ist, wird er nicht teleportiert. Wenn er jedoch diese Ränder erreicht, dreht er sich um 180° um.
  • Befehl 5.6 Wenn der Rüstungsständer nach ganz oben schaut, wird ihm das Rotations-Etikett gegeben, andersherum, wenn er nach ganz unten schaut wird ihm dieses wieder entfernt[B5.7]
  • Befehl 5.8 Von der Position des Mitte-Rüstungsständers wird der teleport-Befehl ausgeführt. Dieser teleportiert den Begleiter-Rüstungsständer drei Meter in Blickrichtung des Mitte-Rüstungsständers vor diesen.
Ausschalten
  • Befehl 5.9 Die zwei Rüstungsständer werden anhand des Etiketts erkannt und entfernt.

Befehlsblöcke mit Befehlen:
summon minecraft:armor_stand ~ ~8 ~ {Small:true,NoGravity:true,Tags:["EtiObjSt.5Alle","EtiObjSt.5Mitte"]}
summon minecraft:armor_stand ~ ~3 ~ {Small:true,NoGravity:true,Tags:["EtiObjSt.5Alle","EtiObjSt.5Begleiter"]}


execute as @e[type=minecraft:armor_stand,tag=EtiObjSt.5Mitte,tag=EtiObjSt.5Rotation] at @s run teleport @s ~ ~ ~ ~ ~1
execute as @e[type=minecraft:armor_stand,tag=EtiObjSt.5Mitte,tag=!EtiObjSt.5Rotation] at @s run teleport @s ~ ~ ~ ~ ~-1
execute as @e[type=minecraft:armor_stand,tag=EtiObjSt.5Mitte] unless entity @s[x_rotation=-89..89] at @s run teleport @s ~ ~ ~ ~180 ~
tag @e[type=minecraft:armor_stand,tag=EtiObjSt.5Mitte,x_rotation=-90] add EtiObjSt.5Rotation
tag @e[type=minecraft:armor_stand,tag=EtiObjSt.5Mitte,x_rotation=90] remove EtiObjSt.5Rotation
execute at @e[type=minecraft:armor_stand,tag=EtiObjSt.5Mitte] run teleport @e[type=minecraft:armor_stand,tag=EtiObjSt.5Begleiter] ^ ^ ^3


kill @e[type=minecraft:armor_stand,tag=EtiObjSt.5Alle]

Variante 6[Bearbeiten | Quelltext bearbeiten]

Redstone-Schaltkreise Symbol.png
Diese neue oder überarbeitete Technik ist noch nicht in der aktuellen Redstone-Welt vorhanden.
In einem der nächsten Updates wird sie dort hinzugefügt werden.

Objekt-Steuerung (Befehle) Bild 6.1.png

Die Objekt-Steuerung teleportiert einen Rüstungsständer an die Stelle auf die der Spieler schaut. Falls jedoch keine festen Blöcke innerhalb eines Umkreises von 25 Metern gibt wird der Rüstungsständer maximal nach dort teleportiert, auch wenn es noch weiter weg wieder feste Blöcke geben würde.

Einschalten
  • Befehl 6.1 Wenn der Hebel umgelegt wird, wird die Start-Funktion gestartet.
Wiederholen
  • Befehl 6.2 Beim Einschalten wird auch der Wiederhol-Befehlsblock gestartet, der jeden Tick die Zyklus-Funktion lädt.
Ausschalten
  • Befehl 6.3 Wenn der Hebel wieder in Ausgangsstellung zurück gelegt wird, wird die Stopp-Funktion ausgelöst und schaltet alles wieder ab.

Befehlsblöcke mit Befehlen:



Variante 6: Start-Funktion
Die Start-Funktion erstellt einen Rüstungsständer.

Editor Icon.png objekt-steuerung:v6start.mcfunction
# Der Rüstungsständer, welcher klein, keine Hitbox und keine Schwerkraft besitzt, wird erstellt
summon minecraft:armor_stand ~ ~3 ~ {Small:true,Marker:true,NoGravity:true,Tags:["EtiObjSt.6Alle"]}

Variante 6: Zyklus-Funktion
Die Zyklus-Funktione führt von dem nächst gelegenen Spieler die Blick-Positions-Funktion auf.

Editor Icon.png objekt-steuerung:v6zyklus.mcfunction
# Im Umkreis von 25 Metern wird von der Position des Spielers einen Meter in Blickrichtung die Blick-Positions-Funktion gestartet
execute as @p[distance=..25] at @s positioned ^ ^ ^1 run function objekt-steuerung:v6blickposition

Variante 6: Blick-Positions-Funktion
Die Blick-Positions-Funktion positioniert den Rüstungsständer an der Stelle wo der Spieler hinschaut. Wenn er jedoch in den Himmel schaut, wo sich kein fester Block befindet, so wird der Rüstungsständer maximal 25 Meter weit nach vorne bewegt und bleibt dort.

Editor Icon.png objekt-steuerung:v6blickposition.mcfunction
# Maximal 25 Meter weit vom Spieler wird diese Funktion selbstaufgerufen und dabei wird der Rüstungsständer in Blickrichtung maximal 25 Meter weit teleporitert, schaut man jedoch Richtung Boden oder auf andere Hindernisse, so wird der Rüstungsständer maximal bis kurz vor dem Hindernis teleportiert
execute unless entity @p[distance=..25] run teleport @e[type=minecraft:armor_stand,tag=EtiObjSt.6Alle,sort=nearest,limit=1] ~ ~ ~
execute unless block ^ ^ ^1 minecraft:air run teleport @e[type=minecraft:armor_stand,tag=EtiObjSt.6Alle,sort=nearest,limit=1] ~ ~ ~
execute if entity @p[distance=..25] positioned ^ ^ ^1 if block ~ ~ ~ minecraft:air run function objekt-steuerung:v6blickposition

Variante 6: Stopp-Funktion
Die Stopp-Funktion löscht den Rüstungsständer wieder.

Editor Icon.png objekt-steuerung:v6stopp.mcfunction
# Der Rüstungsständer mit dem entsprechenden Etikett wird gelöscht
kill @e[type=minecraft:armor_stand,tag=EtiObjSt.6Alle]

Variante 7[Bearbeiten | Quelltext bearbeiten]

Redstone-Schaltkreise Symbol.png
Diese neue oder überarbeitete Technik ist noch nicht in der aktuellen Redstone-Welt vorhanden.
In einem der nächsten Updates wird sie dort hinzugefügt werden.

Objekt-Steuerung (Befehle) Bild 7.1.png

Mit dieser Variante einer Objekt-Steuerung wird ein verschiebbarer Block erstellt, den ein Spieler durch bloßes heranlaufen verschieben kann.

Einschalten
  • Befehl 7.1 Ein Rüstungsständer wird erzeugt, der klein, unsichtbar ist, schwerelos und zwei Etiketten besitzt. Auf ihm reitet ein Shulker und ein fallender Block. Der Shulker ist leise, besitzt keine KI, besitzt ein Etikett, eine leere Beutetabelle und zwei Statuseffekte Unsichtbarkeit und Regeneration. Der fallende Block besitzt eine extrem lange Lebenszeit, stellt den gemeißelten roten Sandstein dar und besitzt einen benutzerdefinierten Anzeigename und ein Etikett.
Wiederholen
  • Befehl 7.2 Alle Spieler in einem Umktreis von 25 Metern lassen von ihrer Position und um 90° relativ von ihrem Blickwinkel in einem Abstand von 0.55 Metern zu dem Rüstungsständer mit dem Block-Etikett den Befehl von sich ausführen. Der Rüstungsständer mit dem Etikett führt dann von seiner Position ohne die Rotation des Spielers zu ändern einen Test durch, ob in die Richtung in die er teleportiert werden würde sich Luft befindet. Wenn genau das der Fall ist, wird er um 0.1 Meter in die Richtung teleportiert in die ihn der Spieler schieben will.
Ausschalten
  • Befehl 7.3 Der Rüstungsständer, der Shulker sowie der fallende Block werden entfernt, da sie alle das gleiche Etikett besitzen.



Befehlsblöcke mit Befehlen:
summon minecraft:armor_stand ~-3 ~-1 ~ {Small:true,Invisible:true,NoGravity:true,Tags:["EtiObjSt.7Alle","EtiObjSt.7Block"],Passengers:[{id:"minecraft:shulker",Silent:true,NoAI:true,Tags:["EtiObjSt.7Alle"],DeathLootTable:"minecraft:empty",ActiveEffects:[{Id:14b,Amplifier:0b,Duration:2147483647,ShowParticles:false},{Id:10b,Amplifier:10b,Duration:2147483647,ShowParticles:false}]},{id:"minecraft:falling_block",Time:-2147483648,BlockState:{Name:"minecraft:chiseled_red_sandstone"},CustomNameVisible:true,CustomName:'{"text":"Schieb mich!","color":"gold"}',Tags:["EtiObjSt.7Alle"]} ] }


execute as @a[distance=..25] at @s rotated ~90 0 positioned ^1 ^ ^ as @e[distance=..0.55,type=minecraft:armor_stand,tag=EtiObjSt.7Block] positioned as @s if block ^1 ^1 ^ minecraft:air run teleport @s ^0.1 ^ ^


kill @e[tag=EtiObjSt.7Alle]

Variante 8[Bearbeiten | Quelltext bearbeiten]

Redstone-Schaltkreise Symbol.png
Diese neue oder überarbeitete Technik ist noch nicht in der aktuellen Redstone-Welt vorhanden.
In einem der nächsten Updates wird sie dort hinzugefügt werden.

Objekt-Steuerung (Befehle) Bild 8.1.png

Diese Objekt-Steuerung lässt beliebig viele Rüstungsständer um einen rotierenden Rüstungsständer kreisen. Man platziert einen Rüstungsständer und er wird sich in die Kette der anderen einfügen und um den Mittelpunkt kreisen.

Einschalten
  • Befehl 8.1 Wenn der Hebel umgelegt wird, wird die Start-Funktion gestartet.
Wiederholen
  • Befehl 8.2 Beim Einschalten wird auch der Wiederhol-Befehlsblock gestartet, der jeden Tick die Zyklus-Funktion lädt.
Ausschalten
  • Befehl 8.3 Wenn der Hebel wieder in Ausgangsstellung zurück gelegt wird, wird die Stopp-Funktion ausgelöst und schaltet alles wieder ab.

Befehlsblöcke mit Befehlen:



Variante 8: Start-Funktion
Die Start-Funktion erzeugt einen Rüstungsständer, der den Mittelpunkt darstellt und alle Spieler im Umkreis erhalten 16 Rüstungsständer die sie platzieren können um als Begleiter für den Mittelpunkt-Rüstungsständer zu fungieren.

Editor Icon.png objekt-steuerung:v8start.mcfunction
# Einen Block über der Befehlsquelle wird ein Rüstungsständer, der das Zentrum markiert schwebend platziert. Spieler erhalten 16 Rüstungsständer, die man beliebig platzieren kann, damit diese dann sich an den Mittelpunkt einfinden und sich um diesen bewegen
summon minecraft:armor_stand ~ ~1 ~ {Small:true,NoGravity:true,CustomNameVisible:true,CustomName:'{"text":"Mittelpunkt","bold":true}',Tags:["EtiObjSt.8Alle","EtiObjSt.8Mittelpunkt"]}
give @a[distance=..15] minecraft:armor_stand{objekt-steuerung:"v8gegenstand",display:{Lore:['"Platziere diesen Rüstungsständer"','"damit er als Begleiter um den"','"Mittelpunkt drehen kann"']},EntityTag:{Small:true,NoGravity:true,Tags:["EtiObjSt.8Alle","EtiObjSt.8Begleiter"]} } 16

Variante 8: Zyklus-Funktion
Die Zyklus-Funktion lässt den Mittelpunkt-Rüstungsständer sich im Kreis drehen und führt von dessen Position die Kettenpositions-Funktion aus.

Editor Icon.png objekt-steuerung:v8zyklus.mcfunction
# Der Mittelpunkt-Rüstungsständer wird jeden Tick etwas rotiert und Begleiter-Rüstungsständer ordnen sich durch die Funktion ein
execute as @e[type=minecraft:armor_stand,tag=EtiObjSt.8Mittelpunkt] at @s run teleport @s ~ ~ ~ ~1 ~
execute as @e[type=minecraft:armor_stand,tag=EtiObjSt.8Begleiter] at @e[type=minecraft:armor_stand,tag=EtiObjSt.8Mittelpunkt] positioned ^ ^ ^1 run function objekt-steuerung:v8kettenposition

Variante 8: Kettenpositions-Funktion
Die Kettenpositions-Funktion teleportiert jeden Rüstungsständer an seine Position um den Mittelpunkt-Rüstungsständer.

Editor Icon.png objekt-steuerung:v8kettenposition.mcfunction
# Der ausführende Begleiter-Rüstungsständer bekommt zur Erkennung ein Etikett für sich selbst. Wenn kein Begleiter an der Position ist wird er selbst teleportiert ansonsten wird die Funktion um einen Meter weiter nochmaöl aufgerufen.
tag @s[tag=!EtiObjSt.8Selbst] add EtiObjSt.8Selbst
execute unless entity @e[distance=..0.4,type=minecraft:armor_stand,tag=EtiObjSt.8Begleiter,tag=!EtiObjSt.8Selbst] run teleport @s ~ ~ ~ ~ ~
execute if entity @e[distance=..0.4,type=minecraft:armor_stand,tag=EtiObjSt.8Begleiter,tag=!EtiObjSt.8Selbst] positioned ^ ^ ^1 run function objekt-steuerung:v8kettenposition
tag @s[tag=EtiObjSt.8Selbst] remove EtiObjSt.8Selbst

Variante 1: Stopp-Funktion
Die Stopp-Funktion entfernt alle Rüstungsständer mit entsprechender Eigenschaft aus dem Inventar und löscht alle Objekte in der Welt mit dem Etikett.

Editor Icon.png objekt-steuerung:v8stopp.mcfunction
# Die Rüstungsständer werden aus dem Inventar gelöscht und alle platzieren aus der Welt entfernt
clear @a[distance=..15] minecraft:armor_stand{objekt-steuerung:"v8gegenstand"}
tag @e[type=minecraft:item,nbt={Item:{tag:{objekt-steuerung:"v8gegenstand"} } }] add EtiObjSt.8Alle
kill @e[tag=EtiObjSt.8Alle]

Variante 9[Bearbeiten | Quelltext bearbeiten]

Redstone-Schaltkreise Symbol.png
Diese neue oder überarbeitete Technik ist noch nicht in der aktuellen Redstone-Welt vorhanden.
In einem der nächsten Updates wird sie dort hinzugefügt werden.

Objekt-Steuerung (Befehle) Bild 9.1.png

Diese Objekt-Steuerung lässt einen Rüstungsständer den Pfad den ein Spieler läuft entlang laufen. Er verfolgt ihn unentwegs bis er ihn erreicht hat.

Einschalten
  • Befehl 9.1 Ein Punktestand-Ziel für die Länge wird als dummy-Ziel erstellt.
  • Befehl 9.2 Der nächstgelegene Spieler erhält den Wert 15 für die Länge.
  • Befehl 9.3 Es wird ein Rüstungsständer erzeugt, der schwerelos, seinen Anzeigenamen anzeigt, den Namen Verfolger besitzt und mit zwei Etiketten ausgestattet ist.
Wiederholen
  • Befehl 9.4 In einem Umkreis von 25 Metern führt der nächstgelegene Spieler von seiner Position einen summon-Befehl aus. Damit wird an der Position des Spielers ein Rüstungsständer erzeugt, dieser ist klein und schwerelos, sowie besitzt er zwei Etiketten.
  • Befehl 9.5 Dieser Rüstungsständer besitzt noch nicht die Längennummer, sodass er diese von dem Spieler erhält.
  • Befehl 9.6 Anschließend erhält er ein Etikett, das zeigt, das er die Nummer jetzt besitzt.
  • Befehl 9.7 Jedem Positions-Rüstungsständer wird der Wert um eins verringert.
  • Befehl 9.8 Der Verfolger-Rüstungsständer wird immer an die Position des Positions-Rüstungsständer teleportiert, der den Wert null erreicht hat.
  • Befehl 9.9 Der Rüstungsständer der den Wert null erreicht wird gelöscht.
Ausschalten
  • Befehl 9.10 Das Punktestand-Ziel wird gelöscht.
  • Befehl 9.11 Alle Rüstungsständer mit den Etikett werden gelöscht.

Befehlsblöcke mit Befehlen:
scoreboard objectives add PZObjSt.9Laenge dummy ["Objekt-Steuerung.9: ",{"text":"Länge","bold":true}]
scoreboard players set @p PZObjSt.9Laenge 15
summon minecraft:armor_stand ~ ~ ~ {NoGravity:true,CustomNameVisible:true,CustomName:'{"text":"Verfolger","color":"green","bold":true}',Tags:["EtiObjSt.9Alle","EtiObjSt.9Verfolger"]}


execute as @p[distance=..25] at @s run summon minecraft:armor_stand ~ ~ ~ {Small:true,NoGravity:true,Tags:["EtiObjSt.9Alle","EtiObjSt.9Position"] }
scoreboard players operation @e[type=minecraft:armor_stand,tag=EtiObjSt.9Position,tag=!EtiObjSt.9KeineNummer] PZObjSt.9Laenge = @p PZObjSt.9Laenge
tag @e[type=minecraft:armor_stand,tag=EtiObjSt.9Position,tag=!EtiObjSt.9KeineNummer] add EtiObjSt.9KeineNummer
scoreboard players remove @e[type=minecraft:armor_stand,tag=EtiObjSt.9Position] PZObjSt.9Laenge 1
teleport @e[type=minecraft:armor_stand,tag=EtiObjSt.9Verfolger] @e[type=minecraft:armor_stand,tag=EtiObjSt.9Position,scores={PZObjSt.9Laenge=..0},sort=nearest,limit=1]
kill @e[type=minecraft:armor_stand,tag=EtiObjSt.9Position,scores={PZObjSt.9Laenge=..0}]


scoreboard objectives remove PZObjSt.9Laenge
kill @e[type=minecraft:armor_stand,tag=EtiObjSt.9Alle]

Variante 10[Bearbeiten | Quelltext bearbeiten]

Redstone-Schaltkreise Symbol.png
Diese neue oder überarbeitete Technik ist noch nicht in der aktuellen Redstone-Welt vorhanden.
In einem der nächsten Updates wird sie dort hinzugefügt werden.

Objekt-Steuerung (Befehle) Bild 10.1.png

Mit dieser Objekt-Steuerung wird eine Schlange an Rüstungsständern erzeugt, die den Spieler verfolgt. Die Schlange bewegt sich auch durch Blöcke, wenn diese sich im Weg befinden.

Einschalten
  • Befehl 10.1 Wenn der Hebel umgelegt wird, wird die Start-Funktion gestartet.
Wiederholen
  • Befehl 10.2 Beim Einschalten wird auch der Wiederhol-Befehlsblock gestartet, der jeden Tick die Zyklus-Funktion lädt.
Ausschalten
  • Befehl 10.3 Wenn der Hebel wieder in Ausgangsstellung zurück gelegt wird, wird die Stopp-Funktion ausgelöst und schaltet alles wieder ab.

Befehlsblöcke mit Befehlen:



Variante 10: Start-Funktion
Die Start-Funktion erstellt mehrere Punktestand-Ziele und bereitet den Spieler mit Etiketten darauf vor, dass er eine Schlange von Rüstungsständern anführt.

Editor Icon.png objekt-steuerung:v10start.mcfunction
# Punktestand-Ziele für die Nummer,, Vergleichsnummer und der Länge werden erstellt
scoreboard objectives add PZObjSt.10Nr dummy ["Objekt-Steuerung.10: ",{"text":"Positionsnummer","bold":true}]
scoreboard objectives add PZObjSt.10Vergl dummy ["Objekt-Steuerung.10: ",{"text":"Vergleichsnummer","bold":true}]
scoreboard objectives add PZObjSt.10Laenge dummy ["Objekt-Steuerung.10: ",{"text":"Länge","bold":true}]

# Dem nächsten Spieler in 15 Metern Entfernung wird ein Etikett gegeben, sodass dieser bestimmte Grundeinstellungen erhält
tag @p[distance=..15] add EtiObjSt.10Spieler
tag @p[tag=EtiObjSt.10Spieler] add EtiObjSt.10Alle
scoreboard players set @p[tag=EtiObjSt.10Spieler] PZObjSt.10Nr 0
scoreboard players set @p[tag=EtiObjSt.10Spieler] PZObjSt.10Laenge 10

Variante 10: Zyklus-Funktion
Die Zyklus-Funktion ruft die Längen-Funktion für den Spieler auf, falls noch nicht alle Rüstungsständer für die Schlange erstellt wurden. Außerdem wird das Folgen der einzelnen Schlangenglieder durchgeführt.

Editor Icon.png objekt-steuerung:v10zyklus.mcfunction
# Spieler mit dem Punktestand der Länge eins oder größer rufen von sich aus die Längen-Funktion auf
execute as @a[tag=EtiObjSt.10Spieler,scores={PZObjSt.10Laenge=1..}] run function objekt-steuerung:v10laenge

# Der Rüstungsständer mit dem Wert null ist der erste in der Schlange und folgt daher dem Spieler
execute as @e[type=minecraft:armor_stand,tag=EtiObjSt.10Alle,scores={PZObjSt.10Laenge=0}] at @s run teleport @s ^ ^ ^0.1 facing entity @p[distance=0.5..,tag=EtiObjSt.10Spieler] feet

# Alle weiteren Rüstungsständer folgen ihren jeweiligen Vorgänger, in dem für jeden einzelnen die Folgen-Funktion aufgerufen wird
execute as @e[type=minecraft:armor_stand,tag=EtiObjSt.10Alle,scores={PZObjSt.10Laenge=1..}] at @s run function objekt-steuerung:v10folgen

Variante 10: Längen-Funktion
Die Längen-Funktion erstellt pro Aufruf ein Schlangen-Glied und verringert dann den Wert des Spielers bis er keine weiteren Glieder mehr braucht.

Editor Icon.png objekt-steuerung:v10laenge.mcfunction
# Zuerst wird die Variable für das Schlangenende auf null gesetzt, damit anschließend der größte Nummernwert übertragen werden kann
scoreboard players set #VarObjSt.10SchlangenEnde PZObjSt.10Vergl 0
scoreboard players operation #VarObjSt.10SchlangenEnde PZObjSt.10Vergl > @e[tag=EtiObjSt.10Alle] PZObjSt.10Nr

# An der Position des Schlangenendes (entweder ein Rüstungsständer oder der Spieler) wird ein weiterer Rüstungsständer erzeugt
execute as @e[tag=EtiObjSt.10Alle] if score @s PZObjSt.10Nr = #VarObjSt.10SchlangenEnde PZObjSt.10Vergl at @s run summon minecraft:armor_stand ~ ~ ~ {Invisible:true,Small:true,NoGravity:true,Marker:true,Tags:["EtiObjSt.10Alle","EtiObjSt.10KeineNummer"],ArmorItems:[{},{},{},{id:"minecraft:lime_concrete_powder",Count:1b} ]}

# Der Wert der Länge wird vom Spieler um eins verringert
scoreboard players remove @s PZObjSt.10Laenge 1

# Die aktuelle Anzahl wird in den Punktestand der Länge gespeichert und anschließend wird die Anzahl um eins erhöht. Der Rüstungsständer erhält im nächsten Schritt die Nummer und das Etikett wird entfernt
scoreboard players operation @e[type=minecraft:armor_stand,tag=EtiObjSt.10Alle,tag=EtiObjSt.10KeineNummer] PZObjSt.10Laenge = #VarObjSt.10Anzahl PZObjSt.10Nr
scoreboard players add #VarObjSt.10Anzahl PZObjSt.10Nr 1
scoreboard players operation @e[type=minecraft:armor_stand,tag=EtiObjSt.10Alle,tag=EtiObjSt.10KeineNummer] PZObjSt.10Nr = #VarObjSt.10Anzahl PZObjSt.10Nr
tag @e[type=minecraft:armor_stand,tag=EtiObjSt.10Alle,tag=EtiObjSt.10KeineNummer,scores={PZObjSt.10Nr=1..}] remove EtiObjSt.10KeineNummer

Variante 10: Folgen-Funktion
Die Folgen-Funktion berechnet den Vordermann eines jeden Schlangengliedes und lässt dann dieses den Vordermann folgen.

Editor Icon.png objekt-steuerung:v10folgen.mcfunction
# Der Rüstungsständer erhält ein Etikett für sich selbst, sodass er von den anderen unterschieden werden kann
tag @s add EtiObjSt.10Selbst

# Alle Rüstungsständer außer sich selbst wird die Nummer in die Vergleichsnummer gespeichert, damit sie anschließend von dem eigenen Rüstungsständer die Nummer abgezogen werden kann
execute as @e[type=minecraft:armor_stand,tag=EtiObjSt.10Alle,tag=!EtiObjSt.10Selbst,scores={PZObjSt.10Nr=1..}] run scoreboard players operation @s PZObjSt.10Vergl = @s PZObjSt.10Nr
execute as @e[type=minecraft:armor_stand,tag=EtiObjSt.10Alle,tag=!EtiObjSt.10Selbst,scores={PZObjSt.10Nr=1..}] run scoreboard players operation @s PZObjSt.10Vergl -= @e[type=minecraft:armor_stand,tag=EtiObjSt.10Alle,tag=EtiObjSt.10Selbst] PZObjSt.10Laenge

# Das Etikett wird wieder entfernt und der Rüstungsständer folgt dem Vorgänger, denn dieser muss den Vergleichswert null besitzen
tag @s remove EtiObjSt.10Selbst
teleport @s ^ ^ ^0.1 facing entity @e[distance=0.4..,sort=nearest,limit=1,type=minecraft:armor_stand,tag=EtiObjSt.10Alle,scores={PZObjSt.10Vergl=0}] feet

Variante 10: Stopp-Funktion
Die Stopp-Funktion löscht die Punktestand-Ziele wieder und entfernt die Etiketten der Spieler sowie die Rüstungsständer.

Editor Icon.png objekt-steuerung:v10stopp.mcfunction
# Die Punktestände werden gelöscht
scoreboard objectives remove PZObjSt.10Nr
scoreboard objectives remove PZObjSt.10Vergl
scoreboard objectives remove PZObjSt.10Laenge

# Alle Etiketten, die der Spieler erhalten hatte, werden wieder entfernt
tag @a[tag=EtiObjSt.10Spieler] remove EtiObjSt.10Alle
tag @a[tag=EtiObjSt.10Spieler] remove EtiObjSt.10Spieler

# Alle Rüstungsständer werden wieder entfernt
kill @e[type=minecraft:armor_stand,tag=EtiObjSt.10Alle]