Das offizielle Minecraft Wiki twittert hier: Wiki-Twitter  –  Chatte im Wiki-Discord  – Noch keinen Server gefunden? Es gibt einen Wiki-Server

Einfachauswahl (Befehle)

Aus Technik Wiki
Wechseln zu: Navigation, Suche
Gruppe: Grid Klebriger Kolben.png
Anlagen

Grid Roter Sand blass.png mit Mechaniken

Grid Redstone.png mit Redstone
                Hier:
Grid Befehlsblock.png mit Befehlen

Die vorgestellte Technik kann in der Redstone-Welt angesehen werden.

Die Einfachauswahl ermöglicht das aktivieren von einer Schaltfläche durch einen Mausklick. Die Schaltflächen werden hierbei mit Objekten realisiert. Wenn man auf eine Schaltfläche klickt, wird sie aktiv, wenn man jedoch eine andere Schaltfläche anklickt werden sämtliche Schaltflächen einer Gruppe deaktiviert und nur die gerade angeklickte wird aktiv geschaltet.

Inhaltsverzeichnis

Variante 1[Bearbeiten | Quelltext bearbeiten]

Einfachauswahl (Befehle) Bild 1.1.png Einfachauswahl (Befehle) Bild 1.2.png Einfachauswahl (Befehle) Bild 1.3.png

Mit dieser Einfachauswahl kann man Rüstungsständer an beliebigen Stellen platzieren um dort Schaltflächen in Form von Glocken zu erhalten. Man kann die Schaltflächen durch das Rechtsklicken auf diese aktivieren. Dann leuchten sie weiß auf und lassen etwas Partikel entstehen.

Einschalten
  • Befehl 1.1 Wenn der Hebel umgelegt wird, wird die Start-Funktion gestartet.
Wiederholen
  • Befehl 1.2 Beim Einschalten wird auch der Wiederhol-Befehlsblock gestartet, der jeden Tick die Zyklus-Funktion lädt.
Ausschalten
  • Befehl 1.3 Wenn der Hebel wieder in Ausgangsstellung zurück gelegt wird, wird die Stopp-Funktion ausgelöst und schaltet alles wieder ab.

Befehlsblöcke mit Befehlen:


Variante 1: Start-Funktion
Die Start-Funktion erstellt das Auslöser-Punktestand-Ziel und alle Variablen die benötigt werden.

Editor Icon.png einfachauswahl:v1start.mcfunction
# Das Punktestand-Ziel wird erstellt.
scoreboard objectives add PZEinfA.1Klick minecraft.custom:minecraft.talked_to_villager ["Einfachauswahl.1: ",{"text":"Klick auf Dorfbewohner","bold":true}]

# Den Spielern in einem Umkreis von 25 Metern werden 16 Rüstungsständer gegeben, die sie platzieren können.
give @a[distance=..25] minecraft:armor_stand{einfachauswahl:"v1gegenstand",display:{Name:'{"text":"Schaltfläche","bold":true}',Lore:['"Platziere den Rüstungsständer"','"um eine Auswahlschaltfläche"','"zu erzeugen"']},EntityTag:{Small:true,Invisible:true,Tags:["EtiEinfA.1Alle","EtiEinfA.1Erstellen"]} } 16

Variante 1: Zyklus-Funktion
Die Zyklus-Funktion ermöglicht, dass Glocken-Rüstungsständer angeklickt werden können und markiert werden.

Editor Icon.png einfachauswahl:v1zyklus.mcfunction
# An der Position des Erstellen-Rüstungsständers, wird ein Rüstungsständer mit Truhenkopf und auf ihm ein Dorfbewohner sitzend erzeugt. Der Erstellen-Rüstungsständer wird danach entfernt.
execute at @e[type=minecraft:armor_stand,tag=EtiEinfA.1Erstellen] run summon minecraft:armor_stand ~ ~ ~ {NoGravity:true,Small:true,Marker:true,Invisible:true,CustomNameVisible:true,CustomName:'{"text":"Schaltfläche","bold":true}',Tags:["EtiEinfA.1Alle","EtiEinfA.1Auswahl"],ArmorItems:[{},{},{},{id:"minecraft:bell",Count:1b} ],Passengers:[{id:"minecraft:villager",NoAI:true,Silent:true,NoGravity:true,Offers:{Recipes:[]},Tags:["EtiEinfA.1Alle","EtiEinfA.1Klicken"],ActiveEffects:[{Id:14b,Amplifier:0b,Ambient:false,ShowParticles:false,Duration:2147483647} ] } ] }
kill @e[type=minecraft:armor_stand,tag=EtiEinfA.1Erstellen]

# Die Auswahl-Rüstungsständer schauen zum Spieler, wenn dieser in einem Umkreis von fünf Blöcken bei ihnen steht.
execute as @e[type=minecraft:armor_stand,tag=EtiEinfA.1Auswahl] at @s run teleport @s ~ ~ ~ facing entity @p[distance=..5] eyes

# Wenn der Spieler auf eine Auswahlschaltfläche klickt, werden von allen angeklickten Rüstungsständern die Effekte und die Etiketten entfernt. Anschließend bekommt der angeklickte Rüstungsständer genau dieses Etikett und der Spieler erhält eine Nachricht darüber.
execute at @a[scores={PZEinfA.1Klick=1..}] positioned ^ ^ ^2 if entity @e[distance=..2,type=minecraft:villager,tag=EtiEinfA.1Klicken] run effect clear @e[type=minecraft:armor_stand,tag=EtiEinfA.1Angeklickt]
execute as @a[scores={PZEinfA.1Klick=1..}] at @s positioned ^ ^ ^2 if entity @e[distance=..2,type=minecraft:villager,tag=EtiEinfA.1Klicken] run playsound minecraft:block.bell.use block @s ~ ~ ~ 5 1
execute at @a[scores={PZEinfA.1Klick=1..}] positioned ^ ^ ^2 if entity @e[distance=..2,type=minecraft:villager,tag=EtiEinfA.1Klicken] run tag @e[type=minecraft:armor_stand,tag=EtiEinfA.1Angeklickt] remove EtiEinfA.1Angeklickt
execute at @a[scores={PZEinfA.1Klick=1..}] positioned ^ ^ ^2 run tag @e[distance=..2,type=minecraft:armor_stand,tag=EtiEinfA.1Auswahl,sort=nearest,limit=1] add EtiEinfA.1Angeklickt
execute as @a[scores={PZEinfA.1Klick=1..}] at @s positioned ^ ^ ^2 if entity @e[distance=..2,type=minecraft:armor_stand,tag=EtiEinfA.1Angeklickt,sort=nearest,limit=1] run tellraw @s ["Einfachauswahl.1: ",{"text":"Der Schalter wurde aktiviert (Rechtsklick)","bold":true} ]

# Der angeklickte Rüstungsständer besitzt ein Etikett an dem er erkannt wird und er erzeugt weiße Partikeln und den Leuchten-Effekt.
execute at @e[type=minecraft:armor_stand,tag=EtiEinfA.1Angeklickt] run particle minecraft:block minecraft:white_concrete ~ ~1.1 ~ 0 0 0 0.1 1 normal @a[distance=..25]
effect give @e[type=minecraft:armor_stand,tag=EtiEinfA.1Angeklickt] minecraft:glowing 1 1 false

# Spieler die einen Dorfbewohner angeklickt haben werden wieder auf den Wert null gesetzt.
scoreboard players set @a[scores={PZEinfA.1Klick=1..}] PZEinfA.1Klick 0

Variante 1: Stopp-Funktion
Die Stopp-Funktion entfernt das Auslöser-Punktestand-Ziel und somit auch alle Variablen die damit zu tun haben.

Editor Icon.png einfachauswahl:v1stopp.mcfunction
# Das Punktestand-Ziel wird gelöscht.
scoreboard objectives remove PZEinfA.1Klick

# Die Rüstungsständer mit der bestimmten Eigenschaft werden entfernt
clear @a[distance=..50] minecraft:armor_stand{einfachauswahl:"v1gegenstand"}

# Alle platzierten und auf dem Boden liegende Rüstungsständer werden gelöscht.
tag @e[type=minecraft:item,nbt={Item:{tag:{einfachauswahl:"v1gegenstand"} } }] add EtiEinfA.1Alle
kill @e[tag=EtiEinfA.1Alle]


Disambig color.svg
Grid Grasblock.png
Auch im Minecraft Wiki wird das Thema dieser Technik behandelt:
Befehl#Zielauswahl