Das offizielle Minecraft Wiki twittert hier: Wiki-Twitter  –  Chatte im Wiki-Discord  – Noch keinen Server gefunden? Es gibt einen Wiki-Server

Zeichen-Eingabe (Befehle)

Aus Technik Wiki
(Weitergeleitet von Eingabe-System (Befehle))
Wechseln zu: Navigation, Suche
Gruppe: Grid Ketten-Befehlsblock.png
Systeme

Grid Roter Sand blass.png mit Mechaniken

Grid Redstone blass.png mit Redstone
                Hier:
Grid Befehlsblock.png mit Befehlen

Die vorgestellte Technik kann in der Mechanik-Welt angesehen werden.

Die Zeichen-Eingabe ermöglicht das Eintippen von Zeichen, wie bei einer Tastatur. Alle Zeichen besitzen auf einer echten Tastatur einen bestimmten Datenwert, dieser kann unter Uni-Code nachgeschlagen werden. Der komplette Zeichensatz wird hier nicht eingefügt, sondern es wird sich auf nachfolgende Zeichen beschränkt:

ABCDEFGHIJKLMNOPQRSTUVWXYZÄÖÜ,.-_

Inhaltsverzeichnis

Variante 1[Bearbeiten | Quelltext bearbeiten]

Roter Sand.png
Diese neue oder überarbeitete Technik ist noch nicht in der aktuellen Mechanik-Welt vorhanden.
In einem der nächsten Updates wird sie dort hinzugefügt werden.

Zeichen-Eingabe (Befehle) Bild 1.1.png Zeichen-Eingabe (Befehle) Bild 1.2.png Zeichen-Eingabe (Befehle) Bild 1.3.png

Diese Zeichen-Eingabe ermöglicht das Eintippen von Buchstaben oder anderen Zeichen in der Chat-Leiste. Die Buchstaben werden nach dem Eintippen zusammengefügt. So lassen sich ganze Wörter eingeben, welche man ausgegeben bekommt.

Einschalten
  • Befehl 1.1 Wenn der Hebel umgelegt wird, wird die Start-Funktion gestartet.
Wiederholen
  • Befehl 1.2 Beim Einschalten wird auch der Wiederhol-Befehlsblock gestartet, der jeden Tick die Zyklus-Funktion lädt.
Ausschalten
  • Befehl 1.3 Wenn der Hebel wieder in Ausgangsstellung zurück gelegt wird, wird die Stopp-Funktion ausgelöst und schaltet alles wieder ab.

Befehlsblöcke mit Befehlen:


Variante 1: Start-Funktion
Die Start-Funktion erstellt das Auslöser-Punktestand-Ziel und erzeugt Partikelwolken die die Zeichen speichern samt Schild.

Editor Icon.png zeichen-eingabe:v1start.mcfunction
# Das Punktestand-Ziel für den Auslöser wird erstellt.
scoreboard objectives add PZZeiEin.1Taste trigger ["Zeichen-Eingabe.1: ",{"text":"Tastenklick","bold":true}]

# Zwei Partikelwolken werden erstellt, welche die eingetippten Zeichen speichern
summon minecraft:area_effect_cloud ~ ~1 ~ {Duration:-1,Age:-2147483648,WaitTime:-2147483648,Particle:"minecraft:block minecraft:air",Tags:["EtiZeiEin.1Alle","EtiZeiEin.1Zeichen"],CustomName:'{"text":"","color":"gray"}'}
summon minecraft:area_effect_cloud ~ ~2 ~ {Duration:-1,Age:-2147483648,WaitTime:-2147483648,Particle:"minecraft:block minecraft:air",Tags:["EtiZeiEin.1Alle","EtiZeiEin.1Zeichenkette"],CustomName:'{"text":"","color":"gray"}'}

# An der Position der Partikelwolke wird ein Schild aufgestellt, welches für das Verbinden von Zeichen verwendet wird.
execute at @e[tag=EtiZeiEin.1Zeichen] run setblock ~ ~ ~ minecraft:oak_sign{Text1:'[{"text":""}]'} replace

Variante 1: Zyklus-Funktion
Die Zyklus-Funktion zeigt dem Spieler im Chat eine Zeichen-Eingabe von dem Alphabet inklusive ein paar Sonderzeichen. Auf diese kann er tippen, wodurch ein Auslöser aktiv wird und darauf hin wird eine Klick-Funktion gestartet.

Editor Icon.png zeichen-eingabe:v1zyklus.mcfunction
# Wenn der Spieler ein Zeichen angeklickt hat, wird die Klick-Funktion gestartet
execute if entity @p[scores={PZZeiEin.1Taste=1..}] as @e[type=minecraft:area_effect_cloud,tag=EtiZeiEin.1Zeichen,sort=nearest,limit=1] run function zeichen-eingabe:v1klick

# Von der Position der Partikelwolke erhalten alle Spieler in einem Umkreis von 25 Metern, sofern sie etwas zuvor eingetippt hatten, die Chat-Eingabe angezeigt. Dort wird dem Spieler eine Tastatur angezeigt, wo er jeden einzelnen Buchstaben und andere Zeichen antippen kann.
execute at @e[type=minecraft:area_effect_cloud,tag=EtiZeiEin.1Zeichen,sort=nearest,limit=1] as @a[distance=..25] unless entity @s[scores={PZZeiEin.1Taste=0}] run tellraw @s ["Zeichen-Eingabe.1:\n",{"text":"Q","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"Q\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 81"} },{"text":" W","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"W\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 87"} },{"text":" E","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"E\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 69"} },{"text":" R","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"R\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 82"} },{"text":" T","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"T\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 84"} },{"text":" Z","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"Z\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 90"} },{"text":" U","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"U\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 85"} },{"text":" I","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"I\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 73"} },{"text":" O","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"O\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 79"} },{"text":" P","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"P\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 80"} },{"text":" Ü","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"Ü\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 220"} },{"text":"\nA","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"A\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 65"} },{"text":" S","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"S\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 83"} },{"text":" D","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"D\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 68"} },{"text":" F","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"F\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 70"} },{"text":" G","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"G\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 71"} },{"text":" H","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"H\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 72"} },{"text":" J","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"J\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 74"} },{"text":" K","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"K\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 75"} },{"text":" L","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"L\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 76"} },{"text":" Ö","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"Ö\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 214"} },{"text":" Ä","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"Ä\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 196"} },{"text":"\nY","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"Y\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 89"} },{"text":" X","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"X\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 88"} },{"text":" C","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"C\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 67"} },{"text":" V","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"V\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 86"} },{"text":" B","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"B\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 66"} },{"text":" N","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"N\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 78"} },{"text":" M","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"M\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 77"} },{"text":" ,","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\",\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 44"} },{"text":" .","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\".\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 46"} },{"text":" -","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"-\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 45"} },{"text":" _","color":"gray","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"\"_\""} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 95"} },{"text":"\n<Eingabe Löschen>","color":"red","bold":true,"hoverEvent":{"action":"show_text","value":{"text":"Tippe um eine neue Zeichenkette einzugeben"} },"clickEvent":{"action":"run_command","value":"/trigger PZZeiEin.1Taste set 1"} },{"text":"\nzeichenkette == \"","bold":true},{"block":"~ ~ ~","nbt":"Text1","interpret":true},{"text":"\"","bold":true}]

# Wenn der Spieler etwas angetippt hat, erhält er erneut die Möglichkeit den Auslöser wieder zu aktivieren und der Wert wird auf null gesetzt.
execute as @a[distance=..25] unless entity @s[scores={PZZeiEin.1Taste=0}] run scoreboard players enable @s PZZeiEin.1Taste
execute as @a[distance=..25] unless entity @s[scores={PZZeiEin.1Taste=0}] run scoreboard players set @s PZZeiEin.1Taste 0

Variante 1: Klick-Funktion
Die Klick-Funktion schaut auf den Wert des Spieler um zu erfahren welches Zeichen getippt wurde und speichert dieses in eine Partikelwolke und vereint dieses eine Zeichen der bisherigen Eingabe durch ein Schild, dass den gemeinsamen Text speichert.

Editor Icon.png zeichen-eingabe:v1klick.mcfunction
# Wenn der Spieler den Wert eins besitzt, hat er auf Eingabe löschen detippt, wodurch die Partikelwolken einen leeren Namen bekommen
execute if entity @p[scores={PZZeiEin.1Taste=1}] as @e[type=minecraft:area_effect_cloud,tag=EtiZeiEin.1Alle,sort=nearest,limit=2] run data merge entity @s {CustomName:'{"text":""}'}

# Je nach Zeichen das der Spieler angeklickt hat, erhält er einen bestimmten Wert. Dieser bestimmt, welches Zeichen die Zeichen-Partikelwolke bekommt.
execute if entity @p[scores={PZZeiEin.1Taste=44}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":","}'}
execute if entity @p[scores={PZZeiEin.1Taste=45}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"-"}'}
execute if entity @p[scores={PZZeiEin.1Taste=46}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"."}'}
execute if entity @p[scores={PZZeiEin.1Taste=65}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"A"}'}
execute if entity @p[scores={PZZeiEin.1Taste=66}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"B"}'}
execute if entity @p[scores={PZZeiEin.1Taste=67}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"C"}'}
execute if entity @p[scores={PZZeiEin.1Taste=68}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"D"}'}
execute if entity @p[scores={PZZeiEin.1Taste=69}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"E"}'}
execute if entity @p[scores={PZZeiEin.1Taste=70}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"F"}'}
execute if entity @p[scores={PZZeiEin.1Taste=71}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"G"}'}
execute if entity @p[scores={PZZeiEin.1Taste=72}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"H"}'}
execute if entity @p[scores={PZZeiEin.1Taste=73}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"I"}'}
execute if entity @p[scores={PZZeiEin.1Taste=74}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"J"}'}
execute if entity @p[scores={PZZeiEin.1Taste=75}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"K"}'}
execute if entity @p[scores={PZZeiEin.1Taste=76}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"L"}'}
execute if entity @p[scores={PZZeiEin.1Taste=77}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"M"}'}
execute if entity @p[scores={PZZeiEin.1Taste=78}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"N"}'}
execute if entity @p[scores={PZZeiEin.1Taste=79}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"O"}'}
execute if entity @p[scores={PZZeiEin.1Taste=80}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"P"}'}
execute if entity @p[scores={PZZeiEin.1Taste=81}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"Q"}'}
execute if entity @p[scores={PZZeiEin.1Taste=82}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"R"}'}
execute if entity @p[scores={PZZeiEin.1Taste=83}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"S"}'}
execute if entity @p[scores={PZZeiEin.1Taste=84}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"T"}'}
execute if entity @p[scores={PZZeiEin.1Taste=85}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"U"}'}
execute if entity @p[scores={PZZeiEin.1Taste=86}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"V"}'}
execute if entity @p[scores={PZZeiEin.1Taste=87}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"W"}'}
execute if entity @p[scores={PZZeiEin.1Taste=88}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"X"}'}
execute if entity @p[scores={PZZeiEin.1Taste=89}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"Y"}'}
execute if entity @p[scores={PZZeiEin.1Taste=90}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"Z"}'}
execute if entity @p[scores={PZZeiEin.1Taste=95}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"_"}'}
execute if entity @p[scores={PZZeiEin.1Taste=196}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"Ä"}'}
execute if entity @p[scores={PZZeiEin.1Taste=214}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"Ö"}'}
execute if entity @p[scores={PZZeiEin.1Taste=220}] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"Ü"}'}

# Die beiden Namen der Partikelwolken werden im Schild zusammengefügt.
execute at @s run data merge block ~ ~ ~ {Text1:'[{"entity":"@e[tag=EtiZeiEin.1Zeichenkette,sort=nearest,limit=1]","nbt":"CustomName","interpret":true},{"entity":"@e[tag=EtiZeiEin.1Zeichen,sort=nearest,limit=1]","nbt":"CustomName","interpret":true}]'}

# Die Zeichenketten-Partikelwolke erhält anschließend die komplette Zeichenkette des Schildes als Namen.
execute at @s run data modify entity @e[type=minecraft:area_effect_cloud,tag=EtiZeiEin.1Zeichenkette,sort=nearest,limit=1] CustomName set from block ~ ~ ~ Text1

Variante 1: Stopp-Funktion
Die Stopp-Funktion löscht das Punktestand-Ziel wieder, sowie die Partikelwolken und das Schild.

Editor Icon.png zeichen-eingabe:v1stopp.mcfunction
# Das Punktestand-Ziel wird wieder gelöscht.
scoreboard objectives remove PZZeiEin.1Taste

# Das Schild wie auch die Partikelwolken werden entfernt
execute at @e[tag=EtiZeiEin.1Zeichen] run setblock ~ ~ ~ minecraft:air replace
kill @e[tag=EtiZeiEin.1Alle]

Variante 2[Bearbeiten | Quelltext bearbeiten]

Roter Sand.png
Diese neue oder überarbeitete Technik ist noch nicht in der aktuellen Mechanik-Welt vorhanden.
In einem der nächsten Updates wird sie dort hinzugefügt werden.

Zeichen-Eingabe (Befehle) Bild 2.1.png Zeichen-Eingabe (Befehle) Bild 2.2.png Zeichen-Eingabe (Befehle) Bild 2.3.png

Mit dieser Zeichen-Eingabe erhält man eine in der Welt vorhandene Anzeige auf die man klicken kann. Auf dieser Anzeige wird eine Tastatur abgebildet und alle Zeichen die man angetippt hat, werden im Chat angezeigt.

Einschalten
  • Befehl 2.1 Wenn der Hebel umgelegt wird, wird die Start-Funktion gestartet.
Wiederholen
  • Befehl 2.2 Beim Einschalten wird auch der Wiederhol-Befehlsblock gestartet, der jeden Tick die Zyklus-Funktion lädt.
Ausschalten
  • Befehl 2.3 Wenn der Hebel wieder in Ausgangsstellung zurück gelegt wird, wird die Stopp-Funktion ausgelöst und schaltet alles wieder ab.

Befehlsblöcke mit Befehlen:


Variante 2: Start-Funktion
Die Start-Funktion erstellt das Auslöser-Punktestand-Ziel, erstellt das Team, damit keine Kollsionen entstehen sowie Esel, Dorfbewohner, Partikelwolke samt der Rüstungsständer die die Zeichen als Namen tragen und in der Luft schweben.

Editor Icon.png zeichen-eingabe:v2start.mcfunction
# Ein Punktestand-Ziel für das Klicken auf die Chat-Auslöser wird erstellt.
scoreboard objectives add PZZeiEin.2Klick minecraft.custom:minecraft.talked_to_villager ["Zeichen-Eingabe.2: ",{"text":"Rechtsklick auf Dorfbewohner","bold":true}]

# Das Team wird erstellt, damit keine Kollision mit dem Esel und Dorfbewohner zu stande kommt.
team add TMZeiEin.2Kol ["Zeichen-Eingabe.2: ",{"text":"Kollisionsfrei","bold":true}]
team modify TMZeiEin.2Kol collisionRule never

# Der unsichtbare Esel wird erstellt, auf dem sich der Spieler draufsetzen kann, welcher in sich eine Eichenholztreppe hat. Über ihn wird ein unsichtbarer Dorfbewohner erzeugt. Alle befinden sich in dem Team.
summon minecraft:donkey ~ ~-1 ~-10 {ChestedHorse:true,NoAI:true,Silent:true,Tame:true,Invulnerable:true,NoGravity:true,Rotation:[270.0f,0.0f],Team:"TMZeiEin.2Kol",Tags:["EtiZeiEin.2Alle","EtiZeiEin.2Sitz"],DeathLootTable:"minecraft:empty",ActiveEffects:[{Id:14b,Amplifier:0b,Ambient:false,ShowParticles:false,Duration:2147483647},{Id:10b,Amplifier:10b,Ambient:false,ShowParticles:false,Duration:2147483647}]}
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run setblock ~ ~1 ~ minecraft:oak_stairs[facing=west]
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:villager ~0.5 ~0.5 ~ {NoAI:true,Silent:true,Invulnerable:true,NoGravity:true,Offers:{Recipes:[]},Rotation:[270.0f,0.0f],Team:"TMZeiEin.2Kol",Tags:["EtiZeiEin.2Alle","EtiEing:1Klick"],ActiveEffects:[{Id:14b,Amplifier:0b,Ambient:false,ShowParticles:false,Duration:2147483647},{Id:10b,Amplifier:10b,Ambient:false,ShowParticles:false,Duration:2147483647}]}

# Vor dem Esel werden zwei unsichtbare Partikelwolken erzeugt, die die Zeichen speichern werden.
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:area_effect_cloud ~2 ~1 ~ {Duration:-1,Age:-2147483648,WaitTime:-2147483648,Particle:"minecraft:block minecraft:air",Tags:["EtiZeiEin.2Alle","EtiZeiEin.2Zeichen"],CustomName:'{"text":"","color":"gray"}'}
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:area_effect_cloud ~2 ~1 ~ {Duration:-1,Age:-2147483648,WaitTime:-2147483648,Particle:"minecraft:block minecraft:air",Tags:["EtiZeiEin.2Alle","EtiZeiEin.2Zeichenkette"],CustomName:'{"text":"","color":"gray"}'}

# An der Position der Zeichen-Partikelwolke wird ein Schild platziert, dass die Zeichen der Partikelwolken verbinden kann.
execute at @e[tag=EtiZeiEin.2Zeichen] run setblock ~ ~ ~ minecraft:oak_sign[rotation=4]{Text1:'[{"text":""}]'} replace

# Alle Zeichen die eintippbar sind, werden als unsichtbare Rüstungsständer ohne Schwerkraft mit ihren Namen angezeigt, an der Stell des Esels erzeugt.
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~1 ~-1.25 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"Q","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~1 ~-1 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"W","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~1 ~-0.75 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"E","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~1 ~-0.5 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"R","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~1 ~-0.25 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"T","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~1 ~ {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"Z","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~1 ~0.25 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"U","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~1 ~0.5 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"I","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~1 ~0.75 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"O","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~1 ~1 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"P","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~1 ~1.25 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"Ü","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~0.75 ~-1.25 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"A","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~0.75 ~-1 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"S","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~0.75 ~-0.75 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"D","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~0.75 ~-0.5 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"F","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~0.75 ~-0.25 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"G","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~0.75 ~ {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"H","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~0.75 ~0.25 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"J","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~0.75 ~0.5 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"K","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~0.75 ~0.75 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"L","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~0.75 ~1 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"Ö","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~0.75 ~1.25 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"Ä","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~0.5 ~-1.25 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"Y","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~0.5 ~-1 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"X","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~0.5 ~-0.75 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"C","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~0.5 ~-0.5 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"V","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~0.5 ~-0.25 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"B","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~0.5 ~ {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"N","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~0.5 ~0.25 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"M","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~0.5 ~0.5 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":", ","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~0.5 ~0.75 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":". ","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~0.5 ~1 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"-","bold":true}',Tags:["EtiZeiEin.2Alle"] }
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run summon minecraft:armor_stand ~2 ~0.5 ~1.25 {Small:true,NoGravity:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"_","bold":true}',Tags:["EtiZeiEin.2Alle"] }

Variante 2: Zyklus-Funktion
Die Zyklus-Funktion prüft ob sich ein Spieler auf dem Esel gesetzt hat und auf eines der Zeichen geklickt hat. Dann ruft sie die Klick-Funktion auf. Anschließend wird die bisherige Eingabe samt neuen Zeichen im Chat ausgegeben.

Editor Icon.png zeichen-eingabe:v2zyklus.mcfunction
# Nur wenn sich der nächstgelegene Spieler auf dem Esel sitzt, wird die Klick-Funktion gestartet.
execute at @p[distance=..15,scores={PZZeiEin.2Klick=1..},nbt={RootVehicle:{Entity:{id:"minecraft:donkey",Tags:["EtiZeiEin.2Sitz"]} } }] as @e[type=minecraft:area_effect_cloud,tag=EtiZeiEin.2Zeichen,sort=nearest,limit=1] run function zeichen-eingabe:v2klick

# Wenn der Spieler in der Nähe der Zeichen-Partikelwolke einen Klick-wert von mindestens eins besitzt, wird ihm im Chat die aktuelle Zeichenkette angezeigt.
execute at @e[type=minecraft:area_effect_cloud,tag=EtiZeiEin.2Zeichen,sort=nearest,limit=1] run tellraw @p[distance=..5,scores={PZZeiEin.2Klick=1..}] ["Zeichen-Eingabe.2: ",{"text":"\nzeichenkette == \"","bold":true},{"block":"~ ~ ~","nbt":"Text1","interpret":true},{"text":"\"","bold":true}]

# Falls Spieler den Klick-Wert mindestens bei eins besitzen, wird er wieder auf null gesetzt.
scoreboard players set @a[scores={PZZeiEin.2Klick=1..}] PZZeiEin.2Klick 0

Variante 2: Klick-Funktion
Die Klick-Funktion prüft in welche genaue Richtung der Spieler geschaut hat und erkannt dadurch das Zeichen was angeklickt wurde und speichert dieses in Partikelwolken und anschließend in das Schild.

Editor Icon.png zeichen-eingabe:v2klick.mcfunction
# Je nach Rotation und Neigung kann geschlussfolgert werden, auf welches Zeichen der Spieler getippt hat und genau dieses Zeichen wird in die Zeichen-Partikelwolke gespeichert.
execute if entity @p[distance=..1,y_rotation=-124..-120,x_rotation=-7..-2] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"Q"}'}
execute if entity @p[distance=..1,y_rotation=-119..-114,x_rotation=-7..-2] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"W"}'}
execute if entity @p[distance=..1,y_rotation=-113..-108,x_rotation=-7..-2] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"E"}'}
execute if entity @p[distance=..1,y_rotation=-107..-101,x_rotation=-7..-2] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"R"}'}
execute if entity @p[distance=..1,y_rotation=-100..-94,x_rotation=-7..-2] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"T"}'}
execute if entity @p[distance=..1,y_rotation=-93..-87,x_rotation=-7..-2] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"Z"}'}
execute if entity @p[distance=..1,y_rotation=-86..-80,x_rotation=-7..-2] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"U"}'}
execute if entity @p[distance=..1,y_rotation=-79..-73,x_rotation=-7..-2] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"I"}'}
execute if entity @p[distance=..1,y_rotation=-72..-67,x_rotation=-7..-2] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"O"}'}
execute if entity @p[distance=..1,y_rotation=-66..-61,x_rotation=-7..-2] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"P"}'}
execute if entity @p[distance=..1,y_rotation=-60..-55,x_rotation=-7..-2] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"Ü"}'}
execute if entity @p[distance=..1,y_rotation=-124..-120,x_rotation=-1..4] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"A"}'}
execute if entity @p[distance=..1,y_rotation=-119..-114,x_rotation=-1..4] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"S"}'}
execute if entity @p[distance=..1,y_rotation=-113..-108,x_rotation=-1..4] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"D"}'}
execute if entity @p[distance=..1,y_rotation=-107..-101,x_rotation=-1..4] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"F"}'}
execute if entity @p[distance=..1,y_rotation=-100..-94,x_rotation=-1..4] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"G"}'}
execute if entity @p[distance=..1,y_rotation=-93..-87,x_rotation=-1..4] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"H"}'}
execute if entity @p[distance=..1,y_rotation=-86..-80,x_rotation=-1..4] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"J"}'}
execute if entity @p[distance=..1,y_rotation=-79..-73,x_rotation=-1..4] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"K"}'}
execute if entity @p[distance=..1,y_rotation=-72..-67,x_rotation=-1..4] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"L"}'}
execute if entity @p[distance=..1,y_rotation=-66..-61,x_rotation=-1..4] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"Ö"}'}
execute if entity @p[distance=..1,y_rotation=-60..-55,x_rotation=-1..4] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"Ä"}'}
execute if entity @p[distance=..1,y_rotation=-124..-120,x_rotation=5..10] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"Y"}'}
execute if entity @p[distance=..1,y_rotation=-119..-114,x_rotation=5..10] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"X"}'}
execute if entity @p[distance=..1,y_rotation=-113..-108,x_rotation=5..10] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"C"}'}
execute if entity @p[distance=..1,y_rotation=-107..-101,x_rotation=5..10] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"V"}'}
execute if entity @p[distance=..1,y_rotation=-100..-94,x_rotation=5..10] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"B"}'}
execute if entity @p[distance=..1,y_rotation=-93..-87,x_rotation=5..10] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"N"}'}
execute if entity @p[distance=..1,y_rotation=-86..-80,x_rotation=5..10] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"M"}'}
execute if entity @p[distance=..1,y_rotation=-79..-73,x_rotation=5..10] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":","}'}
execute if entity @p[distance=..1,y_rotation=-72..-67,x_rotation=5..10] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"."}'}
execute if entity @p[distance=..1,y_rotation=-66..-61,x_rotation=5..10] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"-"}'}
execute if entity @p[distance=..1,y_rotation=-60..-55,x_rotation=5..10] run data merge entity @s {CustomName:'{"bold":true,"color":"dark_purple","text":"_"}'}

# Die bishere Eingabe als Zeichenkette wie auch das neue eingetippte Zeichen werden zusammen in das Schild gespeichert.
execute at @s run data merge block ~ ~ ~ {Text1:'[{"entity":"@e[tag=EtiZeiEin.2Zeichenkette,sort=nearest,limit=1]","nbt":"CustomName","interpret":true},{"entity":"@e[tag=EtiZeiEin.2Zeichen,sort=nearest,limit=1]","nbt":"CustomName","interpret":true}]'}

# Die zusammengefügte Zeichenkette wird dann wieder in die Zeichenketten-Partikelwolke gespeichert.
execute at @s run data modify entity @e[type=minecraft:area_effect_cloud,tag=EtiZeiEin.2Zeichenkette,sort=nearest,limit=1] CustomName set from block ~ ~ ~ Text1

Variante 2: Stopp-Funktion
Die Stopp-Funktion löscht das Punktestand-Ziel sowie das Team wieder. Auch werden der Esel, der Dorfbewohner, die Partikelwolken und die Rüstungsständer gelöscht. Dabei werden diese zuvor in die Leere teleportiert, damit deren unvermeidbare Drops nicht in Erscheinung treten.

Editor Icon.png zeichen-eingabe:v2stopp.mcfunction
# Das Punktestand-Ziel sowie das Team wird gelöscht
scoreboard objectives remove PZZeiEin.2Klick
team remove TMZeiEin.2Kol

# Die Treppe und das Schild wird entfernt und der Esel, Dorfbewohner und alle Rüstungsständer werden gelöscht.
execute at @e[type=minecraft:donkey,tag=EtiZeiEin.2Sitz] run fill ~ ~1 ~ ~2 ~1 ~ minecraft:air replace
execute as @e[tag=EtiZeiEin.2Alle] at @s run teleport @s ~ ~-256 ~
kill @e[tag=EtiZeiEin.2Alle]


Disambig color.svg