Technik Wiki
Registrieren
Advertisement
Gruppe: Grid Kolben
Vorrichtungen

Grid Roter Sand mit Mechaniken

Grid Redstone blass mit Redstone
                Hier:
Grid Befehlsblock mit Befehlen
Verfügbar in:
Wiki Redstone-Welt Redstone-Welt

Ein Dropgenerator kann Gegenstände zu einer festgelegten Zeit immer wieder erzeugen. Diese hier sind besonders bei Minispiele sehr nützlich, da sie den Spielern einen Vorrat an bestimmten Barren liefern. Man kann auch den Dropgenerator in Kombination einer Tauschmaschine nutzen, sodass man die hier erhaltenen Drops gegen andere Blöcke oder Gegenstände tauschen kann, um beispielsweise Waffen oder Werkzeuge zu bekommen.

Die unten gezeigten Dropgeneratoren werden vor allem im sehr bekannten Minispiel Bedwars verwendet.

Variante 1[]

Dropgenerator (Befehle) Bild 1.1

Mit dieser Variante lassen sich Kupfergeneratoren durch das Platzieren von Rüstungsständern erzeugen. an der platzierten Stelle wird ein Kupferblock gesetzt der nach einer bestimmten Zeit einen Kupferbarren erzeugt.

Einschalten

Beim Einschalten wird ein Punkte-Ziel erstellt und die Spieler erhalten Kupferbarrengeratoren in die Hand.

  • Befehl 1.1 Das Punkte-Ziel für die Zeit wird erstellt. Welches genutzt wird um den Zeitpunkt zu ermitteln, wann ein neuer Kupferbarren erzeugt werden soll.
  • Befehl 1.2 Der Kupfergenerator in Form von Rüstungsständern wird allen Spielern in einem Umkreis von 15 Metern mitgegeben.
Wiederholen

Alle 200 Ticks (10 Sekunden) wird ein Kupferbarren an der Stelle des Generators erzeugt und beim Platzieren von diesem wird ein Kupferblock platziert.

  • Befehl 1.3 Wenn sich an der Position des Rüstungsständers noch kein Block befindet, wird ein Kupferblock dort platziert.
  • Befehl 1.4 Jeden Tick wird der Wert, aller Rüstungsständer die in der Welt platziert wurden, um eins erhöht.
  • Befehl 1.5 Sobald die Kupfergenerator-Rüstungsständer den Wert 20 erreichen, wird an deren Position einen Meter höher ein Kupferbarren erzeugt, der noch ein wenig in die Lüfte springt.
  • Befehl 1.6 Wenn der Kupfergenerator-Rüstungsständer den Wert 200 oder höher besitzt, wird der Wert wieder auf null zurückgesetzt.
Ausschalten

Das Punkte-Ziel, sowie alle Kupfergeneratoren, alle Kupferbarren und Gegenstände im Inventar werden gelöscht.

  • Befehl 1.7 Das Punkte-Ziel für die Zeitfeststellung wird gelöscht.
  • Befehl 1.8 Rüstungsständer die als Kupfergenerator arbeiten, werden aus dem Inventar entfernt.
  • Befehl 1.9 Kupferbarren die aufgesammelt wurden, werden aus dem Inventar entfernt.
  • Befehl 1.10 An der Position der Kupferbarrengeneratoren wird zuerst geprüft ob sich dort Kupferblöcke befinden und erst dann wird dieser entfernt.
  • Befehl 1.11 Falls noch Drops auf dem Boden liegen, erhalten sie ein Etikett um erkannt zu werden.
  • Befehl 1.12 Alle Kupfergeneratoren und eventuell herumliegende Drops werden gelöscht.



Befehlsblöcke mit Befehlen:
scoreboard objectives add PZDropG.1Zeit dummy ["Dropgenerator.1: ",{"text":"Ticks bis ein Barren erscheint","bold":true}]
give @a[distance=..15] minecraft:armor_stand{EigDropG.1Alle:true,display:{Name:'{"text":"Kupfergenerator","color":"#8e402a","bold":true}',Lore:['"Platziere den Rüstungsständer"','"auf dem Boden"','"um einen Kupfergenerator"','"zu kreieren"']},EntityTag:{Small:true,NoGravity:true,Invisible:true,Tags:["EtiDropG.1Alle","EtiDropG.1Generator"]} } 16


execute at @e[type=minecraft:armor_stand,tag=EtiDropG.1Generator] run setblock ~ ~ ~ minecraft:copper_block keep
scoreboard players add @e[type=minecraft:armor_stand,tag=EtiDropG.1Generator] PZDropG.1Zeit 1
execute at @e[type=minecraft:armor_stand,tag=EtiDropG.1Generator,scores={PZDropG.1Zeit=20}] run summon minecraft:item ~ ~1 ~ {Item:{id:"minecraft:copper_ingot",Count:1b,tag:{EigDropG.1Alle:true} },Motion:[0.0d,0.3d,0.0d],Tags:["EtiDropG.1Alle"] }
scoreboard players set @e[type=minecraft:armor_stand,tag=EtiDropG.1Generator,scores={PZDropG.1Zeit=200..}] PZDropG.1Zeit 0


scoreboard objectives remove PZDropG.1Zeit
clear @a minecraft:armor_stand{EigDropG.1Alle:true}
clear @a minecraft:brick{EigDropG.1Alle:true}
execute at @e[type=minecraft:armor_stand,tag=EtiDropG.1Generator] if block ~ ~ ~ minecraft:copper_block run setblock ~ ~ ~ minecraft:air replace
tag @e[type=minecraft:item,nbt={Item:{tag:{EigDropG.1Alle:true} } }] add EtiDropG.1Alle
kill @e[tag=EtiDropG.1Alle]

Variante 2[]

Dropgenerator (Befehle) Bild 2.1

Wie bereits bei der ersten Variante können auch hier durch Rüstungsständer Generatoren platziert werden. Hierbei erhält man die Möglichkeit Generatoren für Kupfer-, Eisen- und Goldbarren zu platzieren. Sie erzeugen nach einer gewissen Zeit entsprechende Barren, die man aufsammeln kann.

Einschalten
  • Befehl 2.1 Auf dem Wiederhol-Befehlsblock befindet sich ein Hebel. Legt man ihn um, wird zuerst der Befehlsblock mit der Startfunktion dropgenerator:v2start aktiviert.
Wiederholen
Ausschalten

Befehlsblöcke mit Befehlen:


Datenpaket
  • Vorrichtungen


Variante 2: Start-Funktion
Es wird das Punkte-Ziel für das Hochzählen der Zeit erstellt, sowie die Rüstungsständer in die Hand der Spieler gegeben, die man als Generatoren auf den Boden platzieren kann.

Editor Icon dropgenerator:v2start.mcfunction
# Das Punkte-Ziel für die Zeitmessung wird erstellt.
scoreboard objectives add PZDropG.2Tick dummy ["Dropgenerator.2: ",{"text":"Ticks bis ein Barren erscheint","bold":true}]

# Spieler in einem Umkreis von 15 Metern erhalten für Kupfer-, Eisen- und Goldgenerator die jeweiligen Rüstungsständer in das Inventar und einen Rüstungsständer mit dem man die Generatoren wieder entfernen kann.
give @a[distance=..15] minecraft:armor_stand{EigDropG.2Alle:true,display:{Name:'{"text":"Kupfergenerator","color":"#8e402a","bold":true}',Lore:['"Platziere den Rüstungsständer"','"auf dem Boden"','"um einen Kupfergenerator"','"zu kreieren"']},EntityTag:{Small:true,NoGravity:true,Invisible:true,Tags:["EtiDropG.2Alle","EtiDropG.2Generator","EtiDropG.2Kupfer"]} } 16
give @a[distance=..15] minecraft:armor_stand{EigDropG.2Alle:true,display:{Name:'{"text":"Eisengenerator","color":"gray","bold":true}',Lore:['"Platziere den Rüstungsständer"','"auf dem Boden"','"um einen Eisengenerator"','"zu kreieren"']},EntityTag:{Small:true,NoGravity:true,Invisible:true,Tags:["EtiDropG.2Alle","EtiDropG.2Generator","EtiDropG.2Eisen"]} } 16
give @a[distance=..15] minecraft:armor_stand{EigDropG.2Alle:true,display:{Name:'{"text":"Goldgenerator","color":"gold","bold":true}',Lore:['"Platziere den Rüstungsständer"','"auf dem Boden"','"um einen Goldgenerator"','"zu kreieren"']},EntityTag:{Small:true,NoGravity:true,Invisible:true,Tags:["EtiDropG.2Alle","EtiDropG.2Generator","EtiDropG.2Gold"]} } 16
give @a[distance=..15] minecraft:armor_stand{EigDropG.2Alle:true,display:{Name:'{"text":"Generator entfernen","color":"red","bold":true}',Lore:['"Platziere den Rüstungsständer"','"neben einen Generator"','"um diesen zu entfernen"']},EntityTag:{Small:true,NoGravity:true,Invisible:true,Tags:["EtiDropG.2Alle","EtiDropG.2Entfernen"]} } 16


Variante 2: Zyklus-Funktion
Alle 200, 400 oder 800 Ticks werden die entsprechenden Barren an den Generatoren erzeugt und falls sich der entsprechende Block noch nicht am Generator befindet wird dieser noch platziert.

Editor Icon dropgenerator:v2zyklus.mcfunction
# Falls sich kein Block bei den Generatoren befindet, wird der jeweilige Block platziert.
execute at @e[type=minecraft:armor_stand,tag=EtiDropG.2Kupfer] run setblock ~ ~ ~ minecraft:copper_block keep
execute at @e[type=minecraft:armor_stand,tag=EtiDropG.2Eisen] run setblock ~ ~ ~ minecraft:iron_block keep
execute at @e[type=minecraft:armor_stand,tag=EtiDropG.2Gold] run setblock ~ ~ ~ minecraft:gold_block keep

# Jeden Tick wird der Wert aller Generatoren um eins erhöht.
scoreboard players add @e[type=minecraft:armor_stand,tag=EtiDropG.2Generator] PZDropG.2Tick 1

# Wenn die Generatoren den Wert 20 erreichen erzeugen sie ihren jeweilgen Barren über sich, welcher ein wenig in die Höhe springt.
execute at @e[type=minecraft:armor_stand,tag=EtiDropG.2Kupfer,scores={PZDropG.2Tick=20}] run summon minecraft:item ~ ~1 ~ {Item:{id:"minecraft:copper_ingot",Count:1b,tag:{EigDropG.2Alle:true} },Motion:[0.0d,0.3d,0.0d],Tags:["EtiDropG.2Alle"] }
execute at @e[type=minecraft:armor_stand,tag=EtiDropG.2Eisen,scores={PZDropG.2Tick=20}] run summon minecraft:item ~ ~1 ~ {Item:{id:"minecraft:iron_ingot",Count:1b,tag:{EigDropG.2Alle:true} },Motion:[0.0d,0.3d,0.0d],Tags:["EtiDropG.2Alle"] }
execute at @e[type=minecraft:armor_stand,tag=EtiDropG.2Gold,scores={PZDropG.2Tick=20}] run summon minecraft:item ~ ~1 ~ {Item:{id:"minecraft:gold_ingot",Count:1b,tag:{EigDropG.2Alle:true} },Motion:[0.0d,0.3d,0.0d],Tags:["EtiDropG.2Alle"] }

# Je nach Generatortyp wird die Zeit bei 200, 400 oder 800 wieder auf null zurückgesetzt.
scoreboard players set @e[type=minecraft:armor_stand,tag=EtiDropG.2Kupfer,scores={PZDropG.2Tick=200..}] PZDropG.2Tick 0
scoreboard players set @e[type=minecraft:armor_stand,tag=EtiDropG.2Eisen,scores={PZDropG.2Tick=400..}] PZDropG.2Tick 0
scoreboard players set @e[type=minecraft:armor_stand,tag=EtiDropG.2Gold,scores={PZDropG.2Tick=800..}] PZDropG.2Tick 0

# Wenn der Entfernen-Rüstungsständer neben einen Generator gesetzt wurde, werden diese entfernt.
execute at @e[type=minecraft:armor_stand,tag=EtiDropG.2Entfernen] at @e[distance=..2,type=minecraft:armor_stand,tag=EtiDropG.2Generator] run setblock ~ ~ ~ minecraft:air replace
execute at @e[type=minecraft:armor_stand,tag=EtiDropG.2Entfernen] run kill @e[distance=..2,tag=EtiDropG.2Alle,sort=nearest,limit=4]


Variante 2: Stopp-Funktion
Das Punkte-Ziel, die Generatoren sowie die Gegenstände im Inventar wie auch in der Welt liegende werden gelöscht.

Editor Icon dropgenerator:v2stopp.mcfunction
# Das Punkte-Ziel wird wieder gelöscht.
scoreboard objectives remove PZDropG.2Tick

# Gegenstände von und für die Generatoren werden aus dem Inventar gelöscht der Spieler gelöscht.
clear @a minecraft:armor_stand{EigDropG.2Alle:true}
clear @a minecraft:copper_ingot{EigDropG.2Alle:true}
clear @a minecraft:iron_ingot{EigDropG.2Alle:true}
clear @a minecraft:gold_ingot{EigDropG.2Alle:true}

# Wenn sich an der Stelle der Generatoren ein Block befindet, wird dieser durch Luft ersetzt.
execute at @e[type=minecraft:armor_stand,tag=EtiDropG.2Generator] unless block ~ ~ ~ minecraft:air run setblock ~ ~ ~ minecraft:air replace

# Barren die auf dem Boden liegen und Generatoren werden gelöscht.
tag @e[type=minecraft:item,nbt={Item:{tag:{EigDropG.2Alle:true} } }] add EtiDropG.2Alle
kill @e[tag=EtiDropG.2Alle]
Advertisement