Biom-Sensor (Befehle)

Aus Technik Wiki
Wechseln zu: Navigation, Suche
Gruppe: Grid Kolben.png
Vorrichtungen

Grid Roter Sand blass.png mit Mechaniken

Grid Redstone blass.png mit Redstone
                Hier:
Grid Befehlsblock.png mit Befehlen
Verfügbar in:
Wiki Redstone-Welt.png Redstone-Welt

Ein Biom-Sensor ist in der Lage, das Biom in dem sich der Spieler befindet, zu erkennen. Mit Hilfe von Fortschritten oder Prädikaten kann man prüfen ob der Spieler in einem bestimmten Biom sich befindet.

Inhaltsverzeichnis

Variante 1[Bearbeiten | Quelltext bearbeiten]

Biom-Sensor (Befehle) Bild 1.1.png

Dieser Biom-Sensor erkennt mit Hilfe eines Fortschrittes, ob der spieler im Biom die Leere sich befindet. Nur wenn er sich dort befindet, bekommt er eine Schnelleisten-Nachricht.

Einschalten
  • Befehl 1.1 Auf dem Wiederhol-Befehlsblock befindet sich ein Hebel. Legt man ihn um, wird zuerst der Befehlsblock mit der Start-Funktion biom-sensor:v1start aktiviert.
Wiederholen
Ausschalten

Befehlsblöcke mit Befehlen:



Variante 1: Start-Funktion
Die Start-Funktion gibt dem Spieler einen verzauberten Stock.

Editor Icon.png biom-sensor:v1start.mcfunction
# Den Spielern wird ein Stock mit Verzauberungsschimmer gegeben.
give @a[distance=..15] minecraft:stick{EigBiomS.1Alle:true,EigBiomS.1Sensor:true,Enchantments:[{id:-1}],display:{Name:'{"text":"Biom-Sensor","color":"dark_purple","bold":true}',Lore:['"Wähle den Stock aus"','"um nach dem Biom"','"zu testen."'] } }

Variante 1: Zyklus-Funktion
Die Zyklus-Funktion prüft, ob der Fortschritt für das Biom erhalten wurde und gibt dann eine Schnelleisten-Nachricht aus.

Editor Icon.png biom-sensor:v1zyklus.mcfunction
# Wenn der Spieler im Biom die Leere ist, erhält er den Fortschritt dafür und das wird getestet. Nur wenn er diesen hat und den Stock ausgewählt hat, erhält er die Schnelleisten-Nachricht.
title @a[advancements={biom-sensor:v1biom_leere=true},nbt={SelectedItem:{tag:{EigBiomS.1Sensor:true} } }] actionbar ["",{"text":"Biom == ","color":"gray","bold":true},{"text":"Die Leere","color":"blue","bold":true}]

# Wenn Spieler das Biom die Leere betreten haben, wird der Fortschritt wieder entfernt, damit er nur dann vorhanden ist, wenn man aktuell dort ist.
advancement revoke @a[advancements={biom-sensor:v1biom_leere=true}] only biom-sensor:v1biom_leere
JSON Icon.png biom-sensor:v1biom_leere.json
{
  "criteria": {
    "Biom": {
      "trigger": "minecraft:location",
      "conditions": {
        "location": {
          "biome": "minecraft:the_void"
        }
      }
    }
  }
}

Variante 1: Stopp-Funktion
Die Stopp-Funktion löscht den Fortschritt und den Stock wieder.

Editor Icon.png biom-sensor:v1stopp.mcfunction
# Der Fortschritt wird entfernt.
advancement revoke @a[advancements={biom-sensor:v1biom_leere=true}] only biom-sensor:v1biom_leere

# Der Stock wird entfernt.
clear @a minecraft:stick{EigBiomS.1Alle:true}

# Falls der Stock auf den Boden geworfen wurde, wird er entfernt.
kill @e[type=minecraft:item,nbt={Item:{tag:{EigBiomS.1Alle:true} } }]

Variante 2[Bearbeiten | Quelltext bearbeiten]

Biom-Sensor (Befehle) Bild 1.1.png

Dieser Biom-Sensor erfasst durch ein Prädikat, ob der Spieler sich im Biom die Leere aufhält. Wenn er dabei einen bestimmten Stock in der Schnelleiste ausgewählt hat, erscheint eine Nachricht über der Schnelleiste.

Einschalten
  • Befehl 2.1 Auf dem Wiederhol-Befehlsblock befindet sich ein Hebel. Legt man ihn um, wird zuerst der Befehlsblock mit der Start-Funktion biom-sensor:v2start aktiviert.
Wiederholen
Ausschalten

Befehlsblöcke mit Befehlen:



Variante 2: Start-Funktion
Die Start-Funktion gibt dem Spieler einen Stock, den er auswählen muss um den Sensor zu aktivieren.

Editor Icon.png biom-sensor:v2start.mcfunction
# Allen Spielern im Umkreis von 15 Blöcken wird jeweils ein Stock mit Verzauberungschimmer gegeben.
give @a[distance=..15] minecraft:stick{EigBiomS.2Alle:true,EigBiomS.2Sensor:true,Enchantments:[{id:-1}],display:{Name:'{"text":"Biom-Sensor","color":"dark_purple","bold":true}',Lore:['"Wähle den Stock aus"','"um nach dem Biom"','"zu testen."'] } }

Variante 2: Zyklus-Funktion
Die Zyklus-Funktion prüft ob der Spieler im entsprechenden Biom sich befindet. Wenn er dabei den Stock ausgewählt hat, erscheint über der Schnellleiste das Biom als Nachricht.

Editor Icon.png biom-sensor:v2zyklus.mcfunction
# Wenn der Spieler in dem Biom die Leere sich befindet und den Stock ausgewählt hat, wird ihm die Schnelleisten-Nachricht angegeben.
title @a[predicate=biom-sensor:v2biom_leere,nbt={SelectedItem:{tag:{EigBiomS.2Sensor:true} } }] actionbar ["",{"text":"Biom == ","color":"gray","bold":true},{"text":"Die Leere","color":"blue","bold":true}]
JSON Icon.png biom-sensor:v2biom_leere.json
{
  "condition": "minecraft:location_check",
  "predicate": {
    "biome": "minecraft:the_void"
  }
}

Variante 2: Stopp-Funktion
Die Stopp-Funktion löscht den Stock als Drop und als Gegenstand im Inventar wieder.

Editor Icon.png biom-sensor:v2stopp.mcfunction
# Der Stock wird aus dem Inventar aller Spieler entfernt.
clear @a minecraft:stick{EigBiomS.2Alle:true}

# Falls der Stock auf den Boden geworfen wurde, wird er entfernt.
kill @e[type=minecraft:item,nbt={Item:{tag:{EigBiomS.2Alle:true} } }]


Disambig color.svg
 
Grid Grasblock.png
Auch im Minecraft Wiki wird das Thema dieser Technik behandelt:
Biom