Das offizielle Minecraft Wiki twittert hier: Wiki-Twitter  –  Chatte im Wiki-Discord  – Noch keinen Server gefunden? Es gibt einen Wiki-Server

Lebenspunkte-System (Befehle)

Aus Technik Wiki
Wechseln zu: Navigation, Suche
Gruppe: Grid Ketten-Befehlsblock.png
Systeme

Grid Roter Sand blass.png mit Mechaniken

Grid Redstone blass.png mit Redstone
                Hier:
Grid Befehlsblock.png mit Befehlen

Die vorgestellte Technik kann in der Mechanik-Welt angesehen werden.

Das Lebenspunkte-System macht die Leben oder Herzen der umherlaufenden Kreaturen sichtbar. Dies kann auf unterschiedliche Weisen erreicht werden. So können zum Beispiel die Herzen über den Kreaturen sichtbar über ihren Köpfen angezeigt werden, oder vom Spieler können sie in der Tab-Leiste angezeigt werden.

Inhaltsverzeichnis

Variante 1[Bearbeiten | Quelltext bearbeiten]

Lebenspunkte-System (Befehle) Bild 1.1.png

Dieses System zeigt die aktuelle Anzahl an noch verfügbaren Herzen an, die ein Tier hat, die Gesamtzahl der Herzen ist hierbei jedoch fest und nicht individuell für jedes Tier. Wenn man die Spawn-Eier benutzt, werden Tiere mit einem bestimmten Etikett gespawnt, nur solche Tiere werden von diesem System erfasst. Halbe Herzen werden mit diesem System nicht unterstützt, es werden immer volle Herzen angezeigt.

Einschalten

Wird der Hebel umgelegt, startet der Befehlsblock und führt die Start-Funktion einmal aus

Wiederholen

Mit dem Wiederhol-Befehlsblock führt jeden Tick die Zyklus-Funktion aus

Ausschalten

Sobald der Hebel wieder in Ausgangsstellung zurück gelegt wurde, wird die Stopp-Funktion aktiviert


Befehlsblöcke mit Befehlen:



Variante 1: Start-Funktion
Die Start-Funktion erzeugt die Punktestand-Ziele die für die Lebensleiste benutzt werden und sie gibt den Spielern vier Spawn-Eier, dessen Tiere die Lebensleiste unterstützen.

  • Zeile 2 Ein dummy-Punktestand-Ziel für die aktuellen Lebenspunkte der Tiere
  • Zeile 3 Ein dummy-Punktestand-Ziel für die Lebenspunkte vor einem Tick
  • Zeile 6 Es werden ein Huhn, eine Kuh[Z7], ein Schwein[Z8] und ein Schaf[Z9] als Spawn-Ei gegeben.
Editor Icon.png technik_wiki:lebenspunkte-system/v1start.mcfunction
# Die Punktestand-Ziele werden erstellt
scoreboard objectives add PZLebP.1Leben dummy ["Lebenspunkte-System.1: ",{"text":"Die aktuellen Herzen der Kreaturen","bold":true}]
scoreboard objectives add PZLebP.1Vergl dummy ["Lebenspunkte-System.1: ",{"text":"Die Herzen der Kreaturen vor einem Tick","bold":true}]

# Den Spielern in einem Umkreis von 25 Blöcken werden vier Spawn-Eier gegeben. Mit denen lassen sich Tiere spawnen die ihre Lebensleiste als Namen tragen werden
give @a[distance=..25] minecraft:chicken_spawn_egg{display:{Lore:["Eine Kreatur mit","Lebenspunkten"] },EntityTag:{CustomNameVisible:true,Tags:["EtiLebP.1Herzen"],DeathLootTable:"minecraft:empty"} }
give @a[distance=..25] minecraft:cow_spawn_egg{display:{Lore:["Eine Kreatur mit","Lebenspunkten"] },EntityTag:{CustomNameVisible:true,Tags:["EtiLebP.1Herzen"],DeathLootTable:"minecraft:empty"} }
give @a[distance=..25] minecraft:pig_spawn_egg{display:{Lore:["Eine Kreatur mit","Lebenspunkten"] },EntityTag:{CustomNameVisible:true,Tags:["EtiLebP.1Herzen"],DeathLootTable:"minecraft:empty"} }
give @a[distance=..25] minecraft:sheep_spawn_egg{display:{Lore:["Eine Kreatur mit","Lebenspunkten"] },EntityTag:{CustomNameVisible:true,Tags:["EtiLebP.1Herzen"],DeathLootTable:"minecraft:empty"} }


Variante 1: Zyklus-Funktion
Die Zyklus-Funktion ließt jeden Tick die Lebenspunkte der Tiere aus und vergleicht sie mit den Lebenspunkten vor einem Tick. Wenn es Unterschiede gibt, wird die Herzen-Funktion aufgerufen um die aktuellen Herze anzuzeigen.

  • Zeile 2 Zu erst werden die Lebenspunkte vor einem Tick gespeichert. Wenn das Tier gerade gespawnt wurde, besitzt es noch keinen Punktestand für die Leben und daher liegt er bei dieser Operation dann bei null.
  • Zeile 3 Danach werden die aktuellen Lebenspunkte ausgelesen und in "Leben" gespeichert.
  • Zeile 6 Anschließend werden von den Tieren, deren aktuelle Lebenspunkte mit denen vor einen Tick verglichen. Nur wenn es Unterschiede gibt, wird dann die Herzen-Funktion aufgerufen.
Editor Icon.png technik_wiki:lebenspunkte-system/v1zyklus.mcfunction
# Jeden Tick werden die Lebenspunkte der Tiere in einen Vergleispunktestand gespeichert und danach wird der aktuelle Lebenspunktewert ermittelt
execute as @e[distance=..50,tag=EtiLebP.1Herzen] run scoreboard players operation @s PZLebP.1Vergl = @s PZLebP.1Leben
execute as @e[distance=..50,tag=EtiLebP.1Herzen] store result score @s PZLebP.1Leben run data get entity @s Health

# Alle Tiere die mit den Spawn-Eiern erschaffen wurden (entsprechende Etikett) werden geprüft ob sie noch ihre aktuellen Herzen haben, wenn nicht wird die Funktion für das Tier aufgerufen
execute as @e[tag=EtiLebP.1Herzen] unless score @s PZLebP.1Vergl = @s PZLebP.1Leben run function technik_wiki:lebenspunkte-system/v1herzen

Variante 1: Herzen-Funktion
Die Herzen-Funktion schaut nach, welchen Lebenspunkte-Wert das Tier hat und gibt darauf basierend dem Tier den entsprechenden Namen mit den Herzen.

Editor Icon.png technik_wiki:lebenspunkte-system/v1herzen.mcfunction
# Alle Tiere bekommen je nach Leben die entsprechenden Herzen über ihren Kopf angezeigt
data merge entity @s[scores={PZLebP.1Leben=1..2}] {CustomName:"[\"\",{\"text\":\"❤\",\"color\":\"red\"},{\"text\":\"❤❤❤❤❤❤❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.1Leben=3..4}] {CustomName:"[\"\",{\"text\":\"❤❤\",\"color\":\"red\"},{\"text\":\"❤❤❤❤❤❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.1Leben=5..6}] {CustomName:"[\"\",{\"text\":\"❤❤❤\",\"color\":\"red\"},{\"text\":\"❤❤❤❤❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.1Leben=7..8}] {CustomName:"[\"\",{\"text\":\"❤❤❤❤\",\"color\":\"red\"},{\"text\":\"❤❤❤❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.1Leben=9..10}] {CustomName:"[\"\",{\"text\":\"❤❤❤❤❤\",\"color\":\"red\"},{\"text\":\"❤❤❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.1Leben=11..12}] {CustomName:"[\"\",{\"text\":\"❤❤❤❤❤❤\",\"color\":\"red\"},{\"text\":\"❤❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.1Leben=13..14}] {CustomName:"[\"\",{\"text\":\"❤❤❤❤❤❤❤\",\"color\":\"red\"},{\"text\":\"❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.1Leben=15..16}] {CustomName:"[\"\",{\"text\":\"❤❤❤❤❤❤❤❤\",\"color\":\"red\"},{\"text\":\"❤❤\"}]"}
data merge entity @s[scores={PZLebP.1Leben=17..18}] {CustomName:"[\"\",{\"text\":\"❤❤❤❤❤❤❤❤❤\",\"color\":\"red\"},{\"text\":\"❤\"}]"}
data merge entity @s[scores={PZLebP.1Leben=19..20}] {CustomName:"[\"\",{\"text\":\"❤❤❤❤❤❤❤❤❤❤\",\"color\":\"red\"}]"}


Variante 1: Stopp-Funktion
Die Stopp-Funktion löscht alle Punktestand-Ziele, alle Spawn-eier und entfernt alle Tiere die mit den Spawn-Eiern gespawnt wurden

Editor Icon.png technik_wiki:lebenspunkte-system/v1stopp.mcfunction
# Die Punktestand-Ziele werden entfernt
scoreboard objectives remove PZLebP.1Leben
scoreboard objectives remove PZLebP.1Vergl

# Die Spawn-Eier werden entfernt
clear @a[distance=..25] minecraft:chicken_spawn_egg{EntityTag:{Tags:["EtiLebP.1Herzen"] } }
clear @a[distance=..25] minecraft:cow_spawn_egg{EntityTag:{Tags:["EtiLebP.1Herzen"] } }
clear @a[distance=..25] minecraft:pig_spawn_egg{EntityTag:{Tags:["EtiLebP.1Herzen"] } }
clear @a[distance=..25] minecraft:sheep_spawn_egg{EntityTag:{Tags:["EtiLebP.1Herzen"] } }

# Alle Tiere die gespawnt wurden, werden entfernt
kill @e[tag=EtiLebP.1Herzen]

Variante 2[Bearbeiten | Quelltext bearbeiten]

Lebenspunkte-System (Befehle) Bild 1.2.png

Mit diesem Lebenspunkte-System werden nicht nur die Herzen der Tiere angezeigt, sondern auch die genaue Anzahl ihrer maximalen Lebensleiste. Wenn man das System einschaltet, kann man mit den erhaltenen Spawn-Eiern mehrere Tiere spawnen, die über sich als Namen die Lebensleiste tragen. Fügt man ihnen Schaden hinzu, so sieht man das und die Herzen färben sich nach und nach von grün, über gelb auf rot um.

Einschalten

Wird der Hebel umgelegt, startet der Befehlsblock und führt die Start-Funktion einmal aus

Wiederholen

Mit dem Wiederhol-Befehlsblock führt jeden Tick die Zyklus-Funktion aus

Ausschalten

Sobald der Hebel wieder in Ausgangsstellung zurück gelegt wurde, wird die Stopp-Funktion aktiviert


Befehlsblöcke mit Befehlen:



Variante 2: Start-Funktion
Die Start-Funktion erstellt die entsprechenden Punktestand-Ziele und gibt den Spielern mehrere Spawn-Eier für das Spawnen von Tieren mit Lebensleisten

  • Zeile 2 Dieses Punktestand-Ziel speichert die aktuellen Lebenspunkte der Tiere
  • Zeile 3 Mit diesem Punktestand-Ziel werden die Lebenspunkte vor einem Tick gespeichert
  • Zeile 4 Das Punktestand-Ziel speichert die maximalen Lebenspunkte die ein Tier ohne Schaden haben kann
  • Zeile 7 Anschließend werden den Spielern in einem Radius von 25 Blöcken Kabeljaue, Lachse[Z8], Kugelfische[Z9], Delfine[Z10] und Schildkröten[Z11] als Spawn-Eier zur Verfügung gestellt
Editor Icon.png technik_wiki:lebenspunkte-system/v2start.mcfunction
# Die Punktestand-Ziele werden erstellt
scoreboard objectives add PZLebP.2Leben dummy ["Lebenspunkte-System.2: ",{"text":"Die aktuellen Herzen der Kreaturen","bold":true}]
scoreboard objectives add PZLebP.2Vergl dummy ["Lebenspunkte-System.2: ",{"text":"Die Herzen der Kreaturen vor einem Tick","bold":true}]
scoreboard objectives add PZLebP.2MaxLeb dummy ["Lebenspunkte-System.2: ",{"text":"Das maximale Leben einer Kreatur","bold":true}]

# Den Spielern in einem Umkreis von 25 Blöcken werden vier Spawn-Eier gegeben. Mit denen lassen sich Tiere spawnen die ihre Lebensleiste als Namen tragen werden
give @a[distance=..25] minecraft:cod_spawn_egg{display:{Lore:["Eine Kreatur mit","Lebenspunkten"] },EntityTag:{CustomNameVisible:true,Tags:["EtiLebP.2Herzen"],DeathLootTable:"minecraft:empty"} }
give @a[distance=..25] minecraft:salmon_spawn_egg{display:{Lore:["Eine Kreatur mit","Lebenspunkten"] },EntityTag:{CustomNameVisible:true,Tags:["EtiLebP.2Herzen"],DeathLootTable:"minecraft:empty"} }
give @a[distance=..25] minecraft:pufferfish_spawn_egg{display:{Lore:["Eine Kreatur mit","Lebenspunkten"] },EntityTag:{CustomNameVisible:true,Tags:["EtiLebP.2Herzen"],DeathLootTable:"minecraft:empty"} }
give @a[distance=..25] minecraft:dolphin_spawn_egg{display:{Lore:["Eine Kreatur mit","Lebenspunkten"] },EntityTag:{CustomNameVisible:true,Tags:["EtiLebP.2Herzen"],DeathLootTable:"minecraft:empty"} }
give @a[distance=..25] minecraft:turtle_spawn_egg{display:{Lore:["Eine Kreatur mit","Lebenspunkten"] },EntityTag:{CustomNameVisible:true,Tags:["EtiLebP.2Herzen"],DeathLootTable:"minecraft:empty"} }


Variante 2: Zyklus-Funktion
Die Zyklus-Funktion prüft ob die Tiere Schaden genommen haben und falls es so ist, wird die Herzen-Funktion aufgerufen die die aktuellen Lebenspunkte anzeigt

  • Zeile 2 Zuerst werden die Lebenspunkte vor einem Tick gespeichert, wenn das Tier zuvor noch nicht existierte, betragen die Lebenspunkte vor einem Tick null.
  • Zeile 3 Anschließend werden die aktuellen Lebenspunkte ermittelt und in den Punktestand fürs Leben gespeichert.
  • Zeile 6 Tiere die gerade gespawnt wurden, besitzen im Punktestand vor einem Tick den Wert null. Diese wird abgefragt und wenn solch ein Tier gefunden wurde, wird in dem Punktestand für die maximale Lebensenergie der Wert der aktuellen Leben gespeichert, denn zu diesem Zeitpunkt hat das Tier seine vollen Leben.
  • Zeile 9 Es wird nun verglichen ob die Tiere Schaden erhalten haben, falls das so ist wird deren Lebensleiste aktualisiert, in dem die Herzen-Funktion für genau dieses Tier geladen wird
Editor Icon.png technik_wiki:lebenspunkte-system/v2zyklus.mcfunction
# Jeden Tick werden die Lebenspunkte der Tiere in einen Vergleispunktestand gespeichert und danach wird der aktuelle Lebenspunktewert ermittelt
execute as @e[distance=..50,tag=EtiLebP.2Herzen] run scoreboard players operation @s PZLebP.2Vergl = @s PZLebP.2Leben
execute as @e[distance=..50,tag=EtiLebP.2Herzen] store result score @s PZLebP.2Leben run data get entity @s Health

# Eine neu gespawnte Kreatur besitzt einen Vergleichswert von null, daher wird bei diesem das aktuelle Leben dem maximalen Leben gleichgesetzt
execute as @e[distance=..50,tag=EtiLebP.2Herzen,scores={PZLebP.2Vergl=0}] run scoreboard players operation @s PZLebP.2MaxLeb = @s PZLebP.2Leben

# Alle Tiere die mit den Spawn-Eiern erschaffen wurden und somit das entsprechende Etikett besitzen werden geprüft ob sie noch ihre aktuellen Herzen haben, wenn nicht wird die Funktion für das Tier aufgerufen
execute as @e[distance=..50,tag=EtiLebP.2Herzen] unless score @s PZLebP.2Vergl = @s PZLebP.2Leben run function technik_wiki:lebenspunkte-system/v2herzen


Variante 2: Herzen-Funktion
Die Herzen-Funktion schaut nach, was das Tier maximal an Leben hat und lädt dann die entsprechende Herzen-Funktion auf.

Editor Icon.png technik_wiki:lebenspunkte-system/v2herzen.mcfunction
# Für jedes Tier wird die entsprechende Gerzen-Funktion geladen, die dann die maximale Lebensenergie berücksichtigt
execute if entity @s[scores={PZLebP.2MaxLeb=1..3}] run function technik_wiki:lebenspunkte-system/v2herzen_3
execute if entity @s[scores={PZLebP.2MaxLeb=4}] run function technik_wiki:lebenspunkte-system/v2herzen_4
execute if entity @s[scores={PZLebP.2MaxLeb=5..6}] run function technik_wiki:lebenspunkte-system/v2herzen_6
execute if entity @s[scores={PZLebP.2MaxLeb=7..8}] run function technik_wiki:lebenspunkte-system/v2herzen_8
execute if entity @s[scores={PZLebP.2MaxLeb=9..10}] run function technik_wiki:lebenspunkte-system/v2herzen_10
execute if entity @s[scores={PZLebP.2MaxLeb=11..20}] run function technik_wiki:lebenspunkte-system/v2herzen_20
execute if entity @s[scores={PZLebP.2MaxLeb=21..30}] run function technik_wiki:lebenspunkte-system/v2herzen_30


Variante 2: Herzen-3-Funktion

Editor Icon.png technik_wiki:lebenspunkte-system/v2herzen_3.mcfunction
# Alle Tiere mit ein und ein halbes Herz erhalten diese Lebensleiste
data merge entity @s[scores={PZLebP.2Leben=1}] {CustomName:"[\"\",{\"text\":\"❥\",\"color\":\"red\"},{\"text\":\"❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=2}] {CustomName:"[\"\",{\"text\":\"❤\",\"color\":\"gold\"},{\"text\":\"❥\"}]"}
data merge entity @s[scores={PZLebP.2Leben=3}] {CustomName:"[\"\",{\"text\":\"❤❥\",\"color\":\"green\"}]"}


Variante 2: Herzen-4-Funktion

Editor Icon.png technik_wiki:lebenspunkte-system/v2herzen_4.mcfunction
# Alle Tiere mit zwei Herzen erhalten diese Lebensleiste
data merge entity @s[scores={PZLebP.2Leben=1}] {CustomName:"[\"\",{\"text\":\"❥\",\"color\":\"red\"},{\"text\":\"❥❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=2}] {CustomName:"[\"\",{\"text\":\"❤\",\"color\":\"gold\"},{\"text\":\"❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=3}] {CustomName:"[\"\",{\"text\":\"❤❥\",\"color\":\"gold\"},{\"text\":\"❥\"}]"}
data merge entity @s[scores={PZLebP.2Leben=4}] {CustomName:"[\"\",{\"text\":\"❤❤\",\"color\":\"green\"}]"}


Variante 2: Herzen-6-Funktion

Editor Icon.png technik_wiki:lebenspunkte-system/v2herzen_6.mcfunction
# Alle Tiere mit drei Herzen erhalten diese Lebensleiste
data merge entity @s[scores={PZLebP.2Leben=1}] {CustomName:"[\"\",{\"text\":\"❥\",\"color\":\"red\"},{\"text\":\"❥❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=2}] {CustomName:"[\"\",{\"text\":\"❤\",\"color\":\"gold\"},{\"text\":\"❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=3}] {CustomName:"[\"\",{\"text\":\"❤❥\",\"color\":\"gold\"},{\"text\":\"❥❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=3..4}] {CustomName:"[\"\",{\"text\":\"❤❤\",\"color\":\"gold\"},{\"text\":\"❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=5..6}] {CustomName:"[\"\",{\"text\":\"❤❤❤\",\"color\":\"green\"}]"}


Variante 2: Herzen-8-Funktion

Editor Icon.png technik_wiki:lebenspunkte-system/v2herzen_8.mcfunction
# Alle Tiere mit vier Herzen erhalten diese Lebensleiste
data merge entity @s[scores={PZLebP.2Leben=1}] {CustomName:"[\"\",{\"text\":\"❥\",\"color\":\"red\"},{\"text\":\"❥❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=2}] {CustomName:"[\"\",{\"text\":\"❤\",\"color\":\"red\"},{\"text\":\"❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=3}] {CustomName:"[\"\",{\"text\":\"❤❥\",\"color\":\"gold\"},{\"text\":\"❥❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=4}] {CustomName:"[\"\",{\"text\":\"❤❤\",\"color\":\"gold\"},{\"text\":\"❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=5..6}] {CustomName:"[\"\",{\"text\":\"❤❤❤\",\"color\":\"green\"},{\"text\":\"❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=7..8}] {CustomName:"[\"\",{\"text\":\"❤❤❤❤\",\"color\":\"green\"}]"}

Variante 2: Herzen-10-Funktion

Editor Icon.png technik_wiki:lebenspunkte-system/v2herzen_10.mcfunction
# Alle Tiere mit fünf Herzen erhalten diese Lebensleiste
data merge entity @s[scores={PZLebP.2Leben=1}] {CustomName:"[\"\",{\"text\":\"❥\",\"color\":\"red\"},{\"text\":\"❥❤❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=2}] {CustomName:"[\"\",{\"text\":\"❤\",\"color\":\"red\"},{\"text\":\"❤❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=3}] {CustomName:"[\"\",{\"text\":\"❤❥\",\"color\":\"gold\"},{\"text\":\"❥❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=4}] {CustomName:"[\"\",{\"text\":\"❤❤\",\"color\":\"gold\"},{\"text\":\"❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=5..6}] {CustomName:"[\"\",{\"text\":\"❤❤❤\",\"color\":\"gold\"},{\"text\":\"❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=7..8}] {CustomName:"[\"\",{\"text\":\"❤❤❤❤\",\"color\":\"green\"},{\"text\":\"❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=9..10}] {CustomName:"[\"\",{\"text\":\"❤❤❤❤❤\",\"color\":\"green\"}]"}


Variante 2: Herzen-20-Funktion

Editor Icon.png technik_wiki:lebenspunkte-system/v2herzen_20.mcfunction
# Alle Tiere mit zehn Herzen erhalten diese Lebensleiste
data merge entity @s[scores={PZLebP.2Leben=1}] {CustomName:"[\"\",{\"text\":\"❥\",\"color\":\"red\"},{\"text\":\"❥❤❤❤❤❤❤❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=2}] {CustomName:"[\"\",{\"text\":\"❤\",\"color\":\"red\"},{\"text\":\"❤❤❤❤❤❤❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=3}] {CustomName:"[\"\",{\"text\":\"❤❥\",\"color\":\"red\"},{\"text\":\"❥❤❤❤❤❤❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=4}] {CustomName:"[\"\",{\"text\":\"❤❤\",\"color\":\"red\"},{\"text\":\"❤❤❤❤❤❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=5..6}] {CustomName:"[\"\",{\"text\":\"❤❤❤\",\"color\":\"gold\"},{\"text\":\"❤❤❤❤❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=7..8}] {CustomName:"[\"\",{\"text\":\"❤❤❤❤\",\"color\":\"gold\"},{\"text\":\"❤❤❤❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=9..10}] {CustomName:"[\"\",{\"text\":\"❤❤❤❤❤\",\"color\":\"gold\"},{\"text\":\"❤❤❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=11..12}] {CustomName:"[\"\",{\"text\":\"❤❤❤❤❤❤\",\"color\":\"gold\"},{\"text\":\"❤❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=13..14}] {CustomName:"[\"\",{\"text\":\"❤❤❤❤❤❤❤\",\"color\":\"green\"},{\"text\":\"❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=15..16}] {CustomName:"[\"\",{\"text\":\"❤❤❤❤❤❤❤❤\",\"color\":\"green\"},{\"text\":\"❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=17..18}] {CustomName:"[\"\",{\"text\":\"❤❤❤❤❤❤❤❤❤\",\"color\":\"green\"},{\"text\":\"❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=19..20}] {CustomName:"[\"\",{\"text\":\"❤❤❤❤❤❤❤❤❤❤\",\"color\":\"green\"}]"}

Variante 2: Herzen-30-Funktion

Editor Icon.png technik_wiki:lebenspunkte-system/v2herzen_30.mcfunction
# Alle Tiere mit fünfzehn Herzen erhalten diese Lebensleiste
data merge entity @s[scores={PZLebP.2Leben=1}] {CustomName:"[\"\",{\"text\":\"❥\",\"color\":\"red\"},{\"text\":\"❥❤❤❤❤❤❤❤❤❤❤❤❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=2}] {CustomName:"[\"\",{\"text\":\"❤\",\"color\":\"red\"},{\"text\":\"❤❤❤❤❤❤❤❤❤❤❤❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=3}] {CustomName:"[\"\",{\"text\":\"❤❥\",\"color\":\"red\"},{\"text\":\"❥❤❤❤❤❤❤❤❤❤❤❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=4}] {CustomName:"[\"\",{\"text\":\"❤❤\",\"color\":\"red\"},{\"text\":\"❤❤❤❤❤❤❤❤❤❤❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=5..6}] {CustomName:"[\"\",{\"text\":\"❤❤❤\",\"color\":\"red\"},{\"text\":\"❤❤❤❤❤❤❤❤❤❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=7..8}] {CustomName:"[\"\",{\"text\":\"❤❤❤❤\",\"color\":\"gold\"},{\"text\":\"❤❤❤❤❤❤❤❤❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=9..10}] {CustomName:"[\"\",{\"text\":\"❤❤❤❤❤\",\"color\":\"gold\"},{\"text\":\"❤❤❤❤❤❤❤❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=11..12}] {CustomName:"[\"\",{\"text\":\"❤❤❤❤❤❤\",\"color\":\"gold\"},{\"text\":\"❤❤❤❤❤❤❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=13..14}] {CustomName:"[\"\",{\"text\":\"❤❤❤❤❤❤❤\",\"color\":\"gold\"},{\"text\":\"❤❤❤❤❤❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=15..16}] {CustomName:"[\"\",{\"text\":\"❤❤❤❤❤❤❤❤\",\"color\":\"gold\"},{\"text\":\"❤❤❤❤❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=17..18}] {CustomName:"[\"\",{\"text\":\"❤❤❤❤❤❤❤❤❤\",\"color\":\"gold\"},{\"text\":\"❤❤❤❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=17..18}] {CustomName:"[\"\",{\"text\":\"❤❤❤❤❤❤❤❤❤❤\",\"color\":\"gold\"},{\"text\":\"❤❤❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=21..22}] {CustomName:"[\"\",{\"text\":\"❤❤❤❤❤❤❤❤❤❤❤\",\"color\":\"green\"},{\"text\":\"❤❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=23..24}] {CustomName:"[\"\",{\"text\":\"❤❤❤❤❤❤❤❤❤❤❤❤\",\"color\":\"green\"},{\"text\":\"❤❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=25..26}] {CustomName:"[\"\",{\"text\":\"❤❤❤❤❤❤❤❤❤❤❤❤❤\",\"color\":\"green\"},{\"text\":\"❤❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=27..28}] {CustomName:"[\"\",{\"text\":\"❤❤❤❤❤❤❤❤❤❤❤❤❤❤\",\"color\":\"green\"},{\"text\":\"❤\"}]"}
data merge entity @s[scores={PZLebP.2Leben=29..30}] {CustomName:"[\"\",{\"text\":\"❤❤❤❤❤❤❤❤❤❤❤❤❤❤❤\",\"color\":\"green\"}]"}

Variante 2: Stopp-Funktion
Die Stopp-Funktion löscht alle Punktestand-Ziele wieder und auch die Spawn-Eier sowie die damit erschaffenen Tiere

Editor Icon.png technik_wiki:lebenspunkte-system/v2stopp.mcfunction
# Die Punktestand-Ziele werden entfernt
scoreboard objectives remove PZLebP.2Leben
scoreboard objectives remove PZLebP.2Vergl
scoreboard objectives remove PZLebP.2MaxLeb

# Die Spawn-Eier werden entfernt
clear @a[distance=..25] minecraft:chicken_spawn_egg{EntityTag:{Tags:["EtiLebP.2Herzen"] } }
clear @a[distance=..25] minecraft:cow_spawn_egg{EntityTag:{Tags:["EtiLebP.2Herzen"] } }
clear @a[distance=..25] minecraft:pig_spawn_egg{EntityTag:{Tags:["EtiLebP.2Herzen"] } }
clear @a[distance=..25] minecraft:sheep_spawn_egg{EntityTag:{Tags:["EtiLebP.2Herzen"] } }

# Alle Tiere die gespawnt wurden, werden entfernt
kill @e[tag=EtiLebP.2Herzen]