Das offizielle Minecraft Wiki twittert hier: Wiki-Twitter  –  Chatte im Wiki-Discord  – Noch keinen Server gefunden? Es gibt einen Wiki-Server

Tauschmaschine (Befehle)

Aus Technik Wiki
Wechseln zu: Navigation, Suche
Gruppe: Grid Trichter.png
Maschinen

Grid Roter Sand blass.png mit Mechaniken

Grid Redstone.png mit Redstone
                Hier:
Grid Befehlsblock.png mit Befehlen

Die vorgestellte Technik kann in der Mechanik-Welt angesehen werden.
Roter Sand.png
Überarbeitete oder neue Varianten dieser Technik existieren bereits in der aktuellen Mechanik-Welt.
Hier fehlt noch die Dokumentation dieser Varianten, diese müssen noch nachgetragen werden.

Eine Tauschmaschine bietet dem Spieler den Tausch von Waren an. Hierbei können jegliche Gegenstände getauscht werden, am üblichsten werden Smaragde, Goldklumpen oder andere zum tauschen gut geeignete Gegenstände verwendet. Für den Tauschhandel wird dem Spieler eine Eingabe zur Verfügung gestellt, diese zeigt den zu tauschbaren Gegenstand an und der Spieler muss nur noch bestätigen, das er den Gegenstand tauschen möchte. Hierbei wird auch immer geprüft ob der Spieler überhaupt in der Lage ist, den Gegenwert der Ware zu bezahlen. Falls er nicht im Stande dazu ist, findet der Tausch gar nicht erst statt.

Variante 1[Bearbeiten | Quelltext bearbeiten]

Tauschmaschine (Befehle) Bild 1.1.png Tauschmaschine (Befehle) Bild 1.2.png

Mit dieser Tauschmaschine ist man in der Lage Smaragde gegen Redstone zu tauschen. Hierbei kann man auf einen der Rahmen rechts oder links klicken. Wenn man diese Maschine einschaltet, so werden zuerst mehrere unsichtbare Rüstungsständer reitend auf einem sofort verschwindenden Drop erzeugtBefehl 1.1, welche dann ohne vom Drop abhängig zu sein verteilt werden könnenBefehl 1.2. Zusätzlich wird noch ein weiterer aber einzelner Rüstungsständer erzeugt, welcher immer direkt neben der Maschine erscheintBefehl 1.3. Nun wird in Kopfhöhe der Rüstungsständer jeweils ein Goldblock platziertBefehl 1.4 an dem dann der Rahmen erzeugt wirdBefehl 1.5. Als letztes bekommen alle Spieler in einem Radius von 25 Metern 64 Smaragde um dann mit der Maschine zu handelnBefehl 1.6. Um zu testen ob der Rahmen rechts- oder linksgeklickt wurde, wird ihm immer ein Etikett entnommenBefehl 1.7 um es anschließend nur dann wieder zu geben, wenn er nicht angeklickt wurdeBefehl 1.8. Wenn er nun das Etikett nicht besitzt, heißt das ein Gegenstand in ihm gedreht wurde oder es heraus geholt wurde, in beiden Fällen wird der Rahmen wieder in den ursprünglichen Zustand gebrachtBefehl 1.9. Nun wird von dem angeklickten Rahmen geprüft ob der Spieler, der sich um dem Rahmen befindet überhaupt Smaragde besitztBefehl 1.10. Wenn er keine besitzt, wird ihm kein Etikett gegeben und er erhält eine Nachricht diesbezüglichBefehl 1.11. Wenn er jedoch Smaragde bei sich trägt, wird er stattdessen darauf hingewiesen das er nun den Tausch durchläuftBefehl 1.12. Dann bekommt dieser Spieler einen Smaragd abgezogen und erhält ein RedstoneBefehl 1.14. Danach wird ihm auch das Etikett entfernt, welches für die Überprüfung der Smaragde im Inventar zuständig warBefehl 1.15. Wenn man einen Linksklick auf den Rahmen durchgeführt hat, kann es sein, je nach Spielmodus, das der Gegenstand heraus fällt. Damit es nicht zu einer falschen Ausgabe kommt, wird dieser Gegenstand mit einem Etikett belegtBefehl 1.16 und anschließend gelöschtBefehl 1.17. Damit ist der Tauschvorgang abgeschlossen und der Spieler kann so oft auf den Rahmen klicken, wie er Smaragde in seinem Inventar besitzt. Wird die Maschine ausgeschaltet, so werden zuerst die Goldblöcke entferntBefehl 1.18 und dann alle Rüstungsständer und RahmenBefehl 1.19. Zuletzt werden die beiden Gegenstände entferntBefehl 1.20Befehl 1.21


Befehlsblöcke mit Befehlen:
summon minecraft:item ~ ~ ~-2 {Item:{id:"minecraft:barrier",Count:1b},Age:6000,Tags:["EtiTaus:1Alle"],Passengers:[{id:"minecraft:armor_stand",Invisible:true,Tags:["EtiTaus:1Alle"] },{id:"minecraft:armor_stand",Invisible:true,Tags:["EtiTaus:1Alle"] },{id:"minecraft:armor_stand",Invisible:true,Tags:["EtiTaus:1Alle"] } ] }
execute @e[type=minecraft:item,tag=EtiTaus:1Alle] ~ ~ ~ /spreadplayers ~ ~ 5 10 false @e[type=minecraft:armor_stand,tag=EtiTaus:1Alle]
summon minecraft:armor_stand ~4 ~-3 ~ {Invisible:true,Tags:["EtiTaus:1Alle"] }
execute @e[type=minecraft:armor_stand,tag=EtiTaus:1Alle] ~ ~ ~ /setblock ~ ~1 ~ minecraft:gold_block 0 keep
execute @e[type=minecraft:armor_stand,tag=EtiTaus:1Alle] ~ ~ ~ /summon minecraft:item_frame ~ ~1 ~1 {Item:{id:"minecraft:redstone",Count:1b,tag:{display:{Lore:["Anzeige"] } } },CustomName:"ObjTaus:1Tausch",Tags:["EtiTaus:1Alle"],Facing:0}
give @a[r=25] minecraft:emerald 64 0 {display:{Name:"Tauschmaschine:1",Lore:["Smaragd für den Tausch"] } }


execute @a[r=150] ~ ~ ~ /scoreboard players tag @e[type=minecraft:item_frame,name=ObjTaus:1Tausch,tag=EtiTaus:1Klick,r=3] remove EtiTaus:1Klick
execute @a[r=150] ~ ~ ~ /scoreboard players tag @e[type=minecraft:item_frame,name=ObjTaus:1Tausch,tag=EtiTaus:1Alle,r=3] add EtiTaus:1Klick {Item:{id:"minecraft:redstone",Count:1b},ItemRotation:0b}
execute @a[r=150] ~ ~ ~ /entitydata @e[type=minecraft:item_frame,name=ObjTaus:1Tausch,tag=!EtiTaus:1Klick,r=3] {Item:{id:"minecraft:redstone",Count:1b,tag:{display:{Lore:["Anzeige"] } } },ItemRotation:0b}
execute @e[type=minecraft:item_frame,name=ObjTaus:1Tausch,tag=!EtiTaus:1Klick,r=150] ~ ~ ~ /scoreboard players tag @p[tag=!EtiTaus:1Smaragd,r=3] add EtiTaus:1Smaragd {Inventory:[{id:"minecraft:emerald"} ] }
execute @e[type=minecraft:item_frame,name=ObjTaus:1Tausch,tag=!EtiTaus:1Klick,r=150] ~ ~ ~ /title @p[tag=!EtiTaus:1Smaragd,r=3] actionbar ["",{"text":"Du hast keine Smaragde um die Ware zu kaufen!","color":"red","bold":"true"} ]
execute @e[type=minecraft:item_frame,name=ObjTaus:1Tausch,tag=!EtiTaus:1Klick,r=150] ~ ~ ~ /title @p[tag=EtiTaus:1Smaragd,r=3] actionbar ["",{"text":"Du hast die Ware gekauft!","bold":"true"} ]
execute @e[type=minecraft:item_frame,name=ObjTaus:1Tausch,tag=!EtiTaus:1Klick,r=150] ~ ~ ~ /clear @p[tag=EtiTaus:1Smaragd,r=3] minecraft:emerald -1 1
execute @e[type=minecraft:item_frame,name=ObjTaus:1Tausch,tag=!EtiTaus:1Klick,r=150] ~ ~ ~ /give @p[tag=EtiTaus:1Smaragd,r=3] minecraft:redstone 1 0 {display:{Name:"Tauschmaschine:1",Lore:["Redstone von dem Tausch"] } }
execute @e[type=minecraft:item_frame,name=ObjTaus:1Tausch,tag=!EtiTaus:1Klick,r=150] ~ ~ ~ /scoreboard players tag @a[tag=EtiTaus:1Smaragd,r=3] remove EtiTaus:1Smaragd
execute @a[r=150] ~ ~ ~ /scoreboard players tag @e[type=minecraft:item,r=3] add EtiTaus:1Anzeige {Item:{tag:{display:{Lore:["Anzeige"] } } } }
kill @e[type=minecraft:item,tag=EtiTaus:1Anzeige]


execute @e[type=minecraft:item_frame,tag=EtiTaus:1Alle] ~ ~ ~ /setblock ~ ~ ~-1 minecraft:air
kill @e[tag=EtiTaus:1Alle]
clear @a[r=25] minecraft:redstone -1 9999 {display:{Name:"Tauschmaschine:1"} }
clear @a[r=25] minecraft:emerald -1 9999 {display:{Name:"Tauschmaschine:1"} }

Variante 2[Bearbeiten | Quelltext bearbeiten]

Tauschmaschine (Befehle) Bild 2.1.png Tauschmaschine (Befehle) Bild 2.2.png

Diese Tauschmaschine tauscht Erfahrungspunkte gegen Smaragde. Dazu wird beim Einschalten eine Gruppe Rüstungsständer auf einem Drop erzeugtBefehl 2.1, welche dann problemlos verteilt werden könnenBefehl 2.2. Damit ein Rüstungsständer immer in der Nähe ist, wird noch ein zusätzlicher Rüstungsständer erzeugtBefehl 2.3. Anschließend erhalten alle Spieler in einem Radius um die Maschine zehn ErfahrungsstufenBefehl 2.4. Nun soll der Spieler, wenn er sich einem der Rüstungsständer entfernt, sein erster Slot frei geräumt werdenBefehl 2.5, danach bekommt er auch das Etikett entferntBefehl 2.6. Damit der Spieler, der sich in einem Radius von drei Metern um einen der Rüstungsständer befindet, ein droppbaren Smaragd erhält, wird im dieser gegebenBefehl 2.7 solang er noch nicht das Etikett besitzt, welches er aber direkt im Anschluss erhältBefehl 2.8, damit der Smaragd nicht permanent ins Inventar gelegt wird. Nun muss festgestellt werden, ob der Spieler innerhalb des Bereiches, einen Gegenstand fallen gelassen hat, dazu wird ihm erst ein Etikett gegebenBefehl 2.9 um es dann wieder zu entfernenBefehl 2.10, wenn er noch den Smaragd besitzt. Wenn der Spieler nun den Smaragd fallen gelassen hat oder in ein anderes Feld im Inventar gelegt hat, wird zuerst dafür gesorgt, das dieser Smaragd aus dem Inventar gelöscht wirdBefehl 2.11 um anschließend im richtigen Feld wieder genau diesen Smaragd einzubettenBefehl 2.12. Der gedroppte Smaragd wird dabei sofort gelöschtBefehl 2.13. Nun soll der Spieler, solange er noch über einer Erfahrungsstufe steht den Tausch durchführen können und dabei benachrichtigt werden. Wenn er nicht mehr im Stande ist den Tausch durchzuführen soll er ebenfalls eine Nachricht erhalten. Dazu muss zuerst geprüft werden ob der Spieler mindestens eine Erfahrungsstufe hatBefehl 2.14, wenn das der Fall ist wird der darauf folgende Ketten-Befehlsblock dies erfassenBefehl 2.15. Dadurch kann dann der bedingte Ketten-Befehlsblock nur ausgeführt werden, wenn der Spieler weniger als eine Erfahrungsstufe hatBefehl 2.16. Hat der Spieler mehr als eine Erfahrungsstufe, so erhält er eine erfolgreiche BotschaftBefehl 2.17 und erhält einen SmaragdBefehl 2.18 im Tausch gegen eine ErfahrungsstufeBefehl 2.19. Wenn die Maschine wieder ausgeschaltet wird, wird dem Spieler das eventuell noch vorhandene Etikett entferntBefehl 2.20, die Smaragde die er durch den Tausch erhalten hatBefehl 2.21, sowie alle die ein bestimmtes Etikett noch besitzenBefehl 2.22 und die Erfahrungsstufen werden entferntBefehl 2.23.


Befehlsblöcke mit Befehlen:
summon minecraft:item ~ ~10 ~ {Item:{id:"minecraft:barrier",Count:1b},Age:6000,Tags:["EtiTaus:2Alle"],Passengers:[{id:"minecraft:armor_stand",CustomName:"ObjTaus:2Zone",Small:true,Marker:true,Tags:["EtiTaus:2Alle"],ArmorItems:[{},{},{},{id:"minecraft:emerald",Count:1b} ] },{id:"minecraft:armor_stand",CustomName:"ObjTaus:2Zone",Small:true,Marker:true,Tags:["EtiTaus:2Alle"],ArmorItems:[{},{},{},{id:"minecraft:emerald",Count:1b} ] },{id:"minecraft:armor_stand",CustomName:"ObjTaus:2Zone",Small:true,Marker:true,Tags:["EtiTaus:2Alle"],ArmorItems:[{},{},{},{id:"minecraft:emerald",Count:1b} ] } ] }
execute @e[type=minecraft:item,tag=EtiTaus:2Alle] ~ ~ ~ /spreadplayers ~ ~ 10 15 false @e[type=minecraft:armor_stand,tag=EtiTaus:2Alle]
summon minecraft:armor_stand ~4 ~-3 ~ {CustomName:"ObjTaus:2Zone",Small:true,Marker:true,Tags:["EtiTaus:2Alle"],ArmorItems:[{},{},{},{id:"minecraft:emerald",Count:1b} ] }
xp 10L @a[r=25]


execute @e[type=minecraft:armor_stand,name=ObjTaus:2Zone] ~ ~ ~ /replaceitem entity @a[tag=EtiTaus:2TauschZone,rm=3,r=6] slot.hotbar.0 minecraft:air
execute @e[type=minecraft:armor_stand,name=ObjTaus:2Zone] ~ ~ ~ /scoreboard players tag @a[tag=EtiTaus:2TauschZone,rm=3,r=6] remove EtiTaus:2TauschZone
execute @e[type=minecraft:armor_stand,name=ObjTaus:2Zone] ~ ~ ~ /replaceitem entity @a[tag=!EtiTaus:2TauschZone,r=3] slot.hotbar.0 minecraft:emerald 1 0 {display:{Name:"Tauschmaschine:2",Lore:["Klicke oder werfe","den Gegenstand um","den Tausch einzugehen."] } }
execute @e[type=minecraft:armor_stand,name=ObjTaus:2Zone] ~ ~ ~ /scoreboard players tag @a[tag=!EtiTaus:2TauschZone,r=3] add EtiTaus:2TauschZone
execute @e[type=minecraft:armor_stand,name=ObjTaus:2Zone] ~ ~ ~ /execute @a[tag=EtiTaus:2TauschZone,r=3] ~ ~ ~ /scoreboard players tag @p[tag=!EtiTaus:2Tausch,r=0] add EtiTaus:2Tausch
execute @e[type=minecraft:armor_stand,name=ObjTaus:2Zone] ~ ~ ~ /execute @a[tag=EtiTaus:2TauschZone,r=3] ~ ~ ~ /scoreboard players tag @p[tag=EtiTaus:2Tausch,r=0] remove EtiTaus:2Tausch {Inventory:[{Slot:0b,id:"minecraft:emerald",tag:{display:{Name:"Tauschmaschine:2"} } } ] }
execute @e[type=minecraft:armor_stand,name=ObjTaus:2Zone] ~ ~ ~ /execute @a[tag=EtiTaus:2TauschZone,r=3] ~ ~ ~ /clear @p[tag=EtiTaus:2Tausch,r=0] minecraft:emerald -1 9999 {display:{Name:"Tauschmaschine:2"} }
execute @e[type=minecraft:armor_stand,name=ObjTaus:2Zone] ~ ~ ~ /execute @a[tag=EtiTaus:2TauschZone,r=3] ~ ~ ~ /replaceitem entity @p[tag=EtiTaus:2Tausch,r=0] slot.hotbar.0 minecraft:emerald 1 0 {display:{Name:"Tauschmaschine:2",Lore:["Klicke oder werfe","den Gegenstand um","den Tausch einzugehen."] } }
execute @e[type=minecraft:armor_stand,name=ObjTaus:2Zone] ~ ~ ~ /execute @a[tag=EtiTaus:2TauschZone,r=3] ~ ~ ~ /execute @p[tag=EtiTaus:2Tausch,r=0] ~ ~1 ~ /kill @e[type=minecraft:item,r=1,c=1]
execute @e[type=minecraft:armor_stand,name=ObjTaus:2Zone] ~ ~ ~ /execute @a[tag=EtiTaus:2TauschZone,r=3] ~ ~ ~ /testfor @p[tag=EtiTaus:2Tausch,r=0,lm=1]
testforblock ~ ~-1 ~ minecraft:chain_command_block * {SuccessCount:0}
execute @e[type=minecraft:armor_stand,name=ObjTaus:2Zone] ~ ~ ~ /execute @a[tag=EtiTaus:2TauschZone,r=3] ~ ~ ~ /tellraw @p[tag=EtiTaus:2Tausch,r=0,lm=0,l=1] ["Tauschmaschine:2 ",{"text":"Nicht genug Erfahrungspunkte!","bold":"true","color":"red"} ]
execute @e[type=minecraft:armor_stand,name=ObjTaus:2Zone] ~ ~ ~ /execute @a[tag=EtiTaus:2TauschZone,r=3] ~ ~ ~ /tellraw @p[tag=EtiTaus:2Tausch,r=0,lm=1] ["Tauschmaschine:2 ",{"text":"Smaragde für Erfahrungspunkte gekauft","bold":"true"} ]
execute @e[type=minecraft:armor_stand,name=ObjTaus:2Zone] ~ ~ ~ /execute @a[tag=EtiTaus:2TauschZone,r=3] ~ ~ ~ /give @p[tag=EtiTaus:2Tausch,r=0,lm=1] minecraft:emerald
execute @e[type=minecraft:armor_stand,name=ObjTaus:2Zone] ~ ~ ~ /execute @a[tag=EtiTaus:2TauschZone,r=3] ~ ~ ~ /xp -1L @p[tag=EtiTaus:2Tausch,r=0,lm=1]


scoreboard players tag @a[tag=EtiTaus:2Tausch] remove EtiTaus:2Tausch
clear @a[r=25] minecraft:emerald -1 9999 {display:{Name:"Tauschmaschine:2"} }
kill @e[tag=EtiTaus:2Alle]
xp -10L @a[r=25]

Variante 3[Bearbeiten | Quelltext bearbeiten]

Tauschmaschine (Befehle) Bild 3.1.png Tauschmaschine (Befehle) Bild 3.2.png

Diese Tauschmaschine tauscht Waren in dem man mit Dorfbewohnern Handel treibt. Diese Dorfbewohner können sich von ihrem Platz nicht weit entfernen, da sie daran gehindert werden. Beim Einschalten werden mehrere Dorfbewohner auf einem Drop reitend erzeugtBefehl 3.1, welche dann verteilt werdenBefehl 3.2. Zusätzlich wird auch ein Dorfbewohner direkt neben der Maschine gespawnt, damit dieser stehts dort zu finden istBefehl 3.3. Jetzt werden Rüstungsständer an die Positionen der einzelnen Dorfbewohner gespawnt, welche diese aufhalten den Platz zu verlassenBefehl 3.4. Diese Rüstungsständer haben einen weiteren Rüstungsständer huckepack, welcher im Kopfslot einen Smaragden enthält, damit man das gut sichtbar von überall erkennen kann. Als letztes bekommen alle Spieler Ziegeln und SmaragdeBefehl 3.5. Der Wiederhol-Befehlsblock testet jetzt permanent ob sich der Dorfbewohner zu weit von seiner Position entfernt hat, wenn das der Fall ist, wird ihm ein Langsamkeitseffekt gegebenBefehl 3.6 und er wird zum Zentrum seiner ursprünglichen Position zurück teleportiertBefehl 3.7. Diese Position hat der Rüstungsständer inne. Nun kann man auf die einzelnen Dorfbewohner zugehen und mit ihnen handeln. Sie tauschen dabei einen Ziegel und Smaragd gegen acht Sandsteine. Dies könnte man mit einem Dropgenerator kombinieren, welche die entsprechenden Drops erzeugt. Wenn man nun die Maschine wieder ausschaltet, so werden alle Dorfbewohner inklusive Rüstungsständer gelöschtBefehl 3.8. Die beiden Gegenstände werden ebenfalls entferntBefehl 3.9Befehl 3.10.


Befehlsblöcke mit Befehlen:
summon minecraft:item ~ ~ ~ {Item:{id:"minecraft:barrier",Count:1b},Age:6000,Tags:["EtiTaus:3Alle"],Passengers:[{id:"minecraft:villager",Tags:["EtiTaus:3Alle"],Offers:{Recipes:[{buy:{id:"minecraft:brick",Count:1b},buyB:{id:"minecraft:emerald",Count:1b},sell:{id:"minecraft:sandstone",Count:8b},maxUses:500,uses:-500,CanPickUpLoot:false,PersistenceRequired:true,Invulnerable:true,Attributes:[{Name:"generic.knockbackResistance",Base:"1f"},{Name:"generic.movementSpeed",Base:"0f"} ] } ] } },{id:"minecraft:villager",Tags:["EtiTaus:3Alle"],Offers:{Recipes:[{buy:{id:"minecraft:brick",Count:1b},buyB:{id:"minecraft:emerald",Count:1b},sell:{id:"minecraft:sandstone",Count:8b},maxUses:500,uses:-500,CanPickUpLoot:false,PersistenceRequired:true,Invulnerable:true,Attributes:[{Name:"generic.knockbackResistance",Base:"1f"} ] } ] } },{id:"minecraft:villager",Tags:["EtiTaus:3Alle"],Offers:{Recipes:[{buy:{id:"minecraft:brick",Count:1b},buyB:{id:"minecraft:emerald",Count:1b},sell:{id:"minecraft:sandstone",Count:8b},maxUses:500,uses:-500,CanPickUpLoot:false,PersistenceRequired:true,Invulnerable:true,Attributes:[{Name:"generic.knockbackResistance",Base:"1f"} ] } ] } } ] }
execute @e[type=minecraft:item,tag=EtiTaus:3Alle] ~ ~ ~ /spreadplayers ~ ~ 5 15 false @e[type=minecraft:villager,tag=EtiTaus:3Alle]
summon minecraft:villager ~4 ~-3.5 ~ {Tags:["EtiTaus:3Alle"],Offers:{Recipes:[{buy:{id:"minecraft:brick",Count:1b},buyB:{id:"minecraft:emerald",Count:1b},sell:{id:"minecraft:sandstone",Count:8b},maxUses:500,uses:-500,CanPickUpLoot:false,PersistenceRequired:true,Invulnerable:true,Attributes:[{Name:"generic.knockbackResistance",Base:"1f"},{Name:"generic.movementSpeed",Base:"0f"} ] } ] } }
execute @e[type=minecraft:villager,tag=EtiTaus:3Alle] ~ ~ ~ /summon minecraft:armor_stand ~ ~ ~ {CustomName:"ObjTaus:3Käfig",Invisible:true,Tags:["EtiTaus:3Alle"],Passengers:[{id:"minecraft:armor_stand",Invisible:true,Tags:["EtiTaus:3Alle"],ArmorItems:[{},{},{},{id:"minecraft:emerald",Count:1b} ] } ] }
execute @a[r=25] ~ ~ ~ /summon minecraft:item ~ ~ ~ {Item:{id:"minecraft:brick",Count:64b,tag:{display:{Name:"Tauschmaschine:3",Lore:["Tausch den Gegenstand"] } } },Passengers:[{id:"minecraft:item",Item:{id:"minecraft:emerald",Count:64b,tag:{display:{Name:"Tauschmaschine:3",Lore:["Tausch den Gegenstand"] } } } } ] }


execute @e[type=minecraft:armor_stand,name=ObjTaus:3Käfig] ~ ~ ~ /effect @e[type=minecraft:villager,tag=EtiTaus:3Alle,rm=1,r=2] minecraft:slowness 1 5 true
execute @e[type=minecraft:armor_stand,name=ObjTaus:3Käfig] ~ ~ ~ /teleport @e[type=minecraft:villager,tag=EtiTaus:3Alle,rm=1,r=2] ~ ~ ~


kill @e[tag=EtiTaus:3Alle]
clear @a[r=25] minecraft:brick -1 9999 {display:{Name:"Tauschmaschine:3"} }
clear @a[r=25] minecraft:emerald -1 9999 {display:{Name:"Tauschmaschine:3"} }


Disambig color.svg
Grid Grasblock.png
Auch im Minecraft Wiki wird das Thema dieser Technik behandelt:
Handel